Allow exporting as Anki deck

Author: hilverd

CHANGELOG.md

@@ -12,6 +12,9 @@ This applies from version 0.5.0 onwards, as some versions before that have broke
 ## [Unreleased]
 
 ### Added
+
+- Allow exporting as Anki deck (text file suitable for importing).
+
 ### Changed
 ### Fixed
 ### Removed

src/Data/GlossaryTitle.elm

@@ -44,4 +44,4 @@ toFilename extension glossaryTitle =
                 else
                     result
            )
-        |> (\result -> result ++ "." ++ extension)
+        |> (\result -> result ++ extension)

src/Export/Anki.elm

@@ -0,0 +1,106 @@
+module Export.Anki exposing (download)
+
+import Data.AboutLink as AboutLink exposing (AboutLink)
+import Data.GlossaryItem exposing (GlossaryItem)
+import Data.GlossaryItems as GlossaryItems exposing (GlossaryItems)
+import Data.GlossaryTitle as GlossaryTitle exposing (GlossaryTitle)
+import File.Download as Download
+import Regex
+
+
+escape : String -> String
+escape string =
+    string
+        |> String.replace "\"" "\"\""
+        |> String.replace "\t" " "
+
+
+comment : String -> String
+comment =
+    let
+        linebreaks =
+            "[\u{000D}\n]"
+                |> Regex.fromString
+                |> Maybe.withDefault Regex.never
+    in
+    Regex.replace linebreaks (always " ")
+        >> (++) "# "
+
+
+crlf : String
+crlf =
+    "\u{000D}\n"
+
+
+lines : List String -> String
+lines =
+    String.join crlf
+
+
+paragraphs : List String -> String
+paragraphs =
+    List.filter (not << String.isEmpty)
+        >> String.join (crlf ++ crlf)
+
+
+itemToAnki : GlossaryItem -> String
+itemToAnki { terms, details } =
+    let
+        quote string =
+            "\"" ++ string ++ "\""
+
+        front =
+            terms
+                |> List.map (.body >> escape)
+                |> lines
+                |> quote
+
+        back =
+            details
+                |> List.map escape
+                |> paragraphs
+                |> quote
+    in
+    front ++ "\t" ++ back
+
+
+download : GlossaryTitle -> String -> List AboutLink -> GlossaryItems -> Cmd msg
+download glossaryTitle aboutParagraph aboutLinks glossaryItems =
+    let
+        filename =
+            GlossaryTitle.toFilename "-Anki_deck.txt" glossaryTitle
+
+        instructionsComment =
+            comment "This file is meant to be imported into Anki (https://docs.ankiweb.net/importing.html#text-files)."
+
+        titleComment =
+            glossaryTitle |> GlossaryTitle.toString |> comment
+
+        aboutLinksComment =
+            aboutLinks
+                |> List.map
+                    (\aboutLink ->
+                        "* " ++ AboutLink.body aboutLink ++ " - " ++ AboutLink.href aboutLink
+                    )
+                |> List.map comment
+                |> lines
+
+        itemsString =
+            glossaryItems
+                |> GlossaryItems.orderedAlphabetically
+                |> List.map (Tuple.second >> itemToAnki)
+                |> lines
+
+        content =
+            [ instructionsComment
+            , comment ""
+            , titleComment
+            , comment ""
+            , comment aboutParagraph
+            , comment ""
+            , aboutLinksComment
+            , itemsString
+            ]
+                |> lines
+    in
+    Download.string filename "text/plain" content

src/Export/Markdown.elm

@@ -94,7 +94,7 @@ download : GlossaryTitle -> String -> List AboutLink -> GlossaryItems -> Cmd msg
 download glossaryTitle aboutParagraph aboutLinks glossaryItems =
     let
         filename =
-            GlossaryTitle.toFilename "md" glossaryTitle
+            GlossaryTitle.toFilename ".md" glossaryTitle
 
         titleHeaderString =
             glossaryTitle |> GlossaryTitle.toString |> escape |> (++) "# "

src/Pages/ListAll.elm

@@ -16,6 +16,7 @@ import Data.GlossaryItems as GlossaryItems exposing (GlossaryItems)
 import Data.GlossaryTitle as GlossaryTitle
 import Dict exposing (Dict)
 import ElementIds
+import Export.Anki
 import Export.Markdown
 import Extras.Html
 import Extras.HtmlAttribute
@@ -81,6 +82,7 @@ type InternalMsg
     | JumpToTermIndexGroup Bool String
     | ChangeOrderItemsBy CommonModel.OrderItemsBy
     | DownloadMarkdown GlossaryItems
+    | DownloadAnki GlossaryItems
 
 
 type alias Msg =
@@ -305,6 +307,17 @@ update msg model =
                 ]
             )
 
+        DownloadAnki glossaryItems ->
+            ( { model | exportDropdownMenu = Components.DropdownMenu.hidden model.exportDropdownMenu }
+            , Cmd.batch
+                [ Export.Anki.download
+                    model.common.title
+                    model.common.aboutParagraph
+                    model.common.aboutLinks
+                    glossaryItems
+                ]
+            )
+
 
 patchHtmlFile : CommonModel -> GlossaryItemIndex -> GlossaryItems -> Cmd Msg
 patchHtmlFile common indexOfItemBeingDeleted glossaryItems =
@@ -1101,6 +1114,9 @@ viewExportButton glossaryItems exportDropdownMenu =
         , text "Export"
         ]
         [ Components.DropdownMenu.choice
+            [ text "Anki deck" ]
+            (PageMsg.Internal <| DownloadAnki glossaryItems)
+        , Components.DropdownMenu.choice
             [ text "Markdown" ]
             (PageMsg.Internal <| DownloadMarkdown glossaryItems)
         ]