Unable to build up it to Yocto(ARM platform) for Cross-compile

[leoleo419]

Hi Sir,
I download this project, then add a "Cmake file" and modified the makefile for Yocto toolchain for Resenas SoC aarch64 platform as below, but it still use the local host GCC to build up this project then get build failed, I am so confuse about it, could you do me a favor? Many thanks for your any help ^__^ , I am appreciated.

Generating gcc makefiles...
-- The C compiler identification is GNU 9.4.0
-- The CXX compiler identification is GNU 9.4.0
-- Detecting C compiler ABI info
-- Detecting C compiler ABI info - done
-- Check for working C compiler: /usr/bin/gcc - skipped
-- Detecting C compile features
-- Detecting C compile features - done
-- Detecting CXX compiler ABI info
-- Detecting CXX compiler ABI info - done
-- Check for working CXX compiler: /usr/bin/g++ - skipped
-- Detecting CXX compile features
-- Detecting CXX compile features - done
-- Using sysroot path as /opt/poky/3.1.26/sysroots/aarch64-poky-linux
CMake Deprecation Warning at 3rdparty/libwebsockets/CMakeLists.txt:25 (cmake_minimum_required):
Compatibility with CMake < 3.5 will be removed from a future version of
CMake.

Update the VERSION argument value or use a ... suffix to tell
CMake that the project does not need compatibility with older versions.

CMake Warning (dev) at 3rdparty/libwebsockets/CMakeLists.txt:312 (option):
Policy CMP0077 is not set: option() honors normal variables. Run "cmake
--help-policy CMP0077" for policy details. Use the cmake_policy command to
set the policy and suppress this warning.

For compatibility with older versions of CMake, option is clearing the
normal variable 'LWS_WITH_NETLINK'.
This warning is for project developers. Use -Wno-dev to suppress it.

-- Compiled with LWS_WITH_DIR and LWS_WITH_LEJP_CONF
-- Found Git: /usr/bin/git (found version "2.25.1")
Git commit hash: f46d149
-- Performing Test LWS_HAVE_inline
-- Performing Test LWS_HAVE_inline - Failed
-- Performing Test LWS_HAVE___inline__
-- Performing Test LWS_HAVE___inline__ - Failed
-- Performing Test LWS_HAVE___inline
-- Performing Test LWS_HAVE___inline - Failed
-- Performing Test LWS_HAVE_MALLOC_TRIM
-- Performing Test LWS_HAVE_MALLOC_TRIM - Failed
-- Performing Test LWS_HAVE_MALLOC_USABLE_SIZE
-- Performing Test LWS_HAVE_MALLOC_USABLE_SIZE - Failed
-- Looking for fork
-- Looking for fork - found
-- Looking for getenv
-- Looking for getenv - found
-- Looking for malloc
-- Looking for malloc - found
-- Looking for memset
-- Looking for memset - found
-- Looking for realloc
-- Looking for realloc - found
-- Looking for socket
-- Looking for socket - found
-- Looking for strerror
-- Looking for strerror - found

The Cmake file that I add as below:

set(CMAKE_SYSTEM_NAME Linux)
set(CMAKE_SYSTEM_PROCESSOR aarch64)

set(SYSROOT_PATH /opt/poky/3.1.26/sysroots/aarch64-poky-linux )
set(CMAKE_SYSROOT "${SYSROOT_PATH}")
message(STATUS "Using sysroot path as ${SYSROOT_PATH}")

#set(SDKTARGETSYSROOT /opt/poky/3.1.26/sysroots/aarch64-poky-linux )

set(CMAKE_C_COMPILER /opt/poky/3.1.26/sysroots/x86_64-pokysdk-linux/usr/bin/aarch64-poky-linux/aarch64-poky-linux-gcc)
set(CMAKE_CXX_COMPILER /opt/poky/3.1.26/sysroots/x86_64-pokysdk-linux/usr/bin/aarch64-poky-linux/aarch64-poky-linux-g++)

add_link_options("LINKER:-rpath-link,/opt/poky/3.1.26/sysroots/aarch64-poky-linux/lib:/opt/poky/3.1.26/sysroots/aarch64-poky-linux/usr/lib:/opt/poky/3.1.26/sysroots/aarch64-poky-linux/usr/include")

