forked from philpw99/Stash_Helper
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathwd_core.au3
1772 lines (1507 loc) · 68.3 KB
/
wd_core.au3
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
#include-once
#include <WinAPIProc.au3>
#include "JSON.au3" ; https://www.autoitscript.com/forum/topic/148114-a-non-strict-json-udf-jsmn
#include "WinHttp.au3" ; https://www.autoitscript.com/forum/topic/84133-winhttp-functions/
#Region Copyright
#cs
* WD_Core.au3
*
* MIT License
*
* Copyright (c) 2021 Dan Pollak
*
* Permission is hereby granted, free of charge, to any person obtaining a copy
* of this software and associated documentation files (the "Software"), to deal
* in the Software without restriction, including without limitation the rights
* to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
* copies of the Software, and to permit persons to whom the Software is
* furnished to do so, subject to the following conditions:
*
* The above copyright notice and this permission notice shall be included in all
* copies or substantial portions of the Software.
*
* THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
* IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
* FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
* AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
* LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
* OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
* SOFTWARE.
#ce
#EndRegion Copyright
#ignorefunc _WD_IsLatestRelease
#Region Description
; ==============================================================================
; UDF ...........: WD_Core.au3
; Description ...: A UDF for Web Driver automation
; Requirement ...: JSON UDF
; https://www.autoitscript.com/forum/topic/148114-a-non-strict-json-udf-jsmn
; WinHTTP UDF
; https://www.autoitscript.com/forum/topic/84133-winhttp-functions/
;
; WebDriver for desired browser
; Chrome WebDriver https://sites.google.com/a/chromium.org/chromedriver/downloads
; FireFox WebDriver https://github.com/mozilla/geckodriver/releases
; Edge WebDriver https://developer.microsoft.com/en-us/microsoft-edge/tools/webdriver/
;
; Discussion Thread on Autoit Forums
; https://www.autoitscript.com/forum/topic/191990-webdriver-udf-w3c-compliant-version
;
; Author(s) .....: Dan Pollak
; AutoIt Version : v3.3.14.5
; ==============================================================================
#EndRegion Description
#Region Copyright
#cs
* WD_Core.au3
*
* MIT License
*
* Copyright (c) 2020 Dan Pollak
*
* Permission is hereby granted, free of charge, to any person obtaining a copy
* of this software and associated documentation files (the "Software"), to deal
* in the Software without restriction, including without limitation the rights
* to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
* copies of the Software, and to permit persons to whom the Software is
* furnished to do so, subject to the following conditions:
*
* The above copyright notice and this permission notice shall be included in all
* copies or substantial portions of the Software.
*
* THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
* IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
* FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
* AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
* LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
* OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
* SOFTWARE.
#ce
#EndRegion Copyright
#Region Many thanks to:
#cs
- Jonathan Bennett and the AutoIt Team
- Thorsten Willert, author of FF.au3, which I've used as a model
- Michal Lipok for all his feedback / suggestions
#ce
#EndRegion Many thanks to:
#Region Global Constants
Global Const $__WDVERSION = "0.4.1.1"
Global Const $_WD_ELEMENT_ID = "element-6066-11e4-a52e-4f735466cecf"
Global Const $_WD_SHADOW_ID = "shadow-6066-11e4-a52e-4f735466cecf"
Global Const $_WD_EmptyDict = "{}"
Global Const $_WD_LOCATOR_ByCSSSelector = "css selector"
Global Const $_WD_LOCATOR_ByXPath = "xpath"
Global Const $_WD_LOCATOR_ByLinkText = "link text"
Global Const $_WD_LOCATOR_ByPartialLinkText = "partial link text"
Global Const $_WD_LOCATOR_ByTagName = "tag name"
Global Enum _
$_WD_DEBUG_None = 0, _ ; No logging to console
$_WD_DEBUG_Error, _ ; Error logging to console
$_WD_DEBUG_Info ; Full logging to console
Global Enum _
$_WD_ERROR_Success = 0, _ ; No error
$_WD_ERROR_GeneralError, _ ; General error
$_WD_ERROR_SocketError, _ ; No socket
$_WD_ERROR_InvalidDataType, _ ; Invalid data type (IP, URL, Port ...)
$_WD_ERROR_InvalidValue, _ ; Invalid value in function-call
$_WD_ERROR_InvalidArgue, _ ; Invalid argument in function-call
$_WD_ERROR_SendRecv, _ ; Send / Recv Error
$_WD_ERROR_Timeout, _ ; Connection / Send / Recv timeout
$_WD_ERROR_NoMatch, _ ; No match for _WDAction-find/search _WDGetElement...
$_WD_ERROR_RetValue, _ ; Error echo from Repl e.g. _WDAction("fullscreen","true") <> "true"
$_WD_ERROR_Exception, _ ; Exception from web driver
$_WD_ERROR_InvalidExpression, _ ; Invalid expression in XPath query or RegEx
$_WD_ERROR_NoAlert, _ ; No alert present when calling _WD_Alert
$_WD_ERROR_NotFound, _ ;
$_WD_ERROR_ElementIssue, _ ;
$_WD_ERROR_SessionInvalid, _ ;
$_WD_ERROR_UnknownCommand, _ ;
$_WD_ERROR_UserAbort, _ ;
$_WD_ERROR_COUNTER ;
Global Const $aWD_ERROR_DESC[$_WD_ERROR_COUNTER] = [ _
"Success", _
"General Error", _
"Socket Error", _
"Invalid data type", _
"Invalid value", _
"Invalid argument", _
"Send / Recv error", _
"Timeout", _
"No match", _
"Error return value", _
"Webdriver Exception", _
"Invalid Expression", _
"No alert present", _
"Not found", _
"Element interaction issue", _
"Invalid session ID", _
"Unknown Command", _
"User Aborted" _
]
Global Const $WD_ErrorInvalidSession = "invalid session id"
Global Const $WD_ErrorUnknownCommand = "unknown command"
Global Const $WD_ErrorTimeout = "timeout"
Global Const $WD_Element_NotFound = "no such element"
Global Const $WD_Element_Stale = "stale element reference"
Global Const $WD_Element_Invalid = "invalid argument"
Global Const $WD_Element_Intercept = "element click intercepted"
Global Const $WD_Element_NotInteract = "element not interactable"
Global Const $WD_WinHTTPTimeoutMsg = "WinHTTP request timed out before Webdriver"
#EndRegion Global Constants
#Region Global Variables
Global $_WD_DRIVER = "" ; Path to web driver executable
Global $_WD_DRIVER_PARAMS = "" ; Parameters to pass to web driver executable
Global $_WD_BASE_URL = "HTTP://127.0.0.1"
Global $_WD_PORT = 0 ; Port used for web driver communication
Global $_WD_OHTTP = ObjCreate("winhttp.winhttprequest.5.1")
Global $_WD_HTTPRESULT ; Result of last WinHTTP request
Global $_WD_SESSION_DETAILS = "" ; Response from _WD_CreateSession
Global $_WD_BFORMAT = $SB_UTF8 ; Binary format
Global $_WD_ESCAPE_CHARS = '\\"' ; Characters to escape
Global $_WD_DRIVER_CLOSE = True ; Close prior driver instances before launching new one
Global $_WD_DRIVER_DETECT = True ; Don't launch new driver instance if one already exists
Global $_WD_RESPONSE_TRIM = 100 ; Trim response string to given value for debug output
Global $_WD_ERROR_MSGBOX = True ; Shows in compiled scripts error messages in msgboxes
Global $_WD_DEBUG = $_WD_DEBUG_Info ; Trace to console and show web driver app
Global $_WD_CONSOLE = Default ; Destination for console output
Global $_WD_IFILTER = 16 ; Passed to _HtmlTableGetWriteToArray to control filtering
Global $_WD_Sleep = Sleep ; Default to calling standard Sleep function
Global $_WD_DefaultTimeout = 10000 ; 10 seconds
Global $_WD_WINHTTP_TIMEOUTS = True
Global $_WD_HTTPTimeOuts[4] = [0, 60000, 30000, 30000]
Global $_WD_HTTPContentType = "Content-Type: application/json"
#EndRegion Global Variables
; #FUNCTION# ====================================================================================================================
; Name ..........: _WD_CreateSession
; Description ...: Request new session from web driver
; Syntax ........: _WD_CreateSession([$sDesiredCapabilities = Default])
; Parameters ....: $sDesiredCapabilities- [optional] a string value. Default is '{}'.
; Return values .: Success - Session ID to be used in future requests to web driver session
; Failure - Empty string
; @ERROR - $_WD_ERROR_Success
; - $_WD_ERROR_Exception
; @EXTENDED - WinHTTP status code
; Author ........: Dan Pollak
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........: https://www.w3.org/TR/webdriver#new-session
; Example .......: No
; ===============================================================================================================================
Func _WD_CreateSession($sDesiredCapabilities = Default)
Local Const $sFuncName = "_WD_CreateSession"
Local $sSession = ""
If $sDesiredCapabilities = Default Then $sDesiredCapabilities = $_WD_EmptyDict
Local $sResponse = __WD_Post($_WD_BASE_URL & ":" & $_WD_PORT & "/session", $sDesiredCapabilities)
Local $iErr = @error
If $_WD_DEBUG = $_WD_DEBUG_Info Then
__WD_ConsoleWrite($sFuncName & ': ' & $sResponse & @CRLF)
EndIf
If $iErr = $_WD_ERROR_Success Then
Local $oJSON = Json_Decode($sResponse)
$sSession = Json_Get($oJSON, "[value][sessionId]")
If @error Then
Local $sMessage = Json_Get($oJSON, "[value][message]")
Return SetError(__WD_Error($sFuncName, $_WD_ERROR_Exception, $sMessage), $_WD_HTTPRESULT, "")
EndIf
Else
Return SetError(__WD_Error($sFuncName, $_WD_ERROR_Exception, "HTTP status = " & $_WD_HTTPRESULT), $_WD_HTTPRESULT, "")
EndIf
; Save response details for future use
$_WD_SESSION_DETAILS = $sResponse
Return SetError($_WD_ERROR_Success, $_WD_HTTPRESULT, $sSession)
EndFunc ;==>_WD_CreateSession
; #FUNCTION# ====================================================================================================================
; Name ..........: _WD_DeleteSession
; Description ...: Delete existing session
; Syntax ........: _WD_DeleteSession($sSession)
; Parameters ....: $sSession - Session ID from _WD_CreateSession
; Return values .: Success - 1
; Failure - 0
; @ERROR - $_WD_ERROR_Success
; - $_WD_ERROR_Exception
; @EXTENDED - WinHTTP status code
; Author ........: Dan Pollak
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........: https://www.w3.org/TR/webdriver#delete-session
; Example .......: No
; ===============================================================================================================================
Func _WD_DeleteSession($sSession)
Local Const $sFuncName = "_WD_DeleteSession"
Local $sResponse = __WD_Delete($_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession)
Local $iErr = @error
If $_WD_DEBUG = $_WD_DEBUG_Info Then
__WD_ConsoleWrite($sFuncName & ': ' & $sResponse & @CRLF)
EndIf
If $iErr Then
Return SetError(__WD_Error($sFuncName, $_WD_ERROR_Exception, "HTTP status = " & $_WD_HTTPRESULT), $_WD_HTTPRESULT, 0)
EndIf
Return SetError($_WD_ERROR_Success, $_WD_HTTPRESULT, 1)
EndFunc ;==>_WD_DeleteSession
; #FUNCTION# ====================================================================================================================
; Name ..........: _WD_Status
; Description ...: Get current web driver state
; Syntax ........: _WD_Status()
; Parameters ....:
; Return values .: Success - Dictionary object with "message" and "ready" items
; Failure - ''
; @ERROR - $_WD_ERROR_Success
; - $_WD_ERROR_Exception
; @EXTENDED - WinHTTP status code
; Author ........: Dan Pollak
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........: https://www.w3.org/TR/webdriver#status
; Example .......: No
; ===============================================================================================================================
Func _WD_Status()
Local Const $sFuncName = "_WD_Status"
Local $sResponse = __WD_Get($_WD_BASE_URL & ":" & $_WD_PORT & "/status")
Local $iErr = @error, $oResult = Null
If $iErr = $_WD_ERROR_Success Then
Local $oJSON = Json_Decode($sResponse)
$oResult = Json_Get($oJSON, "[value]")
EndIf
If $_WD_DEBUG = $_WD_DEBUG_Info Then
__WD_ConsoleWrite($sFuncName & ': ' & $sResponse & @CRLF)
EndIf
If $iErr Then
Return SetError(__WD_Error($sFuncName, $iErr, "HTTP status = " & $_WD_HTTPRESULT), $_WD_HTTPRESULT, 0)
EndIf
Return SetError($_WD_ERROR_Success, $_WD_HTTPRESULT, $oResult)
EndFunc ;==>_WD_Status
; #FUNCTION# ====================================================================================================================
; Name ..........: _WD_GetSession
; Description ...: Get details on existing session
; Syntax ........: _WD_GetSession($sSession)
; Parameters ....: $sSession - Session ID from _WD_CreateSession
; Return values .: Success - Dictionary object with "sessionId" and "capabilities" items
; Failure - ''
; @ERROR - $_WD_ERROR_Success
; - $_WD_ERROR_Exception
; @EXTENDED - WinHTTP status code
; Author ........: Dan Pollak
; Modified ......:
; Remarks .......: The Get Session functionality was added and then removed from the W3C draft spec, so the code is commented
; until they determine how this should function. See w3c/webdriver@35df53a for details. Meanwhile, I temporarily
; changed the code to return the information that is available
; Related .......:
; Link ..........: https://www.w3.org/TR/webdriver#get-session
; Example .......: No
; ===============================================================================================================================
Func _WD_GetSession($sSession)
Local Const $sFuncName = "_WD_GetSession"
Local $sResult
#forceref $sSession, $sFuncName
; This function is not good. Don't use.
Local $sResponse = __WD_Get($_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession)
Local $iErr = @error, $sResult = ''
If $_WD_DEBUG = $_WD_DEBUG_Info Then
__WD_ConsoleWrite($sFuncName & ': ' & $sResponse & @CRLF)
EndIf
If $iErr = $_WD_ERROR_Success Then
Local $oJSON = Json_Decode($sResponse)
$sResult = Json_Get($oJSON, "[value]")
Return SetError($_WD_ERROR_Success, $_WD_HTTPRESULT, $sResult)
Else
Return SetError(__WD_Error($sFuncName, $_WD_ERROR_Exception, "HTTP status = " & $_WD_HTTPRESULT), $_WD_HTTPRESULT, $sResult)
EndIf
EndFunc ;==>_WD_GetSession
; #FUNCTION# ====================================================================================================================
; Name ..........: _WD_Timeouts
; Description ...: Set or retrieve the session timeout parameters
; Syntax ........: _WD_Timeouts($sSession[, $sTimeouts = Default])
; Parameters ....: $sSession - Session ID from _WD_CreateSession
; $sTimeouts - [optional] a string value. Default is ''.
; Return values .: Success - Raw return value from web driver in JSON format
; Failure - 0
; @ERROR - $_WD_ERROR_Success
; - $_WD_ERROR_Exception
; @EXTENDED - WinHTTP status code
; Author ........: Dan Pollak
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........: https://www.w3.org/TR/webdriver#get-timeouts
; https://www.w3.org/TR/webdriver#set-timeouts
; Example .......: No
; ===============================================================================================================================
Func _WD_Timeouts($sSession, $sTimeouts = Default)
Local Const $sFuncName = "_WD_Timeouts"
Local $sResponse, $sURL
If $sTimeouts = Default Then $sTimeouts = ''
$sURL = $_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession & "/timeouts"
If $sTimeouts = '' Then
$sResponse = __WD_Get($sURL)
Else
$sResponse = __WD_Post($sURL, $sTimeouts)
EndIf
Local $iErr = @error
If $_WD_DEBUG = $_WD_DEBUG_Info Then
__WD_ConsoleWrite($sFuncName & ': ' & $sResponse & @CRLF)
EndIf
If $iErr Then
Return SetError(__WD_Error($sFuncName, $iErr, "HTTP status = " & $_WD_HTTPRESULT), $_WD_HTTPRESULT, 0)
EndIf
Return SetError($_WD_ERROR_Success, $_WD_HTTPRESULT, $sResponse)
EndFunc ;==>_WD_Timeouts
; #FUNCTION# ====================================================================================================================
; Name ..........: _WD_Navigate
; Description ...: Navigate to the designated URL
; Syntax ........: _WD_Navigate($sSession, $sURL)
; Parameters ....: $sSession - Session ID from _WD_CreateSession
; $sURL - Destination URL
; Return values .: Success - 1
; Failure - 0
; @ERROR - $_WD_ERROR_Success
; - $_WD_ERROR_Exception
; - $_WD_ERROR_Timeout
; @EXTENDED - WinHTTP status code
; Author ........: Dan Pollak
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........: https://www.w3.org/TR/webdriver#navigate-to
; Example .......: No
; ===============================================================================================================================
Func _WD_Navigate($sSession, $sURL)
Local Const $sFuncName = "_WD_Navigate"
Local $sResponse = __WD_Post($_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession & "/url", '{"url":"' & $sURL & '"}')
Local $iErr = @error
If $_WD_DEBUG = $_WD_DEBUG_Info Then
__WD_ConsoleWrite($sFuncName & ': ' & $sResponse & @CRLF)
EndIf
If $iErr Then
Return SetError(__WD_Error($sFuncName, $iErr, "HTTP status = " & $_WD_HTTPRESULT), $_WD_HTTPRESULT, 0)
EndIf
Return SetError($_WD_ERROR_Success, $_WD_HTTPRESULT, 1)
EndFunc ;==>_WD_Navigate
; #FUNCTION# ====================================================================================================================
; Name ..........: _WD_Action
; Description ...: Perform various interactions with the web driver session
; Syntax ........: _WD_Action($sSession, $sCommand[, $sOption = Default])
; Parameters ....: $sSession - Session ID from _WD_CreateSession
; $sCommand - one of the following actions:
; | refresh
; | back
; | forward
; | url
; | title
; | actions
; $sOption - [optional] a string value. Default is ''.
; Return values .: Success - Return value from web driver (could be an empty string)
; Failure - ""
; @ERROR - $_WD_ERROR_Success
; - $_WD_ERROR_Exception
; - $_WD_ERROR_InvalidDataType
; @EXTENDED - WinHTTP status code
; Author ........: Dan Pollak
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........: https://www.w3.org/TR/webdriver#navigation
; https://www.w3.org/TR/webdriver#actions
; Example .......: No
; ===============================================================================================================================
Func _WD_Action($sSession, $sCommand, $sOption = Default)
Local Const $sFuncName = "_WD_Action"
Local $sResponse, $sResult = "", $iErr, $oJSON, $sURL
If $sOption = Default Then $sOption = ''
$sCommand = StringLower($sCommand)
$sURL = $_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession & "/" & $sCommand
Switch $sCommand
Case 'back', 'forward', 'refresh'
$sResponse = __WD_Post($sURL, $_WD_EmptyDict)
$iErr = @error
Case 'url', 'title'
$sResponse = __WD_Get($sURL)
$iErr = @error
If $iErr = $_WD_ERROR_Success Then
$oJSON = Json_Decode($sResponse)
$sResult = Json_Get($oJSON, "[value]")
EndIf
Case 'actions'
If $sOption <> '' Then
$sResponse = __WD_Post($sURL, $sOption)
Else
$sResponse = __WD_Delete($sURL)
EndIf
$iErr = @error
Case Else
Return SetError(__WD_Error($sFuncName, $_WD_ERROR_InvalidDataType, "(Back|Forward|Refresh|Url|Title|Actions) $sCommand=>" & $sCommand), 0, "")
EndSwitch
If $_WD_DEBUG = $_WD_DEBUG_Info Then
__WD_ConsoleWrite($sFuncName & ': ' & $sResponse & @CRLF)
EndIf
If $iErr Then
Return SetError(__WD_Error($sFuncName, $iErr, "HTTP status = " & $_WD_HTTPRESULT), $_WD_HTTPRESULT, "")
EndIf
Return SetError($_WD_ERROR_Success, $_WD_HTTPRESULT, $sResult)
EndFunc ;==>_WD_Action
; #FUNCTION# ====================================================================================================================
; Name ..........: _WD_Window
; Description ...: Perform interactions related to the current window
; Syntax ........: _WD_Window($sSession, $sCommand[, $sOption = Default])
; Parameters ....: $sSession - Session ID from _WD_CreateSession
; $sCommand - one of the following actions:
; | Window - Get or set the current window
; | Handles - Get all window handles
; | Maximize - Maximize window
; | Minimize - Minimize window
; | Fullscreen - Set window to fullscreen
; | New - Create a new window
; | Rect - Get or set the window's size & position
; | Screenshot - Take screenshot of window
; | Close - Close current tab
; | Switch - Switch to designated tab
; | Frame - Switch to frame
; | Parent - Switch to parent frame
; | Print - Generate PDF representation of the paginated document
; $sOption - [optional] a string value. Default is ''.
; Return values .: Success - Return value from web driver (could be an empty string)
; Failure - ""
; @ERROR - $_WD_ERROR_Success
; - $_WD_ERROR_Exception
; - $_WD_ERROR_InvalidDataType
; @EXTENDED - WinHTTP status code
; Author ........: Dan Pollak
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........: https://www.w3.org/TR/webdriver/#contexts
; Example .......: No
; ===============================================================================================================================
Func _WD_Window($sSession, $sCommand, $sOption = Default)
Local Const $sFuncName = "_WD_Window"
Local $sResponse, $oJSON, $sResult = "", $iErr
If $sOption = Default Then $sOption = ''
$sCommand = StringLower($sCommand)
Switch $sCommand
Case 'window'
If $sOption = '' Then
$sResponse = __WD_Get($_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession & "/" & $sCommand)
Else
$sResponse = __WD_Post($_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession & "/" & $sCommand, $sOption)
EndIf
$iErr = @error
Case 'handles'
$sResponse = __WD_Get($_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession & "/window/" & $sCommand)
$iErr = @error
Case 'maximize', 'minimize', 'fullscreen'
$sResponse = __WD_Post($_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession & "/window/" & $sCommand, $_WD_EmptyDict)
$iErr = @error
Case 'new'
$sResponse = __WD_Post($_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession & "/window/" & $sCommand, $sOption)
$iErr = @error
Case 'rect'
If $sOption = '' Then
$sResponse = __WD_Get($_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession & "/window/" & $sCommand)
Else
$sResponse = __WD_Post($_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession & "/window/" & $sCommand, $sOption)
EndIf
$iErr = @error
Case 'screenshot'
If $sOption = '' Then
$sResponse = __WD_Get($_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession & "/" & $sCommand)
Else
$sResponse = __WD_Get($_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession & "/" & $sCommand & '/' & $sOption)
EndIf
$iErr = @error
Case 'close'
$sResponse = __WD_Delete($_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession & "/window")
$iErr = @error
Case 'switch'
$sResponse = __WD_Post($_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession & "/window", $sOption)
$iErr = @error
Case 'frame', 'print'
$sResponse = __WD_Post($_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession & "/" & $sCommand, $sOption)
$iErr = @error
Case 'parent'
$sResponse = __WD_Post($_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession & "/frame/parent", $sOption)
$iErr = @error
Case Else
Return SetError(__WD_Error($sFuncName, $_WD_ERROR_InvalidDataType, "(Window|Handles|Maximize|Minimize|Fullscreen|New|Rect|Screenshot|Close|Switch|Frame|Parent|Print) $sCommand=>" & $sCommand), 0, "")
EndSwitch
If $iErr = $_WD_ERROR_Success Then
If $_WD_HTTPRESULT = $HTTP_STATUS_OK Then
Switch $sCommand
Case 'maximize', 'minimize', 'fullscreen', 'close', 'switch', 'frame', 'parent'
$sResult = $sResponse
Case 'new'
$oJson = Json_Decode($sResponse)
$sResult = Json_Get($oJson, "[value][handle]")
Case Else
$oJson = Json_Decode($sResponse)
$sResult = Json_Get($oJson, "[value]")
EndSwitch
Else
$iErr = $_WD_ERROR_Exception
EndIf
EndIf
If $_WD_DEBUG = $_WD_DEBUG_Info Then
__WD_ConsoleWrite($sFuncName & ': ' & StringLeft($sResponse, $_WD_RESPONSE_TRIM) & "..." & @CRLF)
EndIf
If $iErr Then
Return SetError(__WD_Error($sFuncName, $iErr, "HTTP status = " & $_WD_HTTPRESULT), $_WD_HTTPRESULT, "")
EndIf
Return SetError($_WD_ERROR_Success, $_WD_HTTPRESULT, $sResult)
EndFunc ;==>_WD_Window
; #FUNCTION# ====================================================================================================================
; Name ..........: _WD_FindElement
; Description ...: Find element(s) by designated strategy
; Syntax ........: _WD_FindElement($sSession, $sStrategy, $sSelector[, $sStartNodeID = Default[, $bMultiple = Default[,
; $bShadowRoot = Default]]])
; Parameters ....: $sSession - Session ID from _WD_CreateSession
; $sStrategy - Locator strategy. See defined constant $_WD_LOCATOR_* for allowed values
; $sSelector - Value to find
; $sStartNodeID - [optional] ID to use as starting node. Default is ""
; $bMultiple - [optional] Return multiple matching elements? Default is False
; $bShadowRoot - [optional] Starting node is a shadow root? Default is False
;
; Return values .: Success - Element ID(s) returned by web driver
; Failure - ""
; @ERROR - $_WD_ERROR_Success
; - $_WD_ERROR_Exception
; - $_WD_ERROR_NoMatch
; - $_WD_ERROR_InvalidExpression
; @EXTENDED - WinHTTP status code
; Author ........: Dan Pollak
; Modified ......: 01/10/2021
; Remarks .......:
; Related .......:
; Link ..........: https://www.w3.org/TR/webdriver#element-retrieval
; Example .......: No
; ===============================================================================================================================
Func _WD_FindElement($sSession, $sStrategy, $sSelector, $sStartNodeID = Default, $bMultiple = Default, $bShadowRoot = Default)
Local Const $sFuncName = "_WD_FindElement"
Local $sCmd, $sBaseCmd = '', $sResponse, $sResult, $iErr
Local $oJson, $oValues, $sKey, $iRow, $aElements[0]
If $sStartNodeID = Default Then $sStartNodeID = ""
If $bMultiple = Default Then $bMultiple = False
If $bShadowRoot = Default Then $bShadowRoot = False
If $sStartNodeID Then
$sBaseCmd = ($bShadowRoot) ? "/shadow/" : "/element/"
$sBaseCmd &= $sStartNodeID
; Make sure using a relative selector if using xpath strategy
If $sStrategy = $_WD_LOCATOR_ByXPath And StringLeft($sSelector, 1) <> '.' Then
$iErr = $_WD_ERROR_InvalidExpression
$sResponse = "Selector must be relative when supplying a starting element"
EndIf
EndIf
If $iErr = $_WD_ERROR_Success Then
$sCmd = '/element' & (($bMultiple) ? 's' : '')
$sSelector = __WD_EscapeString($sSelector)
$sResponse = __WD_Post($_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession & $sBaseCmd & $sCmd, '{"using":"' & $sStrategy & '","value":"' & $sSelector & '"}')
$iErr = @error
EndIf
If $iErr = $_WD_ERROR_Success Then
If $_WD_HTTPRESULT = $HTTP_STATUS_OK Then
If $bMultiple Then
$oJson = Json_Decode($sResponse)
$oValues = Json_Get($oJson, '[value]')
If UBound($oValues) > 0 Then
$sKey = "[" & $_WD_ELEMENT_ID & "]"
Dim $aElements[UBound($oValues)]
For $oValue In $oValues
$aElements[$iRow] = Json_Get($oValue, $sKey)
$iRow += 1
Next
Else
$iErr = $_WD_ERROR_NoMatch
EndIf
Else
$oJson = Json_Decode($sResponse)
$sResult = Json_Get($oJson, "[value][" & $_WD_ELEMENT_ID & "]")
EndIf
Else
$iErr = $_WD_ERROR_Exception
EndIf
EndIf
If $_WD_DEBUG = $_WD_DEBUG_Info Then
__WD_ConsoleWrite($sFuncName & ': ' & $sResponse & @CRLF)
EndIf
If $iErr Then
Return SetError(__WD_Error($sFuncName, $iErr, "HTTP status = " & $_WD_HTTPRESULT), $_WD_HTTPRESULT, "")
EndIf
Return SetError($_WD_ERROR_Success, $_WD_HTTPRESULT, ($bMultiple) ? $aElements : $sResult)
EndFunc ;==>_WD_FindElement
; #FUNCTION# ====================================================================================================================
; Name ..........: _WD_ElementAction
; Description ...: Perform action on desginated element
; Syntax ........: _WD_ElementAction($sSession, $sElement, $sCommand[, $sOption = Default])
; Parameters ....: $sSession - Session ID from _WD_CreateSession
; $sElement - Element ID from _WD_FindElement
; $sCommand - one of the following actions:
; | Name - Get element's tag name
; | Rect - Get element's dimensions / coordinates
; | Text - Get element's rendered text
; | Selected - Get element's selected status
; | Enabled - Get element's enabled status
; | Displayed - Get element's visibility
; | Active - Get active element
; | Attribute - Get element's attribute
; | Property - Get element's property
; | CSS - Get element's CSS value
; | Clear - Clear element's value
; | Click - Click element
; | Value - Get or set element's value
; | Screenshot - Take element screenshot
; | Shadow - Get element's shadow root
; | CompRole - Get element's computed role
; | CompLabel - Get element's computed label
;
; $sOption - [optional] a string value. Default is ''.
;
; Return values .: Success - Requested data returned by web driver
; Failure - ""
; @ERROR - $_WD_ERROR_Success
; - $_WD_ERROR_NoMatch
; - $_WD_ERROR_Exception
; - $_WD_ERROR_InvalidDataType
; - $_WD_ERROR_InvalidExpression
; @EXTENDED - WinHTTP status code
; Author ........: Dan Pollak
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........: https://www.w3.org/TR/webdriver/#state
; https://www.w3.org/TR/webdriver#element-interaction
; https://www.w3.org/TR/webdriver/#take-element-screenshot
; https://www.w3.org/TR/webdriver/#element-displayedness
; Example .......: No
; ===============================================================================================================================
Func _WD_ElementAction($sSession, $sElement, $sCommand, $sOption = Default)
Local Const $sFuncName = "_WD_ElementAction"
Local $sResponse, $sResult = '', $iErr, $oJson
If $sOption = Default Then $sOption = ''
$sCommand = StringLower($sCommand)
Switch $sCommand
Case 'name', 'rect', 'text', 'selected', 'enabled', 'displayed', 'screenshot', 'shadow', 'comprole', 'complabel'
$sResponse = __WD_Get($_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession & "/element/" & $sElement & "/" & $sCommand)
$iErr = @error
Case 'active'
$sResponse = __WD_Get($_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession & "/element/" & $sCommand)
$iErr = @error
Case 'attribute', 'property', 'css'
$sResponse = __WD_Get($_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession & "/element/" & $sElement & "/" & $sCommand & "/" & $sOption)
$iErr = @error
Case 'clear', 'click'
$sResponse = __WD_Post($_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession & "/element/" & $sElement & "/" & $sCommand, '{"id":"' & $sElement & '"}')
$iErr = @error
Case 'value'
If $sOption Then
$sResponse = __WD_Post($_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession & "/element/" & $sElement & "/" & $sCommand, '{"id":"' & $sElement & '", "text":"' & __WD_EscapeString($sOption) & '"}')
Else
$sResponse = __WD_Get($_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession & "/element/" & $sElement & "/property/value")
EndIf
$iErr = @error
Case Else
Return SetError(__WD_Error($sFuncName, $_WD_ERROR_InvalidDataType, "(Name|Rect|Text|Selected|Enabled|Displayed|Active|Attribute|Property|CSS|Clear|Click|Value|Screenshot|Shadow|CompRole|CompLabel) $sCommand=>" & $sCommand), 0, "")
EndSwitch
If $iErr = $_WD_ERROR_Success Then
Switch $_WD_HTTPRESULT
Case $HTTP_STATUS_OK
Switch $sCommand
Case 'clear', 'click'
$sResult = $sResponse
Case 'value'
If $sOption Then
$sResult = $sResponse
Else
$oJson = Json_Decode($sResponse)
$sResult = Json_Get($oJson, "[value]")
EndIf
Case Else
$oJson = Json_Decode($sResponse)
$sResult = Json_Get($oJson, "[value]")
EndSwitch
Case Else
$iErr = $_WD_ERROR_Exception
EndSwitch
EndIf
If $_WD_DEBUG = $_WD_DEBUG_Info Then
__WD_ConsoleWrite($sFuncName & ': ' & StringLeft($sResponse,$_WD_RESPONSE_TRIM) & "..." & @CRLF)
EndIf
If $iErr Then
Return SetError(__WD_Error($sFuncName, $iErr, $sResponse), $_WD_HTTPRESULT, "")
EndIf
Return SetError($_WD_ERROR_Success, $_WD_HTTPRESULT, $sResult)
EndFunc ;==>_WD_ElementAction
; #FUNCTION# ====================================================================================================================
; Name ..........: _WD_ExecuteScript
; Description ...: Execute Javascipt commands
; Syntax ........: _WD_ExecuteScript($sSession, $sScript[, $sArguments = Default[, $bAsync = Default]])
; Parameters ....: $sSession - Session ID from _WD_CreateSession
; $sScript - Javascript command(s) to run
; $sArguments - [optional] String of arguments in JSON format
; $bAsync - [optional] Perform request asyncronously? Default is False.
; Return values .: Raw response from web driver
; @ERROR - $_WD_ERROR_Success
; - $_WD_ERROR_Exception
; - $_WD_ERROR_Timeout
; - $_WD_ERROR_SocketError
; - $_WD_ERROR_InvalidValue
; Author ........: Dan Pollak
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........: https://www.w3.org/TR/webdriver#executing-script
; Example .......: No
; ===============================================================================================================================
Func _WD_ExecuteScript($sSession, $sScript, $sArguments = Default, $bAsync = Default)
Local Const $sFuncName = "_WD_ExecuteScript"
Local $sResponse, $sData, $sCmd
If $sArguments = Default Then $sArguments = ""
If $bAsync = Default Then $bAsync = False
$sScript = __WD_EscapeString($sScript)
$sData = '{"script":"' & $sScript & '", "args":[' & $sArguments & ']}'
$sCmd = ($bAsync) ? 'async' : 'sync'
$sResponse = __WD_Post($_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession & "/execute/" & $sCmd, $sData)
Local $iErr = @error
If $_WD_DEBUG = $_WD_DEBUG_Info Then
__WD_ConsoleWrite($sFuncName & ': ' & StringLeft($sResponse,$_WD_RESPONSE_TRIM) & "..." & @CRLF)
EndIf
If $iErr Then
Return SetError(__WD_Error($sFuncName, $iErr, "HTTP status = " & $_WD_HTTPRESULT), $_WD_HTTPRESULT, $sResponse)
EndIf
Return SetError($_WD_ERROR_Success, $_WD_HTTPRESULT, $sResponse)
EndFunc ;==>_WD_ExecuteScript
; #FUNCTION# ====================================================================================================================
; Name ..........: _WD_Alert
; Description ...: Respond to user prompt
; Syntax ........: _WD_Alert($sSession, $sCommand[, $sOption = Default])
; Parameters ....: $sSession - Session ID from _WD_CreateSession
; $sCommand - one of the following actions:
; | dismiss
; | accept
; | gettext
; | sendtext
; | status
; $sOption - [optional] a string value. Default is ''.
; Return values .: Success - Requested data returned by web driver
; Failure - ""
; @ERROR - $_WD_ERROR_Success
; - $_WD_ERROR_Exception
; - $_WD_ERROR_InvalidDataType
; @EXTENDED - WinHTTP status code
; Author ........: Dan Pollak
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........: https://www.w3.org/TR/webdriver#user-prompts
; Example .......: No
; ===============================================================================================================================
Func _WD_Alert($sSession, $sCommand, $sOption = Default)
Local Const $sFuncName = "_WD_Alert"
Local $sResponse, $iErr, $oJSON, $sResult = ''
If $sOption = Default Then $sOption = ''
$sCommand = StringLower($sCommand)
Switch $sCommand
Case 'dismiss', 'accept'
$sResponse = __WD_Post($_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession & "/alert/" & $sCommand, $_WD_EmptyDict)
$iErr = @error
If $iErr = $_WD_ERROR_Success And $_WD_HTTPRESULT = $HTTP_STATUS_NOT_FOUND Then
$iErr = $_WD_ERROR_NoAlert
EndIf
Case 'gettext'
$sResponse = __WD_Get($_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession & "/alert/text")
$iErr = @error
If $iErr = $_WD_ERROR_Success Then
If $_WD_HTTPRESULT = $HTTP_STATUS_NOT_FOUND Then
$sResult = ""
$iErr = $_WD_ERROR_NoAlert
Else
$oJSON = Json_Decode($sResponse)
$sResult = Json_Get($oJSON, "[value]")
EndIf
EndIf
Case 'sendtext'
$sResponse = __WD_Post($_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession & "/alert/text", '{"text":"' & $sOption & '"}')
$iErr = @error
If $iErr = $_WD_ERROR_Success And $_WD_HTTPRESULT = $HTTP_STATUS_NOT_FOUND Then
$iErr = $_WD_ERROR_NoAlert
EndIf
Case 'status'
$sResponse = __WD_Get($_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession & "/alert/text")
$iErr = @error
If $iErr = $_WD_ERROR_Success Then
$sResult = ($_WD_HTTPRESULT = $HTTP_STATUS_NOT_FOUND) ? False : True
EndIf
Case Else
Return SetError(__WD_Error($sFuncName, $_WD_ERROR_InvalidDataType, "(Dismiss|Accept|GetText|SendText|Status) $sCommand=>" & $sCommand), 0, "")
EndSwitch
If $_WD_DEBUG = $_WD_DEBUG_Info Then
__WD_ConsoleWrite($sFuncName & ': ' & $sResponse & @CRLF)
EndIf
If $iErr Then
Return SetError(__WD_Error($sFuncName, $iErr, $sResponse), $_WD_HTTPRESULT, "")
EndIf
Return SetError($_WD_ERROR_Success, $_WD_HTTPRESULT, $sResult)
EndFunc ;==>_WD_Alert
; #FUNCTION# ====================================================================================================================
; Name ..........: _WD_GetSource
; Description ...: Get page source
; Syntax ........: _WD_GetSource($sSession)
; Parameters ....: $sSession - Session ID from _WD_CreateSession
; Return values .: Success - Source code from page
; Failure - ""
; @ERROR - $_WD_ERROR_Success
; - $_WD_ERROR_Exception