build.gradle

group "io.github.ksmirenko.kpc"
version "1.0"

apply plugin: "java"
apply plugin: "kotlin"
apply plugin: "application"

task wrapper(type: Wrapper) {
    gradleVersion = "2.13"
    distributionUrl = "https://services.gradle.org/distributions/gradle-$gradleVersion-all.zip"
}

// create a single Jar with all dependencies
task fatJar(type: Jar) {
    manifest {
        //noinspection GroovyAssignabilityCheck
        attributes(
                "Implementation-Title": "Kotlin PETOOH Compiler",
                "Implementation-Version": "0.1",
                "Main-Class": "io.github.ksmirenko.kpc.MainKt"
        )
    }
    baseName = project.name + '-all'
    from { configurations.compile.collect { it.isDirectory() ? it : zipTree(it) } }
    with jar
}

buildscript {
    ext.kotlin_version = "1.0.3"
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
    }
}

defaultTasks "test", "fatJar"

repositories {
    mavenCentral()
}

dependencies {
    compile "org.jetbrains.kotlin:kotlin-stdlib:$kotlin_version"
    compile group: "org.ow2.asm", name: "asm-all", version: "5.0.1"
    testCompile group: "junit", name: "junit", version: "4.11"
    testCompile "org.jetbrains.kotlin:kotlin-test:$kotlin_version"
}

sourceSets {
    main.java.srcDirs += "src/main/kotlin"
}