cloud_enum: add package (#4468)

* cloud_enum: add package

* Create cloud_enum.install

* Update to-release

* Update PKGBUILD

* Delete packages/cloud_enum/cloud_enum.install

---------

Co-authored-by: noptrix <noptrix@nullsecurity.net>

lists/to-release

@@ -1 +0,0 @@
-shuji

packages/cloud_enum/PKGBUILD

@@ -0,0 +1,48 @@
+# This file is part of BlackArch Linux ( https://www.blackarch.org/ ).
+# See COPYING for license details.
+
+pkgname=cloud_enum
+pkgver=0.7.r10.gd3c292c
+pkgrel=1
+pkgdesc='Multi-cloud OSINT tool. Enumerate public resources in AWS, Azure, and Google Cloud.'
+arch=('any')
+groups=('blackarch' 'blackarch-recon')
+url='https://github.com/initstring/cloud_enum'
+license=('MIT')
+depends=('python' 'python-dnspython' 'python-requests' 'python-requests-futures')
+makedepends=('git')
+source=("git+https://github.com/initstring/$pkgname.git")
+sha512sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+
+  ( set -o pipefail
+    git describe --long --tags --abbrev=7 2>/dev/null |
+      sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
+    printf "%s.%s" "$(git rev-list --count HEAD)" \
+      "$(git rev-parse --short=7 HEAD)"
+  )
+}
+
+package() {
+  cd $pkgname
+
+  install -dm 755 "$pkgdir/usr/bin"
+  install -dm 755 "$pkgdir/usr/share/$pkgname"
+  install -Dm 644 -t "$pkgdir/usr/share/doc/$pkgname/" *.md
+
+  install -Dm 644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+
+  rm -rf LICENSE *.md .gitignore .github tests requirements.txt
+
+  cp -a * "$pkgdir/usr/share/$pkgname/"
+
+  cat > "$pkgdir/usr/bin/$pkgname" << EOF
+#!/bin/sh
+exec python /usr/share/$pkgname/cloud_enum.py "\$@"
+EOF
+
+  chmod a+x "$pkgdir/usr/bin/$pkgname"
+}
+