build.gradle

import org.apache.tools.ant.filters.ReplaceTokens

plugins {
    id 'com.github.johnrengelman.shadow' version '7.0.0'
    id 'java'
}

group 'fr.zorg'
version '1.1.0'

def mcVersion = '1.17'
def subVersion = ''

repositories {
    mavenCentral()
    maven { url = 'https://jitpack.io' }
    maven { url = 'https://hub.spigotmc.org/nexus/content/repositories/snapshots/' }
    maven { url = 'https://oss.sonatype.org/content/repositories/snapshots' }
    maven { url = 'https://repo.destroystokyo.com/repository/maven-public/' }
}

dependencies {
    compileOnly group: 'org.spigotmc', name: 'spigot-api', version: mcVersion + subVersion + '-R0.1-SNAPSHOT'
    compileOnly group: 'net.md-5', name: 'bungeecord-api', version: mcVersion + '-R0.1-SNAPSHOT'
    compileOnly group: 'org.jetbrains', name: 'annotations', version: '16.0.2'
    compileOnly (group: 'com.github.SkriptLang', name: 'Skript', version: '2.6-alpha1') {
        exclude group: 'com.sk89q.worldguard', module: 'worldguard-legacy'
        exclude group: 'net.milkbowl.vault', module: 'Vault'
    }
    implementation group: 'commons-io', name: 'commons-io', version: '2.8.0'
    implementation group: 'com.github.rockaport', name:'alice', version: '0.9.0'
}

[compileJava, compileTestJava]*.options*.encoding = 'UTF-8'

processResources {
    filter ReplaceTokens, tokens: [
            'version': project.property("version"),
    ]
}

configurations {
    implementation {
        canBeResolved = true
    }
}

shadowJar {
    archiveName("BungeeSK.jar")
}