set(CMAKE_FIND_ROOT_PATH /opt/poky/3.1.26/sysroots/aarch64-poky-linux)

set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM NEVER)
set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)

The Makefile that I modified as below:

#Root directory containing the top level CMakeLists.txt file
ROOT_DIR:=$(PWD)

#Generated binary directory
BIN_DIR:=$(ROOT_DIR)/bin

#Make options
#VERBOSE="VERBOSE=1"
PARALLEL_BUILD?=-j 4

#Build type can be either Debug or Release
BUILD_TYPE?=Release

#Logger configuration
EXTERNAL_LOGGER?=OFF

SDKTARGETSYSROOT=/opt/poky/3.1.26/sysroots/aarch64-poky-linux
CC=aarch64-poky-linux-gcc -mtune=cortex-a55 -fstack-protector-strong -D_FORTIFY_SOURCE=2 -Wformat -Wformat-security -Werror=format-security --sysroot=$(SDKTARGETSYSROOT)
ARCH = "aarch64"
# Default target
default: gcc

#Silent makefile
#.SILENT:

#Install prefix
ifneq ($(strip $(INSTALL_PREFIX)),)
CMAKE_INSTALL_PREFIX:=-D CMAKE_INSTALL_PREFIX=$(INSTALL_PREFIX)
CMAKE_INSTALL_PREFIX_CMD:=--prefix $(INSTALL_PREFIX)
endif

[c-jimenez]

Hi,
Sorry for the response delay.
I have successfully built the library using Yocto kirkstone for an aarch64 target.

Here is the recipe for the library :

SUMMARY = "Open OCPP"
HOMEPAGE = "https://github.com/c-jimenez/open-ocpp"
LICENSE = "LGPL-2.1-or-later"
LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/LGPL-2.1-or-later;md5=2a4f4fd2128ea2f65047ee63fbca9f68"

SRC_URI = "git://git@github.com/c-jimenez/open-ocpp.git;protocol=https;branch=main"
SRCREV = "9bad56ab7f9ec03bf6d2fcd8c5207e89c49614ed"
S = "${WORKDIR}/git"

DEPENDS="openssl sqlite3 libwebsockets"
RDEPENDS:${PN}="openssl sqlite3 libwebsockets"

inherit cmake pkgconfig

EXTRA_OECMAKE += "-DEXTERNAL_LOGGER=ON -DBUILD_LWS_LIBRARY=OFF"

It uses the standard libwebsocket recipe provided by the Yocto tree :

SUMMARY = "Canonical libwebsockets.org websocket library"
HOMEPAGE = "https://libwebsockets.org/"
LICENSE = "MIT & Zlib & BSD-3-Clause & Apache-2.0"
LIC_FILES_CHKSUM = "file://LICENSE;md5=382bfdf329e774859fd401eaf850d29b"

DEPENDS = "zlib"
DEPENDS:append:class-native = " libcap-native"

S = "${WORKDIR}/git"
SRCREV = "b0a749c8e7a8294b68581ce4feac0e55045eb00b"
SRC_URI = "git://github.com/warmcat/libwebsockets.git;protocol=https;branch=v4.3-stable \
           file://0001-Fix-Werror-enum-int-mismatch-in-lws_tls_server_abort.patch"

UPSTREAM_CHECK_URI = "https://github.com/warmcat/${BPN}/releases"
UPSTREAM_CHECK_GITTAGREGEX = "v(?P<pver>\d+(\.\d+)+)"

inherit cmake pkgconfig

