-
Notifications
You must be signed in to change notification settings - Fork 1
/
Copy pathrsp.pas
1276 lines (1134 loc) · 32.8 KB
/
rsp.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
unit rsp;
interface
uses
{$ifdef unix}cthreads,{$endif}
Classes, SysUtils, ssockets, debugwire, bpmanager;
type
{ $DEFINE memorymap}
{TGdbRspThread }
TDebugState = (dsPaused, dsRunning);
TDebugStopReason = (srCtrlC, srHWBP, srSWBP);
TFlashWriteBuffer = record
addr: word;
Data: TBytes;
end;
// To view rsp communication as received by gdb:
// (gdb) set debug remote 1
TGdbRspThread = class(TThread)
private
FClientStream: TSocketStream;
FDebugWire: TDebugWire;
FDebugState: TDebugState;
FLogger: TLog;
FBPManager: TBPManager;
FLastCmd: string; // in case a resend is required;
FFlashWriteBuffer: array of TFlashWriteBuffer;
{$ifdef memorymap}
FMemoryMap: string;
{$endif}
FLoggingEnabled: boolean;
procedure FLog(s: string);
procedure FLoggingEnabledProc(val: boolean);
function gdb_fieldSepPos(cmd: string): integer;
procedure gdb_response(s: string);
procedure gdb_response(data: TBytes);
procedure gdb_response_hexencoded(s: string);
procedure gdb_qSupported(cmd: string);
function FTCPDataAvailable: boolean;
function FSerialDataAvailable: boolean;
// Debugwire interface
procedure DebugContinue;
procedure DebugStep;
procedure DebugGetRegisters;
procedure DebugGetRegister(cmd: string);
procedure DebugSetRegisters(cmd: string);
procedure DebugSetRegister(cmd: string);
procedure DebugGetMemory(cmd: string);
procedure DebugSetMemoryHex(cmd: string);
procedure DebugSetMemoryBinary(cmd: string);
procedure DebugSetMemory(addr: dword; data: TBytes);
{$IFDEF memorymap}
procedure DebugMemoryMap(cmd: string);
{$ENDIF memorymap}
procedure DecodeBinary(const s: string; out data: TBytes);
procedure EncodeBinary(const data: TBytes; out s: string);
procedure DebugFlashErase(cmd: string);
procedure DebugFlashWrite(cmd: string);
procedure DebugFlashWriteDone;
procedure DebugStopReason(signal: integer; stopReason: TDebugStopReason);
function HexDecode(hexcode: string): string;
procedure HandleRcmd(req: string);
public
constructor Create(AClientStream: TSocketStream; dw: TDebugWire; logger: TLog);
procedure Execute; override;
property LoggingEnabled: boolean read FLoggingEnabled write FLoggingEnabledProc;
end;
{ TGdbRspServer }
TGdbRspServer = class(TInetServer{TTCPServer})
private
FActiveThread: TGdbRspThread;
FActiveThreadRunning: boolean;
FDebugWire: TDebugWire;
FSerialPort: string;
FBaud: integer;
FVerboseLogging: boolean;
procedure FLog(s: string);
procedure FActiveThreadOnTerminate(Sender: TObject);
procedure FAcceptConnection(Sender: TObject; Data: TSocketStream);
procedure FQueryConnect(Sender: TObject; ASocket: LongInt; var doaccept: Boolean);
public
constructor Create(APort: Word);
function SerialConnect(serialPort: string; baud: integer): boolean; overload;
property VerboseLogging: boolean read FVerboseLogging write FVerboseLogging;
end;
implementation
uses
sockets,
{$IFNDEF WINDOWS}BaseUnix, math;
{$ELSE}windows, winsock2;
{$ENDIF}
function AddrToString(Addr: sockets.TSockAddr): String;
begin
Result := NetAddrToStr(Addr.sin_addr);
Result := Result + ':' + IntToStr(Addr.sin_port);
end;
procedure TGdbRspThread.FLog(s: string);
begin
if FLoggingEnabled and Assigned(FLogger) then
Flogger(s);
end;
procedure TGdbRspThread.FLoggingEnabledProc(val: boolean);
begin
FLoggingEnabled := val;
FBPManager.LoggingEnabled := val;
FDebugWire.LoggingEnabled := val;
end;
function TGdbRspThread.gdb_fieldSepPos(cmd: string): integer;
var
colonPos, commaPos, semicolonPos: integer;
begin
colonPos := pos(':', cmd);
commaPos := pos(',', cmd);
semicolonPos := pos(';', cmd);
result := Max(colonPos, semicolonPos);
result := Max(result, commaPos);
if (colonPos > 0) and (result > colonPos) then
result := colonPos;
if (commaPos > 0) and (result > commaPos) then
result := commaPos;
if (semicolonPos > 0) and (result > semicolonPos) then
result := semicolonPos;
end;
procedure TGdbRspThread.gdb_response(s: string);
var
checksum, i: integer;
reply: string;
begin
FLastCmd := s;
checksum := 0;
for i := 1 to length(s) do
checksum := checksum + ord(s[i]);
reply := '$' + s + '#' + hexStr(byte(checksum), 2);
FClientStream.WriteBuffer(reply[1], length(reply));
FLog('<- ' + reply);
end;
procedure TGdbRspThread.gdb_response(data: TBytes);
var
resp: string;
i: integer;
begin
resp := '';
for i := 0 to length(data)-1 do
resp := resp + hexStr(data[i], 2);
gdb_response(resp);
end;
procedure TGdbRspThread.gdb_response_hexencoded(s: string);
var
enc: string;
i, v: integer;
begin
enc := '';
for i := 1 to length(s) do
begin
v := ord(s[i]);
enc := enc + HexStr(v, 2);
end;
gdb_response(enc);
end;
procedure TGdbRspThread.gdb_qSupported(cmd: string);
begin
if pos('Supported', cmd) > 0 then
gdb_response('hwbreak+;swbreak+;'
// For flash writes transfer at least a flash page full of data
// to prevent potential repeated erasing of the same flash page
// due to data transfer fragementation
+ 'PacketSize=' + IntToStr(FDebugWire.Device.FlashPageSize) + ';'
{$IFDEF memorymap} + 'qXfer:memory-map:read+' {$ENDIF memorymap})
else if pos('Offsets', cmd) > 0 then
gdb_response('Text=0;Data=0;Bss=0')
else if pos('Symbol', cmd) > 0 then
gdb_response('OK');
end;
function TGdbRspThread.FTCPDataAvailable: boolean;
{$if defined(unix) or defined(windows)}
var
FDS: TFDSet;
TimeV: TTimeVal;
{$endif}
begin
Result:=False;
{$if defined(unix) or defined(windows)}
TimeV.tv_usec := 1 * 1000; // 1 msec
TimeV.tv_sec := 0;
{$endif}
{$ifdef unix}
FDS := Default(TFDSet);
fpFD_Zero(FDS);
fpFD_Set(self.FClientStream.Handle, FDS);
Result := fpSelect(self.FClientStream.Handle + 1, @FDS, nil, nil, @TimeV) > 0;
{$else}
{$ifdef windows}
FDS := Default(TFDSet);
FD_Zero(FDS);
FD_Set(self.FClientStream.Handle, FDS);
Result := Select(self.FClientStream.Handle + 1, @FDS, nil, nil, @TimeV) > 0;
{$endif}
{$endif}
end;
function TGdbRspThread.FSerialDataAvailable: boolean;
{$if defined(unix)}
var
FDS: TFDSet;
TimeV: TTimeVal;
{$else}
var
eventMask: dword;
{$endif}
begin
Result:=False;
{$if defined(unix)}
TimeV.tv_usec := 10 * 1000; // 10 msec
TimeV.tv_sec := 0;
FDS := Default(TFDSet);
fpFD_Zero(FDS);
fpFD_Set(self.FDebugWire.Serial.SerialHandle, FDS);
Result := fpSelect(self.FDebugWire.Serial.SerialHandle + 1, @FDS, nil, nil, @TimeV) > 0;
{$elseif defined(windows)}
eventMask := EV_BREAK or EV_RXCHAR; // signal on BREAK or any other char
SetCommMask(self.FDebugWire.Serial.SerialHandle, eventMask);
eventMask := 0;
WaitCommEvent(self.FDebugWire.Serial.SerialHandle, eventMask, nil);
result := eventMask and (EV_BREAK or EV_RXCHAR) > 0;
{$endif}
end;
procedure TGdbRspThread.DebugContinue;
begin
FLog('PC = ' + hexStr(FDebugWire.PC, 4));
FDebugState := dsRunning;
FDebugWire.Run;
end;
procedure TGdbRspThread.DebugStep;
var
instruction, oldPC: word;
ActiveBPRecord: PBP;
begin
oldPC := FDebugWire.PC;
ActiveBPRecord := FBPManager.findSWBPFromAddress(oldPC);
if ActiveBPRecord <> nil then
begin
if length(ActiveBPRecord^.origCode) = 2 then
begin
instruction := ActiveBPRecord^.origCode[0] + (ActiveBPRecord^.origCode[1] shl 8);
FDebugWire.SendInstruction16(instruction);
FDebugWire.PC := oldPC + 2;
end
else
FLog('Unexpected instruction code length');
end
else
FDebugWire.Step;
end;
procedure TGdbRspThread.DebugGetRegisters;
var
data: TBytes;
resp: string;
i: integer;
begin
FDebugWire.safeReadRegs(0, 32, data);
resp := '';
for i := 0 to length(data)-1 do
resp := resp + hexStr(data[i], 2);
// Eliminate gdb error when reply starts with E
resp := LowerCase(resp);
// SREG
FDebugWire.ReadAddress($5F, 1, data);
resp := resp + hexStr(data[0], 2);
// SPL & SPH
FDebugWire.ReadAddress($5D, 2, data);
resp := resp + hexStr(data[0], 2) + hexStr(data[1], 2);
// PC in bytes
resp := resp + hexStr(FDebugWire.PC and $FF, 2) + hexStr(FDebugWire.PC shr 8, 2) + '0000';
gdb_response(resp);
end;
procedure TGdbRspThread.DebugGetRegister(cmd: string);
var
regID: integer;
data: TBytes;
s: string;
i: integer;
begin
// cmd still contain full gdb string with p prefix
delete(cmd, 1, 1);
if Length(cmd) = 2 then // Hex number of a byte value
begin
regID := StrToInt('$'+cmd);
case regID of
0..31: begin // normal registers
FDebugWire.safeReadRegs(regID, 1, data);
end;
32: FDebugWire.ReadAddress($5F, 1, data); // SREG
33: FDebugWire.ReadAddress($5D, 2, data); // SPL, SPH
34: begin // PC
SetLength(data, 4);
data[0] := FDebugWire.PC and $FF;
data[1] := FDebugWire.PC shr 8;
data[2] := 0;
data[3] := 0;
end;
end;
end;
if length(data) > 0 then
begin
s := '';
for i := 0 to high(data) do
s := s + hexStr(data[i], 2);
gdb_response(s);
end
else
gdb_response('E00');
end;
procedure TGdbRspThread.DebugSetRegisters(cmd: string);
var
data: TBytes;
l1, len, i: integer;
s: string;
begin
// cmd still contain full gdb string with G prefix
delete(cmd, 1, 1);
len := length(cmd) div 2; // in byte equivalents
// extract normal registers
l1 := min(len, 32);
SetLength(data, l1);
for i := 0 to l1-1 do
begin
s := '$' + cmd[2*i + 1] + cmd[2*i + 2];
data[i] := StrToInt(s);
end;
FDebugWire.WriteAddress(0, data);
// Check for SREG
if (len > 32) then
begin
s := '$' + cmd[65] + cmd[66];
SetLength(data, 1);
data[0] := StrToInt(s);
FDebugWire.WriteAddress($5F, data);
end;
// Check for SPL/SPH
if (len > 34) then
begin
SetLength(data, 2);
s := '$' + cmd[67] + cmd[68];
data[0] := StrToInt(s);
SetLength(data, 2);
s := '$' + cmd[69] + cmd[70];
data[1] := StrToInt(s);
FDebugWire.WriteAddress($5D, data);
end;
// Should be PC
if (len = 39) then
begin
s := '$' + copy(cmd, 71, 8);
FDebugWire.PC := word(StrToInt(s));
end;
gdb_response('OK');
end;
procedure TGdbRspThread.DebugSetRegister(cmd: string);
var
regID: integer;
data: TBytes;
sep, val, numbytes, i: integer;
begin
// cmd still contain full gdb string with P prefix
delete(cmd, 1, 1);
sep := pos('=', cmd);
if sep = 3 then // regID is before '='
begin
regID := StrToInt('$' + copy(cmd, 1, 2));
numbytes := (length(cmd) - 3) div 2;
SetLength(data, numbytes);
for i := 0 to numbytes-1 do
begin
val := StrToInt('$' + cmd[4 + i*2] + cmd[4 + i*2 + 1]);
data[i] := (val shr (8*i)) and $ff;
end;
case regID of
// normal registers
0..31: FDebugWire.WriteRegs(regID, data);
// SREG
32: FDebugWire.WriteAddress($5F, data);
// SPL, SPH
33: FDebugWire.WriteAddress($5D, data);
// PC
34: FDebugWire.PC := data[0] + data[1] shl 8;
end;
end;
gdb_response('OK');
end;
procedure TGdbRspThread.DebugGetMemory(cmd: string);
var
len, i, err: integer;
s: string;
addr: dword;
data: TBytes;
begin
delete(cmd, 1, 1);
len := gdb_fieldSepPos(cmd);
s := '$' + copy(cmd, 1, len-1);
delete(cmd, 1, len);
val(s, addr, err);
if err <> 0 then
addr := $FFFFFFFF; // invalid address, should be caught below
len := gdb_fieldSepPos(cmd);
delete(cmd, len, length(cmd) - len);
len := StrToInt('$' + cmd);
s := '';
if dword(addr + len) < $800000 then // flash memory
begin
if dword(addr + len) < FDebugWire.Device.flashSize then
FDebugWire.ReadFlash(addr, len, data)
else
begin
FLog('Error: Flash address exceeds device limit');
SetLength(data, 0);
end;
end
else if dword(addr + len) < $810000 then // SRAM
begin
addr := addr and $FFFF;
if addr < 32 + FDebugWire.Device.ioregSize + FDebugWire.Device.sramSize then
FDebugWire.ReadAddress(addr and $FFFF, len, data)
else
begin
FLog('Error: Memory address exceeds device limit');
SetLength(data, 0);
end;
end
else
begin
if dword(addr + len) < ($810000 + FDebugWire.Device.eepromSize) then // must be EEPROM then
FDebugWire.ReadEEPROM(addr, len, data)
else
begin
FLog('Error: Address beyond EEPROM.');
SetLength(data, 0);
end;
end;
if length(data) > 0 then
for i := 0 to high(data) do
s := s + hexStr(data[i], 2)
else
s := 'E00';
gdb_response(s);
end;
procedure TGdbRspThread.DebugSetMemoryHex(cmd: string);
var
len, i: integer;
s: string;
addr: dword;
data: TBytes;
begin
delete(cmd, 1, 1);
i := gdb_fieldSepPos(cmd);
s := '$' + copy(cmd, 1, i-1);
addr := StrToInt(s);
delete(cmd, 1, i);
i := gdb_fieldSepPos(cmd);
s := '$' + copy(cmd, 1, i-1);
len := StrToInt(s);
delete(cmd, 1, i);
// now convert data
if len = (length(cmd) div 2) then
begin
SetLength(data, len);
s := '';
for i := 0 to len-1 do
begin
s := '$' + cmd[2*i + 1] + cmd[2*i + 2]; // 1 based index
data[i] := StrToInt(s);
end;
DebugSetMemory(addr, data);
end
else
begin
FLog('Decoded length <> expected length of Hex data.');
gdb_response('E02');
end;
end;
// X addr,len:XX...
procedure TGdbRspThread.DebugSetMemoryBinary(cmd: string);
var
len: integer;
s: string;
addr: dword;
data: TBytes;
begin
delete(cmd, 1, 1);
len := gdb_fieldSepPos(cmd);
s := '$' + copy(cmd, 1, len-1);
addr := StrToInt(s);
delete(cmd, 1, len);
len := gdb_fieldSepPos(cmd);
s := '$' + copy(cmd, 1, len-1);
delete(cmd, 1, len);
len := StrToInt(s);
// now convert data
DecodeBinary(cmd, data);
if len = length(data) then // ensure decoding yields the expected length data
begin
DebugSetMemory(addr, data);
end
else
begin
FLog('Decoded length <> expected length of binary data.');
gdb_response('E02');
end;
end;
procedure TGdbRspThread.DebugSetMemory(addr: dword; data: TBytes);
var
len: integer;
begin
len := length(data);
if (addr + len) < $800000 then // flash memory
begin
if (addr + len) < FDebugWire.Device.flashSize then
FDebugWire.WriteFlash(addr, data)
else
begin
FLog('Error: Flash address exceeds device limit');
len := 0;
end;
end
else if (addr + len) < $810000 then // SRAM
begin
addr := addr and $FFFF;
if addr < 32 + FDebugWire.Device.ioregSize + FDebugWire.Device.sramSize then
FDebugWire.WriteAddress(addr, data)
else
begin
FLog('Error: Memory address exceeds device limit');
len := 0;
end;
end
else // must be EEPROM then
begin
if dword(addr + len) < ($810000 + FDebugWire.Device.eepromSize) then // must be EEPROM then
FDebugWire.WriteEEPROM(addr, data)
else
begin
FLog('Error: Address beyond EEPROM.');
len := 0;
end;
end;
if len > 0 then
gdb_response('OK')
else
gdb_response('E02');
end;
// Support for qXfer:memory-map
{$IFDEF memorymap}
procedure TGdbRspThread.DebugMemoryMap(cmd: string);
var
i, offset, len: integer;
s: string;
begin
i := pos('::', cmd);
delete(cmd, 1, i+1);
i := gdb_fieldSepPos(cmd);
s := '$' + copy(cmd, 1, i-1);
offset := StrToInt(s);
delete(cmd, 1, i);
len := StrToInt('$' + cmd);
// If requested length < memory map size, prepend "m", else "l"
if (offset + len) < length(FMemoryMap) then
s := 'm' + copy(FMemoryMap, 1+offset, len)
else
s := 'l' + copy(FMemoryMap, 1+offset, len);
gdb_response(s);
end;
{$ENDIF memorymap}
procedure TGdbRspThread.DecodeBinary(const s: string; out data: TBytes);
var
i, j: integer;
begin
SetLength(data, 128);
// s should start before ':', then scan until ending #
i := 1;
j := 0;
while (i <= length(s)) and (s[i] <> '#') do
begin
if s[i] = '}' then // escape character
begin
inc(i); // read next character
data[j] := ord(s[i]) XOR $20;
inc(j);
end
//else if s[i] = '*' then //run length encoding
//begin
// if j > 0 then
// begin
// // repeat count in next byte
// // previous byte is repeated
// inc(i);
// n := ord(s[i]) - 29;
// repeatData := data[j-1];
// while n > 0 do
// begin
// data[j] := repeatData;
// inc(j);
// dec(n);
// end;
// end
// else
// FLog('Unexpected run length encoding detected at start of data.');
//end
else
begin
data[j] := ord(s[i]);
inc(j);
end;
inc(i);
if j >= length(data) then
SetLength(data, j + 128);
end;
SetLength(data, j);
end;
procedure TGdbRspThread.EncodeBinary(const data: TBytes; out s: string);
var
i, j: integer;
begin
SetLength(s, 128);
j := 1;
for i := 0 to high(data) do
begin
case data[i] of
$23, $24, $2A, $7D: // #, $, *, }
begin
s[j] := '}';
inc(j);
s[j] := char(data[i] XOR $20);
end
else
s[j] := char(data[i]);
end;
inc(j);
if j > length(s)-1 then
SetLength(s, Length(s) + 128);
end;
SetLength(s, j-1);
end;
// ‘vFlashErase:addr,length’
// Do nothing for now
// debugwire automatically erase flash as required when writing
procedure TGdbRspThread.DebugFlashErase(cmd: string);
begin
gdb_response('OK');
end;
// ‘vFlashWrite:addr:XX...’
procedure TGdbRspThread.DebugFlashWrite(cmd: string);
var
i, j: integer;
addr: integer;
data: TBytes;
newbuffer: boolean;
begin
i := gdb_fieldSepPos(cmd);
delete(cmd, 1, i);
i := gdb_fieldSepPos(cmd);
addr := StrToInt('$' + copy(cmd, 1, i-1));
delete(cmd, 1, i);
DecodeBinary(cmd, data);
newbuffer := true;
i := length(FFlashWriteBuffer);
if i > 0 then
begin
j := length(FFlashWriteBuffer[i-1].Data);
if (FFlashWriteBuffer[i-1].addr + j) = addr then // contiguous memory, append to this buffer
begin
SetLength(FFlashWriteBuffer[i-1].Data, j + length(data));
Move(data[0], FFlashWriteBuffer[i-1].Data[j], length(data));
newbuffer := false;
end
else
newbuffer := true;
end;
if newbuffer then
begin
SetLength(FFlashWriteBuffer, i+1);
FFlashWriteBuffer[i].addr := addr;
FFlashWriteBuffer[i].Data := copy(data, 0, length(data));
end;
gdb_response('OK')
end;
procedure TGdbRspThread.DebugFlashWriteDone;
var
i: integer;
isGood: boolean;
begin
isGood := true;
for i := 0 to high(FFlashWriteBuffer) do
begin
if FFlashWriteBuffer[i].addr <= FDebugWire.Device.flashSize then
FDebugWire.WriteFlash(FFlashWriteBuffer[i].addr, FFlashWriteBuffer[i].data)
else
begin
isGood := false;
FLog('unexpected address passed to DebugFlashWrite');
end;
end;
if isGood then
gdb_response('OK')
else
gdb_response('E00');
end;
procedure TGdbRspThread.DebugStopReason(signal: integer;
stopReason: TDebugStopReason);
var
s: string;
data: TBytes;
i: integer;
begin
s := 'T' + hexStr(signal, 2);
case stopReason of
srHWBP: s := s + 'hwbreak:;';
srSWBP: s := s + 'swbreak:;';
end;
// 32 General data
FDebugWire.ReadAddress(0, 32, data);
for i := 0 to 31 do
begin
s := s + hexStr(i, 2) + ':' + HexStr(data[i], 2) + ';';
end;
// SREG
FDebugWire.ReadAddress($5F, 1, data);
s := s + '20:' + hexStr(data[0], 2) + ';';
// SPL & SPH
FDebugWire.ReadAddress($5D, 2, data);
s := s + '21:' + hexStr(data[0], 2) + hexStr(data[1], 2) +';';
// PC in bytes
s := s + '22:' + hexStr(FDebugWire.PC and $FF, 2) + hexStr(FDebugWire.PC shr 8, 2) + '0000;';
gdb_response(s);
end;
function TGdbRspThread.HexDecode(hexcode: string): string;
var
i: integer;
s: string;
begin
SetLength(Result, length(hexCode) div 2);
for i := 1 to length(Result) do
begin
s := '$' + hexCode[2*i-1] + hexCode[2*i];
result[i] := char(StrToInt(s));
end;
end;
procedure TGdbRspThread.HandleRcmd(req: string);
var
resp: string;
cmds: TStringList;
begin
if length(req) = 0 then exit;
cmds := TStringList.Create;
try
cmds.Delimiter := ' ';
cmds.DelimitedText := lowercase(HexDecode(req));
FLog('Rcmd received: ' + cmds.DelimitedText);
resp := 'OK'; // Only override on actual error or alternative output
case cmds[0] of
'help':
begin
resp := ' help - List of commands supported.'+LineEnding +
' set verbose [1 or 0] - Enable or disable verbose messages'+LineEnding +
' set timers-disabled [1 or 0] - Disable or enable timers'+LineEnding;
end;
'set': // Options: verbose, timers-disabled
begin
if cmds.Count = 3 then
begin
case cmds[1] of
'verbose':
begin
if cmds[2] = '1' then
Self.LoggingEnabled := true
else if cmds[2] = '0' then
Self.LoggingEnabled := false
else
resp := 'E00';
end;
'timers-disabled':
begin
if cmds[2] = '1' then
FDebugWire.TimersDisabled := true
else if cmds[2] = '0' then
FDebugWire.TimersDisabled := false
else
resp := 'E00';
end;
else
resp := 'E00';
end
end
else
resp := 'E00';
end;
else
resp := 'E00';
end;
finally
cmds.Free;
end;
// Monitor responses should be encoded,
// but normal protocol responses (OK, Enn) should be returned plain text
if (resp = '') or (resp = 'OK') or ((length(resp) = 3) and (resp[1] = 'E')) then
gdb_response(resp)
else
gdb_response_hexencoded(resp);
end;
{ TGdbRspThread }
constructor TGdbRspThread.Create(AClientStream: TSocketStream; dw: TDebugWire;
logger: TLog);
begin
inherited Create(false);
FreeOnTerminate := true;
FClientStream := AClientStream;
FDebugWire := dw;
FDebugState := dsPaused;
FLogger := logger;
FLoggingEnabled := Assigned(logger);
dw.LoggingEnabled := FLoggingEnabled;
FBPManager := TBPManager.Create(FDebugWire, logger);
FBPManager.LoggingEnabled := FLoggingEnabled;
{$IFDEF memorymap}
if dw.Device.ID > 0 then
FMemoryMap := format('<memory-map> <memory type="ram" start="0x800000" length="0x%.4x"/> <memory type="flash" start="0" length="0x%.4x"> <property name="blocksize">0x40</property> </memory></memory-map>',
[32 + FDebugWire.Device.ioregSize + FDebugWire.Device.sramSize, FDebugWire.Device.flashSize]);
{$ENDIF memorymap}
//FMemoryMap := '<?xml version="1.0"?> '+ LineEnding +
// '<!DOCTYPE memory-map PUBLIC "+//IDN gnu.org//DTD GDB Memory Map V1.0//EN" "http://sourceware.org/gdb/gdb-memory-map.dtd"> '+ LineEnding +
// '<memory-map> '+ LineEnding +
// ' <memory type="ram" start="0x800000" length="0x'+ HexStr(FDebugWire.Device.sramSize, 4) + '"/>'+ LineEnding +
// ' <memory type="flash" start="0x00" length="0x'+ HexStr(FDebugWire.Device.flashSize, 4) +'">'+ LineEnding +
// ' <property name="blocksize">0x'+ HexStr(FDebugWire.Device.FlashPageSize, 4) +'</property>'+ LineEnding +
// ' </memory>'+ LineEnding +
// '</memory-map>';
end;
function pos_(const c: char; const s: RawByteString): integer;
var
i, j: integer;
begin
i := 1;
j := length(s);
while (i < j) and (s[i] <> c) do
inc(i);
if s[i] = c then result := i
else
result := 0;
end;
procedure TGdbRspThread.Execute;
var
msg, cmd : RawByteString;
buf: array[0..1023] of char;
count, i, j, idstart, idend, addr: integer;
Done: boolean;
begin
Done := false;
msg := '';
count := 0;
repeat
try
if FTCPDataAvailable then
begin
count := count + FClientStream.Read(buf[0], length(buf));
// if socket signaled and no data available -> connection closed
if count = 0 then
begin
// simulate a kill command, it will delete hw BP and run target
// then exit this thread
buf[0]:='$'; buf[1]:='k'; buf[2]:='#'; buf[3]:='0'; buf[4]:='0'; // CRC is not checked...
count := 5;
FLog('No data read, exiting read thread by simulating [k]ill...');
end;
end
else
count := 0;
// If running target, check check for break
if FDebugState = dsRunning then
begin
if FDebugWire.TrySync then
begin
FDebugState := dsPaused;
FDebugWire.Reconnect;
DebugStopReason(5, srHWBP);
end
end;
if count > 0 then
begin
SetLength(msg, count);
Move(buf[0], msg[1], count);
//msg := copy(buf, 1, count);
// ctrl+c falls outside of normal gdb message structure
if msg[1] = #3 then // ctrl+C
begin
// ack received command
FClientStream.WriteByte(ord('+'));
FLog('-> Ctrl+C');