build.gradle

import java.time.ZonedDateTime
import java.time.format.DateTimeFormatter

plugins {
    id "org.sonarqube" version "2.6.1"
    id "io.codearte.nexus-staging" version "0.11.0"
}

printf "Date: %s\nHost: %s\nOS: %s %s %s\nJVM: %s %s %s %s\nGradle: %s Groovy: %s Java: %s\n" +
    "Build: group: ${project.group} name: ${project.name} version: ${project.version}\n",
    ZonedDateTime.now().format(DateTimeFormatter.ISO_DATE_TIME),
    InetAddress.getLocalHost(),
    System.getProperty("os.name"),
    System.getProperty("os.arch"),
    System.getProperty("os.version"),
    System.getProperty("java.version"),
    System.getProperty("java.vm.version"),
    System.getProperty("java.vm.vendor"),
    System.getProperty("java.vm.name"),
    gradle.gradleVersion, GroovySystem.getVersion(), JavaVersion.current()


apply plugin: 'java'
apply plugin: 'maven'
apply plugin: 'signing'

repositories {
    mavenCentral()
}

configurations {
    wagon
    distJars {
        extendsFrom runtime
        exclude group: 'org.elasticsearch'
        exclude module: 'lucene-core'
        exclude module: 'lucene-analyzers-common'
        exclude module: 'jts'
        exclude module: 'log4j-api'
        exclude module: 'log4j-core'
        exclude module: 'jna'
        exclude module: 'jackson-core'
        exclude module: 'jackson-dataformat-smile'
        exclude module: 'jackson-dataformat-yaml'
    }
}

apply from: 'gradle/ext.gradle'

dependencies {
    implementation "org.elasticsearch:elasticsearch:${project.property('elasticsearch.version')}"
    testImplementation "junit:junit:${project.property('junit.version')}"
    testImplementation "org.elasticsearch.plugin:transport-netty4-client:${project.property('elasticsearch.version')}"
    distJars "${project.group}:${project.name}:${project.version}"
    wagon "org.apache.maven.wagon:wagon-ssh:${project.property('wagon.version')}"
}

sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.VERSION_1_8

[compileJava, compileTestJava]*.options*.encoding = 'UTF-8'

tasks.withType(JavaCompile) {
  options.compilerArgs << "-Xlint:all" << "-profile" << "compact2"
}

test {
    systemProperties['path.home'] = System.getProperty("user.dir")
    testLogging {
        showStandardStreams = false
        exceptionFormat = 'full'
    }
}

task makePluginDescriptor(type: Copy) {
    from 'src/main/templates'
    into 'build/tmp/plugin'
    expand([
        'descriptor': [
            'name': pluginName,
            'classname': pluginClassname,
            'description': pluginDescription,
            'version': project.property('version'),
            'javaVersion': project.property('targetCompatibility'),
            'elasticsearchVersion' : project.property('elasticsearch.version')
        ]
    ])
}

task buildPluginZip(type: Zip, dependsOn: [':jar', ':makePluginDescriptor']) {
  from configurations.distJars
  from 'build/tmp/plugin'
  into 'elasticsearch'
  classifier = 'plugin'
}

task unpackPlugin(type: Copy, dependsOn: [':buildPluginZip']) {
  delete "plugins"
  from configurations.distJars
  from 'build/tmp/plugin'
  into "plugins/${pluginName}"
}

clean {
  delete "plugins"
  delete "data"
  delete "logs"
}

task javadocJar(type: Jar, dependsOn: classes) {
  from javadoc
  classifier 'javadoc'
}

task sourcesJar(type: Jar, dependsOn: classes) {
  from sourceSets.main.allSource
  classifier 'sources'
}

artifacts {
  archives javadocJar, sourcesJar, buildPluginZip
}

if (project.hasProperty('signing.keyId')) {
  signing {
    sign configurations.archives
  }
}