build.gradle

plugins {
  id 'org.springframework.boot' version '2.4.4'
  id 'io.spring.dependency-management' version '1.0.8.RELEASE'
  id 'java'
  id 'maven-publish'
  id 'war'
}

group = 'com.example'
version = '0.1.0-SNAPSHOT'
sourceCompatibility = '11'

repositories {
  mavenCentral()
}

dependencies {
  implementation 'org.springframework.boot:spring-boot-starter-web'
  testImplementation('org.springframework.boot:spring-boot-starter-test') {
    exclude group: 'org.junit.vintage', module: 'junit-vintage-engine'
  }
}

test {
  useJUnitPlatform()
  //we want display the following test events
  testLogging {
    events "PASSED", "STARTED", "FAILED", "SKIPPED"
    exceptionFormat "full"
  }
}

jar.enabled = true

// GitHub Actions内でアーティファクトをリリースするのに必要な設定です
publishing {
  publications {
    bootJava(MavenPublication) {
      artifact bootWar
    }
  }
  repositories {
    maven {
      name = "GitHubPackages"
      url = uri("https://maven.pkg.github.com/ihcomega56/github-actions-example")
      credentials {
        username = System.getenv("GITHUB_ACTOR")
        password = System.getenv("GITHUB_TOKEN")
      }
    }
  }
}