build.gradle

/*
 * Gradle build script for the universal remote control for solvers (RCL).
 */

/************************************
 * Plugin Configuration and Imports *
 ************************************/

plugins {
    id "application"
    id "eclipse"
    id "jacoco"
    id "java"
    id "maven-publish"
    id "org.ajoberstar.grgit" version "4.1.0"
    id "org.openjfx.javafxplugin" version "0.0.13"
}

import org.apache.tools.ant.filters.ReplaceTokens

/**********************
 * Main Configuration *
 **********************/

group = "fr.cril"
version = "0.1.0"

def licenseName = "GNU Lesser General Public License, Version 3"
def licenseUrl = "https://www.gnu.org/licenses/lgpl-3.0.html"

def gitUrl =  "https://github.com/crillab/remote-control"
def issueUrl = "https://github.com/crillab/remote-control/issues"

def outDir = "${rootDir}/dist"
def jarDir = "${outDir}/home"

sourceCompatibility = '17'
targetCompatibility = '17'

/****************
 * Dependencies *
 ****************/

// Declaring the repositories to download the dependencies from.
repositories {
    mavenCentral()
    maven {
        url = uri("https://maven.pkg.github.com/crillab/*")
        credentials {
            username = project.findProperty("gpr.user") ?: System.getenv("GITHUB_ACTOR")
            password = project.findProperty("gpr.key") ?: System.getenv("GITHUB_TOKEN")
        }
    }
}

// Declaring the dependencies of the project.
dependencies {
    implementation group: "com.brunomnsilva", name: "smartgraph", version: "1.0.0"
    implementation group: "fr.cril", name: "juniverse", version: "0.2.10"
}

// Declaring the dependencies on JavaFX components.
javafx {
    version = "17.0.2"
    modules = ["javafx.controls", "javafx.fxml"]
}

/*************************
 * Eclipse Configuration *
 *************************/

// Modularizing project dependencies.
eclipse.classpath.file.whenMerged {
    entries.findAll{ isModule(it) }.each{ it.entryAttributes["module"] = "true" }
}

// Checking whether an Eclipse classpath entry must be put in the module path.
boolean isModule(entry) {
    (entry.kind == "src") || ((entry.kind == "lib") && (entry.entryAttributes["gradle_used_by_scope"] != "test"))
}

/*****************
 * Property File *
 *****************/

// Injects into the source code the information about the latest build.
task preprocessProperties(type: Copy) {
    from "src/main/resources/fr/univartois/cril/rcl/util/"
    into "src/main/java/fr/univartois/cril/rcl/util/"

    include "RemoteControlProperties"
    rename "RemoteControlProperties", "RemoteControlProperties.java"

    filter(ReplaceTokens, beginToken: "##", endToken: "##", tokens: [
    	version: rootProject.version,
    	license_name: licenseName,
    	license_url: licenseUrl,
    	website: gitUrl,
    	support: issueUrl,
    	commit_sha: grgit.head().abbreviatedId
    ])

    filter(ReplaceTokens, beginToken: "0x", endToken: "", tokens: [
    	DA7E: Long.toString(System.currentTimeMillis()) + "L"
    ])
}

// Properties are processed each time the code is compiled.
compileJava.dependsOn preprocessProperties

/***************
 * Application *
 ***************/

// Configuring the module and class to run as main.
application {
    mainModule = "fr.univartois.cril.rcl"
    mainClass = "fr.univartois.cril.rcl.RemoteControl"
}

/*************
 * Packaging *
 *************/

// Putting the generated jars in the output directory.
tasks.withType(Jar) {
    destinationDirectory = file("${jarDir}")
}

// Collects external dependencies of RCL into the output directory.
task collectExternalDependencies(type: Copy) {
    from configurations.runtimeClasspath.collect {
        it
    }
    into "${jarDir}"
}

// Creating a gzipped-tarball with RCL and its dependencies.
task rcl(type: Tar) {
    dependsOn jar
    dependsOn collectExternalDependencies

    from file("${jarDir}")
    destinationDirectory = file("${outDir}")
    archiveBaseName = "rcl"
    archiveExtension = "tgz"

    compression = Compression.GZIP
}

// Removes the binary files of RCL when cleaning.
task removeBinaries(type: Delete) {
    delete "dist"
}
clean.dependsOn removeBinaries

/****************
 * Distribution *
 ****************/

// Adding the Javadoc and source JARs to the generated artifacts.
java {
    withJavadocJar()
    withSourcesJar()
}

// Configuring the POM file to publish.
publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java

            versionMapping {
                usage("java-api") {
                    fromResolutionOf("runtimeClasspath")
                }
                usage("java-runtime") {
                    fromResolutionResult()
                }
            }

            pom {
                name = "RCL"
                description = "A universal remote control for solvers."
                url = "https://github.com/crillab/remote-control"

                licenses {
                    license {
                        name = "GNU Lesser General Public License, Version 3"
                        url = "https://www.gnu.org/licenses/lgpl-3.0.html"
                    }
                }

                developers {
                    developer {
                        id = "thibaultfalque"
                        name = "Thibault Falque"
                        email = "falque@cril.fr"
                    }

                    developer {
                        id = "michaelvalet"
                        name = "Michael Valet"
                        email = "michael_valet@ens.univ-artois.fr"
                    }

                    developer {
                        id = "romainwallon"
                        name = "Romain Wallon"
                        email = "wallon@cril.fr"
                    }
                }

                scm {
                    connection = "scm:git:https://github.com/crillab/remote-control"
                    developerConnection = "scm:git:https://github.com/crillab/remote-control"
                    url = "https://github.com/crillab/remote-control"
                }
            }
        }
    }

    repositories {
        maven {
            name = "GitHubPackages"
            url = uri("https://maven.pkg.github.com/crillab/remote-control")
            credentials {
                username = project.findProperty("gpr.user") ?: System.getenv("GITHUB_ACTOR")
                password = project.findProperty("gpr.key") ?: System.getenv("GITHUB_TOKEN")
            }
        }
    }
}