bintray_lib.gradle

apply plugin: 'com.jfrog.bintray'
// from https://github.com/nuuneoi/JCenter

version = libraryVersion

if (project.hasProperty("android")) { // Android libraries
    task sourcesJar(type: Jar) {
        classifier = 'sources'
        from android.sourceSets.main.java.srcDirs
    }

    task javadoc(type: Javadoc) {
        source = android.sourceSets.main.java.srcDirs
        classpath += project.files(android.getBootClasspath().join(File.pathSeparator))
    }
} else { // Java libraries
    task sourcesJar(type: Jar, dependsOn: classes) {
        classifier = 'sources'
        from sourceSets.main.allSource
    }
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from javadoc.destinationDir
}

artifacts {
    archives javadocJar
    archives sourcesJar
}

// Bintray
Properties properties = new Properties()
def defUser = System.env.gradlePublishUser
def defKey = System.env.gradlePublishKey
def defSecret = System.env.gradlePublishSecret

if (!defKey || !defUser || !defSecret) {
// This is for local build
    def file = new File("${project.rootProject.projectDir}/local.properties")
    if (file.exists())
        properties.load( file.newDataInputStream())
} else {
// This is for remote build set System Properties in travis system
    properties.setProperty("bintray.user", defUser)
    properties.setProperty("bintray.apikey", defKey)
    properties.setProperty("bintray.gpg.password", defSecret)
}

bintray {
//    Properties properties = new Properties()
//    properties.load(project.rootProject.file('local.properties').newDataInputStream())
    user = properties.getProperty("bintray.user")
    key = properties.getProperty("bintray.apikey")

    configurations = ['archives']
    pkg {
        repo = bintrayRepo
        name = bintrayName
        desc = libraryDescription
        websiteUrl = siteUrl
        vcsUrl = gitUrl
        licenses = allLicenses
        publish = true
        publicDownloadNumbers = true
        version {
            desc = libraryDescription
            gpg {
                sign = true //Determines whether to GPG sign the files. The default is false
                passphrase = properties.getProperty("bintray.gpg.password")
                //Optional. The passphrase for GPG signing'
            }
        }
    }
}