ESP32 & EthernetENC OTA update as download

[marcelstoer]

I am a little confused about what I read in the documentation. Maybe you can help clarify.

I want to implement OTA update as download on ESP32 using your EthernetENC library.

• at https://github.com/jandrassy/ArduinoOTA#esp8266-and-esp32-support it says "This library allows to upload a sketch to esp8266 or esp32 over Ethernet with Ethernet or EthernetENC library."
• at https://github.com/jandrassy/ArduinoOTA#ota-update-as-download it says "Use the ... esp32 HTTPUpdate library for OTA update download"

-> nothing in this library for my use case, correct?

So, I went ahead and checked the (public) interface of the ESP32 HTTPUpdate library. At https://github.com/espressif/arduino-esp32/blob/6cfe4613e4b4846e1ab08c7f78b7ea241f52c7da/libraries/HTTPUpdate/src/HTTPUpdate.h#L94 I found this one function that works with an HTTPClient rather than WiFiClient

t_httpUpdate_return update(HTTPClient& httpClient,
                               const String& currentVersion = "");

However, contrary to using the WiFiClient I can't set the URL from where to download the new firmware. Your own example shows how to set the URL/path in the client

https://github.com/jandrassy/ArduinoOTA/blob/1cc443dfa0fcf3141ae4c14ba09f0c3187427911/examples/Advanced/OTASketchDownload/OTASketchDownload.ino#L49-L55 but here it's the client that triggers the GET request - something which your documentation above says should not be used on ESP32.

So, is there an example somewhere how to OTA update as download on ESP32 over Ethernet?

[JAndrassy]

t says "This library allows to upload a sketch to esp8266 or esp32 over Ethernet with Ethernet or EthernetENC library."

sorry this is of course applies to native WiFi of the esp32.

but the InternalStorage of this ArduinoOTA library only wraps the esp32 Update object for the library's upload server.
Use the esp32 Update library directly for update with a downloaded bin.

[marcelstoer]

Thanks for your feedback. I also concluded that I need to implement this myself at the "low level". I am currently experimenting with the following sketch where client is an EthernetENC EthernetClient instance.

 // old code removed, see final sketch in next comment

The client-reading->Update-writing stalls at some point and I have yet to figure out what's wrong with my code.

[JAndrassy]

did you try the ArduinoHttpClient library? the Advanced (download) examples use it. it is much simpler than handling the HTTP in sketch

[marcelstoer]

I ended up implementing the OTA process myself on top of the standard ESP32 Update library and the Ethernet/Stream APIs. I can be significantly shortened if you remove error-handling and logging.

#include <Update.h>
#include "ethernet.h"

const char *host = OTA_HOST;
int port = OTA_HOST_PORT;
int bufferSize = 1024;

void initiateOta(String firmwareFilename) {
  log_i("Connecting to %s:%d", host, port);
  if (client.connect(host, port)) {
    String path = "/" + String(OTA_PROJECT) + "/" + firmwareFilename;
    log_i("Fetching %s", path.c_str());
    client.print(String("GET ") + path + " HTTP/1.1\r\n" +
                 "Host: " + String(host) + "\r\n" +
                 "User-Agent: " + USER_AGENT_HEADER + "\r\n" +
                 "Cache-Control: no-cache\r\n" +
                 "Connection: close\r\n\r\n");
  } else {
    log_e("Connection failed");
    return;
  }

  unsigned long start = millis();
  while (client.available() == 0) {
    if (millis() - start > 5000) {
      log_e("Client timeout -> abort");
      client.stop();
      return;
    }
  }

  int len = 0;
  byte buffer[bufferSize];
  boolean isHeader = true;
  int statusCode = 0;
  long contentLength = 0;
  bool isValidContentType = false;
  String headerLine;
  bool updateStarted = false;
  long bytesWritten = 0;
  start = millis();

  while(client.available() || client.connected()) {
    len = client.available();
    if (len > 0) {
      if (isHeader) {
        headerLine = client.readStringUntil('\n');
        log_d("%s", headerLine.c_str());
        if (headerLine == "\r") {
          log_d("Processing HTTP body");
          isHeader = false;
          continue;
        }
        if (headerLine.startsWith("HTTP/1.")) {
          statusCode = headerLine.substring(9, headerLine.indexOf(' ', 9)).toInt();
          if (statusCode != 200) {
            log_e("Invalid status code %d -> abort", statusCode);
            client.stop();
            return;
          }
        } else if (headerLine.startsWith("Content-Length: ")) {
          contentLength = headerLine.substring(16).toInt();
        } else if (headerLine.startsWith("Content-Type: ")) {
          String contentType = headerLine.substring(14);
          contentType.trim();
          if (contentType == "application/octet-stream") {
            isValidContentType = true;
          }
        }
      } else { // is HTTP body
        if (!updateStarted) {
          if (contentLength && isValidContentType) {
            log_i("Content length & type ok. Checking if there is enough data to start OTA.");
            if (Update.begin(contentLength, U_FLASH)) {
              log_i("All good, start processing bytes");
              updateStarted = true;
            } else {
              log_e("There is not enough space to store the update -> abort");
              client.stop();
              return;
            }
          } else {
            log_e("Content length or type not as expected -> abort");
            client.stop();
            return;
          }
        }
        // never read more than buffer capacity
        if (len > bufferSize) len = bufferSize;
        client.read(buffer, len);
        Update.write(buffer, len);
        bytesWritten += len;
      }
    }
  }
  if (bytesWritten == contentLength) {
    float seconds = (float)(millis() - start) / 1000.0;
    float rate = (float)contentLength / seconds / 1000.0;
    log_i("Writing OTA stream successful; %d bytes in %.2fs -> %.1fKB/s", bytesWritten, seconds, rate);
  } else {
    log_e("Written OTA stream shorter than content length : %d vs. %d. Retry?", bytesWritten, contentLength);
    // retry??
  }
  if (Update.end()) {
    log_i("OTA done!");
    if (Update.isFinished()) {
      log_i("Update successfully completed. Rebooting.");
      client.stop();
      ESP.restart();
    } else {
      log_i("Update not finished, something went wrong");
    }
  } else {
    log_e("Error #: %d", Update.getError());
  }
  client.stop();
}

[OptifySudarshanPatil]

Thanks for the code!
Will try this out and update here. 🤞

[OptifySudarshanPatil]

Hey @marcelstoer !
This code works like a charm!🤟
will try to make it https compatible in future.