PACKAGECONFIG ?= "libuv client server http2 ssl ${@bb.utils.filter('DISTRO_FEATURES', 'ipv6', d)}"
PACKAGECONFIG[client] = "-DLWS_WITHOUT_CLIENT=OFF,-DLWS_WITHOUT_CLIENT=ON,"
PACKAGECONFIG[http2] = "-DLWS_WITH_HTTP2=ON,-DLWS_WITH_HTTP2=OFF,"
PACKAGECONFIG[ipv6] = "-DLWS_IPV6=ON,-DLWS_IPV6=OFF,"
PACKAGECONFIG[libevent] = "-DLWS_WITH_LIBEVENT=ON,-DLWS_WITH_LIBEVENT=OFF,libevent"
PACKAGECONFIG[libev] = "-DLWS_WITH_LIBEV=ON,-DLWS_WITH_LIBEV=OFF,libev"
PACKAGECONFIG[libuv] = "-DLWS_WITH_LIBUV=ON,-DLWS_WITH_LIBUV=OFF,libuv"
PACKAGECONFIG[server] = "-DLWS_WITHOUT_SERVER=OFF,-DLWS_WITHOUT_SERVER=ON,"
PACKAGECONFIG[ssl] = "-DLWS_WITH_SSL=ON,-DLWS_WITH_SSL=OFF,openssl"
PACKAGECONFIG[static] = "-DLWS_WITH_STATIC=ON,-DLWS_WITH_STATIC=OFF -DLWS_LINK_TESTAPPS_DYNAMIC=ON,"
PACKAGECONFIG[systemd] = "-DLWS_WITH_SDEVENT=ON,-DLWS_WITH_SDEVENT=OFF,systemd"

python __anonymous() {
  if bb.utils.contains('PACKAGECONFIG', 'systemd', True, False, d) and not bb.utils.contains('DISTRO_FEATURES', 'systemd', True, False, d):
    bb.fatal("PACKAGECONFIG contains systemd but DISTRO_FEATURES doesn't")
}

EXTRA_OECMAKE += " \
    -DLIB_SUFFIX=${@d.getVar('baselib').replace('lib', '')} \
"

do_install:append() {
    sed -i -e 's|${STAGING_LIBDIR}/libcrypto.so|crypto|g' ${D}${libdir}/cmake/libwebsockets/LibwebsocketsTargets.cmake
    sed -i -e 's|${STAGING_LIBDIR}/libssl.so|ssl|g' ${D}${libdir}/cmake/libwebsockets/LibwebsocketsTargets.cmake
    sed -i -e 's|${STAGING_LIBDIR}/libuv.so|uv|g' ${D}${libdir}/cmake/libwebsockets/LibwebsocketsTargets.cmake
    sed -i -e 's|${STAGING_INCDIR}||g' ${D}${libdir}/cmake/libwebsockets/LibwebsocketsTargets.cmake \
                                       ${D}${libdir}/cmake/libwebsockets/libwebsockets-config.cmake
}

PACKAGES =+ "${PN}-testapps ${PN}-evlib-event ${PN}-evlib-uv ${PN}-evlib-ev ${PN}-evlib-sd"

FILES:${PN}-testapps += "${datadir}/libwebsockets-test-server/* ${bindir}/libwebsockets-test-*"
FILES:${PN}-evlib-event += "${libdir}/libwebsockets-evlib_event.so"
FILES:${PN}-evlib-uv += "${libdir}/libwebsockets-evlib_uv.so"
FILES:${PN}-evlib-ev += "${libdir}/libwebsockets-evlib_ev.so"
FILES:${PN}-evlib-sd += "${libdir}/libwebsockets-evlib_sd.so"

RDEPENDS:${PN} += " ${@bb.utils.contains('PACKAGECONFIG', 'libevent', '${PN}-evlib-event', '', d)}"
RDEPENDS:${PN} += " ${@bb.utils.contains('PACKAGECONFIG', 'libuv', '${PN}-evlib-uv', '', d)}"
RDEPENDS:${PN} += " ${@bb.utils.contains('PACKAGECONFIG', 'libev', '${PN}-evlib-ev', '', d)}"
RDEPENDS:${PN} += " ${@bb.utils.contains('PACKAGECONFIG', 'systemd', '${PN}-evlib-sd', '', d)}"

RDEPENDS:${PN}-dev += " ${@bb.utils.contains('PACKAGECONFIG', 'static', '${PN}-staticdev', '', d)}"

# Avoid absolute paths to end up in the sysroot.
SSTATE_SCAN_FILES += "*.cmake"

BBCLASSEXTEND = "native"

Since I'm not a Yocto expert I can't help you more on this matter.