-
Notifications
You must be signed in to change notification settings - Fork 19
/
Copy pathquest-eden.pm
1060 lines (955 loc) · 33.8 KB
/
quest-eden.pm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
# 22508#Emblema do Éden#
automacro seJuntarAoGrupoEden_MoverPerto {
ConfigKeyNot quest_eden em_curso
ConfigKeyNot naSequenciaDeSalvamento true
InInventoryID 2414 = 0 #sapatos de aprendiz
exclusive 1
BaseLevel >= 12
ConfigKeyNot membroDoEden sim
NpcNotNear /Lenore|Lime/
JobIDNot 0 #aprendiz
JobIDNot 4023 #Baby Aprendiz
call moverPertoDosNpcEden
}
automacro seJuntarAoGrupoEden {
ConfigKeyNot membroDoEden sim
ConfigKeyNot quest_eden em_curso
ConfigKeyNot naSequenciaDeSalvamento true
run-once 1
exclusive 1
NpcNear /Lenore|Lime/
call {
do talk $.NpcNearLastBinId
do talk resp 1
do talk resp 0
do talk text lolol
do talk text lolol
do talk resp 4
do iconf 22508 0 0 0 #Emblema do Éden
}
}
automacro entreiNoGrupoEden {
InInventoryID 22508 = 1 #Emblema do Éden#
ConfigKeyNot membroDoEden sim
exclusive 1
call {
do conf -f membroDoEden sim
}
}
automacro questEden_trocarEmblemaIndoProNpc {
InInventoryID 6219 = 1 #emblema do grupo valhalla (o antigo)
NpcNotNear /Lenore|Lime/
exclusive 1
priority -2 # um pouco alta
call moverPertoDosNpcEden
}
automacro questEden_trocarEmblema {
InInventoryID 6219 = 1 #emblema do grupo valhalla (o antigo)
exclusive 1
priority -2 # um pouco alta
NpcNear /Lenore|Lime/
call {
do talk $.NpcNearLastBinId
do talk resp 0
do iconf 22508 0 0 0 #Emblema do Éden
}
}
automacro questEden12_iniciandoMoverPerto {
NpcNotNear /Boya/
InInventoryID 22508 = 1 #Emblema do Éden#
ConfigKeyNot fazerQuestEden nao
BaseLevel 12..18
exclusive 1
QuestInactive 7128
ConfigKeyNot naSequenciaDeSalvamento true
ConfigKeyNot quest_eden em_curso
ConfigKeyNot quest_eden terminando
IsNotEquippedID armor 15009 #Uniforme Valhalla Iniciante
InInventoryID 15009 = 0 #Uniforme Valhalla Iniciante
JobIDNot $parametrosClasses{idC1T}
JobIDNot $parametrosClasses{idC2T}
JobIDNot $parametrosClasses{idC2TAlt}
call moverPertoDosNpcEden
}
automacro questEden26_iniciandoMoverPerto {
NpcNotNear /Boya/
BaseLevel 26..32
InInventoryID 22508 = 1 #Emblema do Éden#
ConfigKeyNot fazerQuestEden nao
exclusive 1
QuestInactive 7138
QuestInactive 7139
QuestInactive 7140
ConfigKeyNot naSequenciaDeSalvamento true
ConfigKeyNot quest_eden em_curso
ConfigKeyNot quest_eden terminando
IsNotEquippedID armor 15010 #Uniforme Valhalla Intermediário
InInventoryID 15010 = 0 #Uniforme Valhalla Intermediário
JobIDNot $parametrosClasses{idC1T}
JobIDNot $parametrosClasses{idC2T}
JobIDNot $parametrosClasses{idC2TAlt}
call moverPertoDosNpcEden
}
automacro questEden40_iniciandoMoverPerto {
QuestInactive 7147
QuestInactive 7148
QuestInactive 7149
QuestInactive 7150
QuestInactive 7151
ConfigKeyNot fazerQuestEden nao
JobLevel != 50
NpcNotNear /Boya/
BaseLevel 40..49
exclusive 1
ConfigKeyNot naSequenciaDeSalvamento true
ConfigKeyNot quest_eden em_curso
ConfigKeyNot quest_eden terminando
IsNotEquippedID armor 15011
InInventoryID 22508 = 1 #Emblema do Éden#
InInventoryID 15011 = 0 #armadura que ganha com essa quest
JobIDNot $parametrosClasses{idC1T}
JobIDNot $parametrosClasses{idC2T}
JobIDNot $parametrosClasses{idC2TAlt}
call moverPertoDosNpcEden
}
automacro questEden60_iniciandoMoverPerto {
NpcNotNear /Ur/
BaseLevel 60..69
exclusive 1
InInventoryID 22508 = 1 #Emblema do Éden#
JobID $parametrosClasses{idC2}, $parametrosClasses{idC2Alt}, $parametrosClasses{idC2T}, $parametrosClasses{idC2TAlt}, $parametrosClasses{idBC2}, $parametrosClasses{idBC2Alt}
QuestInactive 7214
ConfigKeyNot fazerQuestEden nao
ConfigKeyNot naSequenciaDeSalvamento true
ConfigKeyNot quest_eden em_curso
ConfigKeyNot quest_eden terminando
IsNotEquippedID armor 15031 #Armadura do Grupo Éden
InInventoryID 15031 = 0 #Armadura do Grupo Éden
JobIDNot $parametrosClasses{idC1T}
JobIDNot $parametrosClasses{idC2T}
JobIDNot $parametrosClasses{idC2TAlt}
call moverPertoDosNpcEden
}
macro moverPertoDosNpcEden {
do conf lockMap none
call pararDeAtacar
[
log ===========================================
log =movendo pra perto dos npc do eden pra começar a quest
log ===========================================
]
do move moc_para01 &rand(33,35) &rand(25,27) #posição otima no Eden
do reload event
#estranhamente qando ele chega perto do npc do eden, ele nao checa alguma
#das condições (arrisco dizer a de inventory) por isso tive que colocar essa linha
#que recarrega o eventMacros, aí a proxima automacro trigga de boas
}
automacro questEden12_iniciando {
NpcNear /Boya/
InInventoryID 22508 = 1 #Emblema do Éden#
BaseLevel 12..17
exclusive 1
QuestInactive 7128
ConfigKeyNot fazerQuestEden nao
ConfigKeyNot naSequenciaDeSalvamento true
ConfigKeyNot quest_eden em_curso
ConfigKeyNot quest_eden terminando
IsNotEquippedID armor 15009 #Uniforme Valhalla Iniciante
InInventoryID 15009 = 0 #Uniforme Valhalla Iniciante
call {
[
log ===================================
log =Iniciando a quest eden do lvl 12
log ===================================
]
do talk $.NpcNearLastBinId
do talk resp 1
do talk resp 0
do talk resp 0
do conf -f o_que_estou_fazendo iniciando Quest Eden 12
}
}
automacro questEden26_iniciando {
NpcNear /Boya/
BaseLevel 26..32
ConfigKeyNot fazerQuestEden nao
InInventoryID 22508 = 1 #Emblema do Éden#
exclusive 1
QuestInactive 7138
QuestInactive 7139
QuestInactive 7140
ConfigKeyNot naSequenciaDeSalvamento true
ConfigKeyNot quest_eden em_curso
ConfigKeyNot quest_eden terminando
IsNotEquippedID armor 15010 #Uniforme Valhalla Intermediário
InInventoryID 15010 = 0 #Uniforme Valhalla Intermediário
call {
[
log ===================================
log =Iniciando a quest eden do lvl 26
log ===================================
]
do talk $.NpcNearLastBinId
#se vc não tiver feito a quest éden do lvl 12, a conversa é diferente
#de quem fez ela
if (&inventory(Uniforme Valhalla Iniciante) != -1) {
#se tiver o item da quest éden 12, use essa sequência
do talk resp 1
} else {
#se não tiver, use essa sequência
do talk resp 1
do talk resp 0
do talk resp 0
}
do conf -f o_que_estou_fazendo iniciando Quest Eden 26
}
}
automacro questEden40_iniciando {
NpcNear /Boya/
BaseLevel 40..49
InInventoryID 22508 = 1 #Emblema do Éden#
ConfigKeyNot fazerQuestEden nao
exclusive 1
QuestInactive 7147
ConfigKeyNot naSequenciaDeSalvamento true
ConfigKeyNot quest_eden em_curso
ConfigKeyNot quest_eden terminando
IsNotEquippedID armor 15011 #Uniforme Valhalla Avançado
InInventoryID 15011 = 0 #Uniforme Valhalla Avançado
call {
[
log ==================================
log =Iniciando a quest eden do lvl 40
log ==================================
]
do talk $.NpcNearLastBinId
#se vc não tiver feito a quest éden do lvl 12, a conversa é diferente
#de quem fez ela
if (&inventory(Uniforme Valhalla Iniciante) != -1) {
#se tiver o item da quest éden 12, use essa sequência
do talk resp 0
} else {
#se não tiver, use essa sequência
do talk resp 1
do talk resp 0
do talk resp 0
}
do conf -f o_que_estou_fazendo iniciando Quest Eden 40
}
}
automacro questEden60_iniciando {
NpcNear /Ur/
BaseLevel 60..69
ConfigKeyNot fazerQuestEden nao
exclusive 1
InInventoryID 22508 = 1 #Emblema do Éden#
JobID $parametrosClasses{idC2}, $parametrosClasses{idC2Alt}, $parametrosClasses{idC2T}, $parametrosClasses{idC2TAlt}, $parametrosClasses{idBC2}, $parametrosClasses{idBC2Alt}
QuestInactive 7214
ConfigKeyNot naSequenciaDeSalvamento true
ConfigKeyNot quest_eden em_curso
ConfigKeyNot quest_eden terminando
IsNotEquippedID armor 15031 #Armadura do Grupo Éden
InInventoryID 15031 = 0 #Armadura do Grupo Éden
call {
#aqui não importa se fizeram as outras quests ou não
#como o npc é diferente, fica de boas
[
log ===================================
log =Iniciando a quest eden do lvl 60
log ===================================
]
do talk $.NpcNearLastBinId
do talk resp 0
do talk resp 1
do conf -f o_que_estou_fazendo iniciando Quest Eden 60
}
}
automacro questEden_avisoIntermitenteNivel12 {
exclusive 1
QuestActive 7128
BaseLevel 12..15
timeout 120
call {
[
log ======================================
log comecei a quest eden, porém só vou
log fazer ela no lvl 15 ou acima!
log como não to nesse level ainda, vou upar.
log eu estou no lvl $.lvl agora
log ======================================
]
}
}
#Lembrete: quest éden lvl 26 não precisa desse aviso interminente
#porque ele já vai matar no lvl que começa, diferente das outras
automacro questEden_avisoIntermitenteNivel40 {
exclusive 1
QuestActive 7147
BaseLevel 40..49
timeout 180
call {
[
log ======================================
log comecei a quest eden, porém só vou
log fazer ela no lvl 50 ou acima!
log como não to nesse level ainda, vou upar.
log eu estou no lvl $.lvl agora
log ======================================
]
}
}
automacro questEden_avisoIntermitenteNivel60 {
exclusive 1
QuestActive 7214
BaseLevel 60..69
timeout 240
call {
[
log ======================================
log comecei a quest eden, porém só vou
log fazer ela no lvl 70 ou acima!
log como não to nesse level ainda, vou upar.
log eu estou no lvl $.lvl agora
log ======================================
]
}
}
#7128#Grupo Valhalla#SG_FEEL#QUE_NOIMAGE#
#Você começa seu treinamento com o Grupo Valhalla. Procure o cão falante em Sograt. #
#Converse com o cão falante #
automacro questEden12_salvarNaKafra {
QuestActive 7128
exclusive 1
BaseLevel >= 15
ConfigKeyNot naSequenciaDeSalvamento true
ConfigKeyNot saveMap morocc
call {
do conf -f quest_eden em_curso
call salvarNaCidade "morocc"
do conf -f o_que_estou_fazendo quest eden 12
}
}
#7138#Grupo Valhalla#SG_FEEL#QUE_NOIMAGE#
#Seu próximo desafio é em na Caverna de Payon. Procure um representante do Grupo Valhalla. #
#Converse com o representante do Grupo Valhalla #
automacro questEden26_SalvarNaKafra {
QuestActive 7138
BaseLevel >= 26
exclusive 1
ConfigKeyNot naSequenciaDeSalvamento true
ConfigKeyNot saveMap payon
call {
do conf -f quest_eden em_curso
call salvarNaCidade "payon"
do conf -f o_que_estou_fazendo quest eden 26
}
}
#7147#Grupo Valhalla#SG_FEEL#QUE_NOIMAGE#
#Seu próximo desafio é na Vila Orc. Procure um representante do Grupo Valhalla. #
#Converse com o representante do Grupo Valhalla #
automacro questEden40_SalvarNaKafra {
QuestActive 7147
BaseLevel >= 50
exclusive 1
ConfigKeyNot naSequenciaDeSalvamento true
ConfigKeyNot saveMap prontera
call {
do conf -f quest_eden em_curso
call salvarNaCidade "prontera"
do conf -f o_que_estou_fazendo quest eden 40
}
}
#7214#Treino Avançado - Passo 1 - Comodo#SG_FEEL#QUE_NOIMAGE#
#Encontre o Membro do Grupo Éden em frente à entrada da caverna norte de Comodo #
#Fale com Romeo #
automacro questEden60_SalvarNaKafra {
QuestActive 7214
BaseLevel >= 70
exclusive 1
ConfigKeyNot naSequenciaDeSalvamento true
ConfigKeyNot saveMap comodo
call {
do conf -f quest_eden em_curso
call salvarNaCidade "comodo"
do conf -f o_que_estou_fazendo quest eden 60
}
}
#7128#Grupo Valhalla#SG_FEEL#QUE_NOIMAGE#
#Você começa seu treinamento com o Grupo Valhalla. Procure o cão falante em Sograt. #
#Converse com o cão falante #
automacro questEden12_IrNoMapa {
QuestActive 7128
exclusive 1
BaseLevel >= 15
ConfigKeyNot naSequenciaDeSalvamento true
ConfigKey saveMap morocc
call irNoMapa 'moc_fild11' '180 253' '1107' '1001' '1009' #monstros: filhote de lobo, escopião, condor
}
#7138#Grupo Valhalla#SG_FEEL#QUE_NOIMAGE#
#Seu próximo desafio é em na Caverna de Payon. Procure um representante do Grupo Valhalla. #
#Converse com o representante do Grupo Valhalla #
automacro questEden26_IrNoMapa {
QuestActive 7138
BaseLevel >= 26
exclusive 1
ConfigKeyNot naSequenciaDeSalvamento true
ConfigKey saveMap payon
call irNoMapa 'pay_arche' '41 136' '1076' '1031' '1015' #monstros: esqueleto, poporing, zumbi
}
#7147#Grupo Valhalla#SG_FEEL#QUE_NOIMAGE#
#Seu próximo desafio é na Vila Orc. Procure um representante do Grupo Valhalla. #
#Converse com o representante do Grupo Valhalla #
automacro questEden40_IrNoMapa {
QuestActive 7147
BaseLevel >= 50
exclusive 1
ConfigKeyNot naSequenciaDeSalvamento true
ConfigKey saveMap prontera
call irNoMapa 'in_orcs01' '38 175' '1023' '1686' '1273' #monstros: guerreiro orc, filhote de orc, senhora orc
}
#7214#Treino Avançado - Passo 1 - Comodo#SG_FEEL#QUE_NOIMAGE#
#Encontre o Membro do Grupo Éden em frente à entrada da caverna norte de Comodo #
#Fale com Romeo #
automacro questEden60_IrNoMapa {
QuestActive 7214
BaseLevel >= 70
exclusive 1
ConfigKeyNot naSequenciaDeSalvamento true
ConfigKey saveMap comodo
call irNoMapa 'comodo' '173 354'
}
macro irNoMapa {
do conf -f quest_eden em_curso
[
log ===========================
log =indo fazer a quest eden
log ===========================
]
## $.param[0] tem como valor o local do npc
## $.param[1] tem como valor a coordenada x e y
## $.param[2] tem como valor a id do monstro 1
## $.param[3] tem como valor a id do monstro 2
## $.param[4] tem como valor a id do monstro 3
do move $.param[0] $.param[1] &rand(1,5)
do talk &npc($.param[1])
if ($.param[0] = moc_fild11) do talk resp 1 #significa que ta na quest eden 12
if ( &defined($.param[2]) ) { #evita de mostrar linhas vermelhas a toa de "variavel não existe"
do mconf $.param[2] 0 0 0
do mconf $.param[3] 0 0 0
do mconf $.param[4] 0 0 0
}
}
automacro questEden12_Cacar {
QuestHuntOngoing 7129 1009, 7130 1107, 7131 1001
exclusive 1
timeout 120
call cacarMonstros "moc_fild11" "12"
}
automacro questEden26_Cacar {
QuestHuntOngoing 7139 1076, 7140 1031
exclusive 1
timeout 180
call cacarMonstros "pay_dun00" "26"
}
automacro questEden40_Cacar {
QuestHuntOngoing 7148 1686, 7149 1023, 7150 1273
exclusive 1
timeout 180
JobLevel != 50
call cacarMonstros "gef_fild10" "40"
}
automacro questEden60_Cacar {
QuestHuntOngoing 7215 1278, 7216 1278
exclusive 1
timeout 60
call cacarMonstros "beach_dun2" "60"
}
macro cacarMonstros {
## $.param[0] tem como valor o lockMap que o bot
## vai caçar os monstros
if (&config(quest_eden) != em_curso) do conf -f quest_eden em_curso
[
call voltarAtacar
if ( &config(lockMap) != $.param[0]) do conf lockMap $.param[0]
do mconf $.QuestHuntOngoingLastMobID 2 0 0
## $.param[1] tem como valor o lvl da quest
log ===========================================
log =caçando monstro da quest eden $.param[1]
log ===========================================
]
}
#7217#Treino Avançado - Passo 1.3 - Comodo#SG_FEEL#QUE_NOIMAGE#
#Romeo te passou uma última missão. Derrote Guerreiros Wootan e Dríades para conseguir alguns itens #
#Traga 5 Ombreiras, 7 Folhas Afiadas #
automacro questEden60__JuntarItens {
QuestActive 7217
exclusive 1
timeout 120
call {
do iconf 7196 5 1 0 #ombreira
do iconf 7100 7 1 0 #folha
$qtdOmbreira = &invamount (7196)
$qtdFolha = &invamount (7100)
if (&config(quest_eden) != em_curso) do conf -f quest_eden em_curso
do conf -f o_que_estou_fazendo quest eden 60 coletandoItens
if ( $qtdOmbreira < 5 ) {
[
log ===========================================
log = coletando Ombreiras pra quest eden
log = tenho: $qtdOmbreira , Quero: 5 , Falta: &eval(5 - $qtdOmbreira)
log ===========================================
]
do conf lockMap um_fild02
call voltarAtacar
} elsif ( $qtdOmbreira >= 5 && $qtdFolha < 7 ) {
[
log ===========================================
log = coletando Folha Afiada pra quest eden
log = tenho: $qtdFolha , Quero: 7 , Falta: &eval(7 - $qtdFolha)
log ===========================================
]
do conf lockMap um_fild01
call voltarAtacar
}
}
}
#7217#Treino Avançado - Passo 1.3 - Comodo#SG_FEEL#QUE_NOIMAGE#
#Romeo te passou uma última missão. Derrote Guerreiros Wootan e Dríades para conseguir alguns itens #
#Traga 5 Ombreiras, 7 Folhas Afiadas #
automacro questEden60__JaJunteiOsItens {
InInventoryID 7196 >= 5 #Ombreira
InInventoryID 7100 >= 7 #Folha Afiada
QuestActive 7217
CurrentHP > 80%
exclusive 1
call {
lock questEden60__JuntarItens
[
log ===================================
log Ombreira e Folha Afiada coletada
log vou ao npc entregar
log ===================================
]
if (&config(quest_eden) != em_curso) do conf -f quest_eden em_curso
call pararDeAtacarApenasCorrer
do move um_fild01 &rand(36,38) &rand(277,279)
do talknpc 34 280 c #Romeo#2nd02
do iconf 7196 0 0 1 #ombreira
do iconf 7100 0 0 1 #folha
}
}
automacro questEden12_FinalizarCacas {
QuestHuntCompleted 7129 1009, 7130 1107, 7131 1001
exclusive 1
call {
call pararDeAtacar
if (&config(quest_eden) != em_curso) do conf -f quest_eden em_curso
do mconf $.QuestHuntCompletedLastMobID 0 0 0
[
log ===========================================
log =completei a caça, indo falar com o Cão falante
log ===========================================
]
do move moc_fild11 &rand(181,183) &rand(254,256)
do talk 0 #Cão falante
release questEden12_Cacar
}
}
automacro questEden26_FinalizarCacas {
QuestHuntCompleted 7139 1076, 7140 1031
exclusive 1
call {
call pararDeAtacar
if (&config(quest_eden) != em_curso) do conf -f quest_eden em_curso
do mconf $.QuestHuntCompletedLastMobID 0 0 0
[
log ===========================================
log =completei a caça, indo falar com o Coral
log ===========================================
]
do move pay_arche &rand(44,46) &rand(132,134)
#do talknpc 41 136 c c c c c #Coral
do talk &npc( 41 136 ) #Coral
release questEden26_Cacar
}
}
automacro questEden40_FinalizarCacas {
QuestHuntCompleted 7148 1686, 7149 1023, 7150 1273
exclusive 1
call {
call pararDeAtacar
if (&config(quest_eden) != em_curso) do conf -f quest_eden em_curso
do mconf $.QuestHuntCompletedLastMobID 0 0 0
[
log ===========================================
log =completei a caça, indo falar com o Absalom
log ===========================================
]
do move in_orcs01 38 175 &rand(1,4)
#do talknpc 38 175 c c #Absalom#para07
do talk 0 #Absalom
release questEden40_Cacar
}
}
automacro questEden60_FinalizarCacas {
QuestHuntCompleted 7215 1278, 7216 1278
exclusive 1
call {
if (&config(quest_eden) != em_curso) do conf -f quest_eden em_curso
do mconf $.QuestHuntCompletedLastMobID 0 0 0
[
log ===========================================
log =completei a caça, indo falar com o npc do eden
log ===========================================
]
switch ( $.QuestHuntCompletedLastQuestID ) {
case (= 7215) { #golem1
do move comodo &rand(174,176) &rand(344,346)
#do talknpc 173 354 c c c c c #Mémbro do grupo Éden#2n
do talk &npc( 173 354 )
release questEden60_Cacar
}
case (= 7216) { #golem2
do move um_fild01 &rand(36,38) &rand(277,279)
#do talknpc 34 280 c c c c #Romeo#2nd02
do talk &npc( 34 280 )
release questEden60_Cacar
}
}
}
}
#7132#Grupo Valhalla#SG_FEEL#QUE_NOIMAGE#
#Você completou todas as tarefas do cão falante. Fale com o membro do Grupo Valhalla. #
#Vá ao escritório do Grupo Valhalla #
#7141#Grupo Valhalla#SG_FEEL#QUE_NOIMAGE#
#Você completou todas as tarefas. Fale com o membro do Grupo Valhalla. #
#Vá ao escritório do Grupo Valhalla #
#7151#Grupo Valhalla#SG_FEEL#QUE_NOIMAGE#
#Você completou todas as tarefas. Fale com o membro do Grupo Valhalla. #
#Vá ao escritório do Grupo Valhalla #
#7218#Reporte para Uru#SG_FEEL#QUE_NOIMAGE#
#Você completou este passo do Grupo Éden. Você pode voltar para a sede do Grupo Éden. #
#Reporte para Uru #
automacro questEden_voltarDoMapaMoverPerto {
QuestActive 7132, 7141, 7151, 7218
NpcNotNear /Boya|Ur/
exclusive 1
call {
if (&config(quest_eden) != em_curso) do conf -f quest_eden em_curso
[
log ===========================================
log Completei as Caças!
log vamo lá pegar meus equips de direito!
log ===========================================
]
do conf -f o_que_estou_fazendo quest eden completada voltando para pegar equips
call moverPertoDosNpcEden
}
}
#7132#Grupo Valhalla#SG_FEEL#QUE_NOIMAGE#
#Você completou todas as tarefas do cão falante. Fale com o membro do Grupo Valhalla. #
#Vá ao escritório do Grupo Valhalla #
#7141#Grupo Valhalla#SG_FEEL#QUE_NOIMAGE#
#Você completou todas as tarefas. Fale com o membro do Grupo Valhalla. #
#Vá ao escritório do Grupo Valhalla #
#7151#Grupo Valhalla#SG_FEEL#QUE_NOIMAGE#
#Você completou todas as tarefas. Fale com o membro do Grupo Valhalla. #
#Vá ao escritório do Grupo Valhalla #
#7218#Reporte para Uru#SG_FEEL#QUE_NOIMAGE#
#Você completou este passo do Grupo Éden. Você pode voltar para a sede do Grupo Éden. #
#Reporte para Uru #
automacro questEden_voltarDoMapa {
QuestActive 7132, 7141, 7151, 7218
NpcNear /Boya|Ur/
exclusive 1
call {
#7132 : eden 12
#7141 : eden 26
#7151 : eden 40
#7218 : eden 60
if (&config(quest_eden) != em_curso) do conf -f quest_eden em_curso
[
log ===========================================
log =terminando a quest eden, falando com o npc
log ===========================================
]
switch ($.QuestActiveLastID) {
case (= 7132) { #eden 12
#do talknpc 25 35 c c c #Boya
do talk &npc(/Boya/)
do mconf 1107 1 0 0 #Filhote de lobo
do mconf 1001 1 0 0 #escorpiao
do mconf 1009 1 0 0 #Condor
}
case (= 7141) { #eden 26
#do talknpc 25 35 c c #Boya
do talk &npc(/Boya/)
do mconf 1076 1 0 0 #Esqueleto
do mconf 1031 1 0 0 #poporing
do mconf 1015 1 0 0 #Zumbi
}
case (= 7151) { #eden 40
#do talknpc 25 35 c c #Boya
do talk &npc(/Boya/)
do mconf 1023 1 0 0 #Guerreiro Orc
do mconf 1686 1 0 0 #Filhote de Orc
do mconf 1273 1 0 0 #Senhora Orc
}
case (= 7218) { #eden 60
#do talknpc 23 35 c c c #Uru
do talk &npc(/Ur/)
}
}
if (&questInactiveCount(7132, 7141, 7151, 7218) = 4) {
do conf -f quest_eden terminando
} else {
[
log ===================================
log = acredito que há uma treta no término da quest Éden
log ===================================
]
}
}
}
automacro EdenPegandoEquips_IndoProNpc {
NpcNotNear /hael/i
ConfigKey quest_eden terminando
BaseLevel 12..99
exclusive 1
call {
do move moc_para01 48 37 #portal que antes era porta
do move moc_para01 &rand(112,114) &rand(31,33)
}
}
automacro questEden12e26e40_PegandoEquips {
ConfigKey quest_eden terminando
BaseLevel 12..59
timeout 120
NpcNear /hael/i
call {
[
log ===========================================
log =falando com o Mihael pra ganhar meus equips
log ===========================================
]
do conf -f o_que_estou_fazendo quest eden pegando Meus Equips de Direito
do talk &npc(/hael/i)
do talk resp 0
do talk resp 1
do talk resp /$parametrosQuestEden{armaLevel26e40}/i
if ( $.lvl >= 40 ) {
#pegar encantamento do chapeu valhalla
do talk &npc(/hael/i)
do talk resp 2
do talk resp 4
do talk resp 0
}
}
}
automacro questEden12e26e40_acabeiDePegarEquips {
ConfigKey quest_eden terminando
BaseLevel 12..59
NpcNear /hael/i
exclusive 1
SimpleHookEvent item_gathered
call {
do conf -f quest_eden none
do conf -f o_que_estou_fazendo acabei de Terminar Quest Eden
release equipandoArmaEden
release equipandoArmaduraEden
release equipandoBotaEden
release equipandoChapeuEden
release equipandoCapaEden
}
}
automacro questEden60_PegandoEquips {
ConfigKey quest_eden terminando
BaseLevel 70..98
timeout 120
NpcNear /Ferreiro|smith/i
call {
[
log ===========================================
log =falando com o ferreiro pra ganhar meus equips
log ===========================================
]
do conf -f o_que_estou_fazendo quest eden 60 pegando Meus Equips de Direito
#do talknpc 111 83 c r2 c c r1 #Ferreiro Torhen#2nd10
do talk $.NpcNearLastBinId
do talk resp 2
do talk resp 1
do talk resp /$parametrosQuestEden{armaLevel60}/i
}
}
automacro questEden60_acabeiDePegarEquips {
ConfigKey quest_eden terminando
BaseLevel 70..98
exclusive 1
NpcNear /Ferreiro|smith/i
SimpleHookEvent item_gathered
call {
do conf -f quest_eden none
do conf -f o_que_estou_fazendo acabei De Terminar Quest Eden 60
release equipandoArmaEden
release equipandoArmaduraEden
release equipandoBotaEden
release equipandoChapeuEden
release equipandoCapaEden
}
}
automacro equipandoArmaEden {
BaseLevel 1..98 #não quero checar por armas no lvl 99, pode dar treta
JobIDNot 0 #aprendiz
JobIDNot 4023 # baby aprendiz
overrideAI 1
run-once 1
exclusive 1
call equiparArma
}
macro equiparArma {
#se tiver alguma arma equipada e ela não for do eden ou iniciante, então não faça nada
if (checarSlot("rightHand") = "tem equip" && !pegarNomeDoItemEquipado(rightHand) =~ /Iniciante|Valhalla|Éden/i) {
stop
}
if ($.lvl >= 60 && &inventory($parametrosQuestEden{IDarmaEden}) != -1) {
do eq &inventory($parametrosQuestEden{IDarmaEden})
} elsif ($.lvl >= 40 && &inventory($parametrosQuestEden{IDarmaIntermediario}) != -1) {
do eq &inventory($parametrosQuestEden{IDarmaIntermediario})
} elsif ($.lvl >= 26 && &inventory($parametrosQuestEden{IDarmaIniciante}) != -1) {
do eq &inventory($parametrosQuestEden{IDarmaIniciante})
} elsif ($.lvl >= 1 && &inventory($parametrosQuestClasse1{equipeIniciante}) != -1) {
do eq &inventory($parametrosQuestClasse1{equipeIniciante})
} else {
if (checarSlot("rightHand") = "ta vazio") {
[
error Erro: não foi encontrado nenhuma arma éden para equipar
error Seu bot ta batendo na mao
error A eventMacro não pode fazer nada a respeito disso
]
} else {
[
error Erro desconhecido ao tentar encontrar uma arma para equipar
error Você está com " pegarNomeDoItemEquipado(rightHand) " equipado, não deveria aparecer esse erro
error Caso você esteja lendo isso, contate os criadores da eventMacro
]
call informacoes
}
}
}
automacro equipandoArmaduraEden {
BaseLevel 12..98 #não quero checar por armaduras no lvl 99, pode dar treta
JobIDNot 0 #aprendiz
JobIDNot 4023 # baby aprendiz
overrideAI 1
run-once 1
exclusive 1
call equiparArmadura
}
macro equiparArmadura {
#se tiver alguma armadura equipada e ela não for do eden ou iniciante, então não faça nada
if (checarSlot(armor) = "tem equip" && !pegarNomeDoItemEquipado(armor) =~ /Iniciante|Valhalla|Éden/i) {
stop
}
#15009) #Uniforme Valhalla Iniciante
#15010) #Uniforme Valhalla Intermediário
#15011) #Uniforme Valhalla Avançado
#15031) #Armadura_do_Grupo_Éden#
if ($.lvl >= 60 && &inventory(15031) != -1) { #Armadura_do_Grupo_Éden#
log = Vou equipar armadura do lvl 60+
do eq &inventory(15031) #Armadura_do_Grupo_Éden#
} elsif ($.lvl >= 40 && &inventory(15011) != -1) { #Uniforme Valhalla Avançado
log = Vou equipar armadura do lvl 40+
do eq &inventory(15011) #Uniforme Valhalla Avançado
} elsif ($.lvl >= 26 && &inventory(15010) != -1) { #Uniforme Valhalla Intermediário
log = Vou equipar armadura do lvl 26+
do eq &inventory(15010) #Uniforme Valhalla Intermediário
} elsif ($.lvl >= 12 && &inventory(15009) != -1) { #Uniforme Valhalla Iniciante
log = Vou equipar armadura do lvl 12+ que não é eden mas é bom
do eq &inventory(15009) #Uniforme Valhalla Iniciante
}
#sem um else aqui, porque se o slot tiver vazio, e não tiver nenhum do éden, fodas, ninguém liga
}
automacro equipandoBotaEden {
BaseLevel 12..98 #não quero checar por armas no lvl 99, pode dar treta
JobIDNot 0 #aprendiz
JobIDNot 4023 # baby aprendiz
overrideAI 1
run-once 1
exclusive 1
call equiparBota
}
macro equiparBota {
#se tiver alguma bota equipada e ela não for do eden ou iniciante, então não faça nada
if (checarSlot(rightHand) = "tem equip" && !pegarNomeDoItemEquipado(rightHand) =~ /Iniciante|Valhalla|Éden/i) {
stop
}
# 2456) #Botas Valhalla Iniciante
# 2457) #Botas Valhalla Intermediárias
# 2458) #Botas Valhalla Avançadas
# 2473) ##Botas_IV_do_Grupo_Éden#
if ($.lvl >= 60 && &inventory(2473) != -1) { ##Botas_IV_do_Grupo_Éden#
log = Vou equipar bota do lvl 60+
do eq &inventory(2473) ##Botas_IV_do_Grupo_Éden#
} elsif ($.lvl >= 40 && &inventory(2458) != -1) { #Botas Valhalla Avançadas
log = Vou equipar bota do lvl 40+
do eq &inventory(2458) #Botas Valhalla Avançadas
} elsif ($.lvl >= 26 && &inventory(2457) != -1) { #Botas Valhalla Intermediárias
log = Vou equipar bota do lvl 26+
do eq &inventory(2457) #Botas Valhalla Intermediárias
} elsif ($.lvl >= 12 && &inventory(2456) != -1) { #Botas Valhalla Iniciante
log = Vou equipar bota do lvl 12+ que não é eden mas é bom
do eq &inventory(2456) #Botas Valhalla Iniciante
}
#sem um else aqui, porque se o slot tiver vazio, e não tiver nenhum do éden, fodas, ninguém liga
}
automacro equipandoChapeuEden {
BaseLevel 12..98 #não quero checar por armas no lvl 99, pode dar treta
JobIDNot 0 #aprendiz
JobIDNot 4023 # baby aprendiz