-
Notifications
You must be signed in to change notification settings - Fork 1
/
Copy pathpcmload.inc
1715 lines (1564 loc) · 39 KB
/
pcmload.inc
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
;==============================================================================
;
; PPS/PCMファイルの読み込み PCMメモリをWORKに使うVersion / Include用
; PMDPCM.EXE/PMP.COM/MC.EXE 用
; x8 bit用に変更 /ver.4.4以降
; .P86処理を追加 /ver.4.5以降
; PPZ8用処理を追加 / ver.4.8以降
; PPZ8ADPCM用処理を追加 / ver.4.8k以降
;
; DISKPMD.INCを予めincludeさせておくこと。
; cs:[kankyo_seg]に環境のセグメントを入れておくこと。
;
;==============================================================================
message equ 1 ;エラーメッセージを表示するか否か
ppsdrv equ 64h ;PPSDRVのVector
p86drv equ 65h ;P86DRVのVector
ppzvec equ 7fh ;PPZ8のVector
;==============================================================================
;
; PPZ(PVI/PZI)ファイルの読み込み
;
; input DS:AX filename (128byte)
; CL 読ませるバンク (1=１つ目 2=２つ目 3=両方)
; output cy=1 Not Loaded
; AX=1 ファイルの読み込み失敗
; AX=2 データ形式が違う
; AX=3 メモリが確保できない
; AX=4 EMSハンドルのマッピングができない
; AX=5 PPZ8が常駐していない
; CL エラーの出たPCM番号(0 or 1)
; break ax,cx
;==============================================================================
ppz_load:
push bx
push dx
push si
push di
push bp
push ds
push es
mov cs:[ppz_bank],cl
mov cs:[filename_ofs],ax
mov ax,ds
mov cs:[filename_seg],ax
call ppz_load_main
pop es
pop ds
pop bp
pop di
pop si
pop dx
pop bx
ret
;==============================================================================
; PPZ8 読み込み main
;==============================================================================
ppz_load_main:
call ppz8_check
mov cl,0
mov ax,4
jc ppz_load_error
; PCM２つ読み用追加判別処理
call read_ppz8
jc plm_exit
mov ds,cs:[filename_seg]
lodsb
cmp al,","
jnz plm_exit2 ;PCMは１つだけ
mov cs:[filename_ofs],si
mov cl,1
call read_ppz8
plm_exit:
ret
plm_exit2:
xor ax,ax
ret
read_ppz8:
; 拡張子判別 (PVI / PZI)
lds si,dword ptr cs:[filename_ofs]
xor dx,dx
p8_extcheck_loop:
lodsb
call sjis_check ;in DISKPMD.INC
jnc p8_extcheck_nonsjis
inc si ;2byte目を飛ばす
jmp p8_extcheck_loop
p8_extcheck_nonsjis:
or al,al
jz p8_extcheck_exit
cmp al,","
jz p8_extcheck_exit
cmp al,"."
jnz p8_extcheck_loop
mov dx,si
jmp p8_extcheck_loop
p8_extcheck_exit:
dec si ;si= 00h or "," の位置
shr cs:[ppz_bank],1
jnc p8_load_skip ;load skip
mov ch,1 ;PZI load
test dx,dx
jz p8_load_main ;拡張子省略時 = PZI
mov bx,dx
mov al,1[bx]
and al,11011111b ;小文字＞大文字変換
cmp al,"V"
jnz p8_load_main
dec ch ;PVI load (ch=0)
; PVI / PZI 読み込み
p8_load_main:
push ds:[si]
mov byte ptr [si],0 ; "," なら 00h に一時的に書き換え
mov ax,0300h
mov dx,cs:[filename_ofs]
int ppzvec ; pcm load
jnc p8_load_exit
cmp ax,2
cmc
jc p8_load_exit ; file not found or 形式が違うなら
xor ch,1 ; もう片方の形式も
mov ax,0300h
int ppzvec ; pcm loadを試してみる
p8_load_exit:
pop ds:[si]
jc ppz_load_error
p8_load_skip:
xor ax,ax
ret
; Error処理
ppz_load_error:
inc ax
if message
mov bx,ax
mov dx,offset exit1z_mes
dec bx
jz ppz_error_main
mov dx,offset exit2z_mes
dec bx
jz ppz_error_main
mov dx,offset exit3z_mes
dec bx
jz ppz_error_main
mov dx,offset exit4z_mes
dec bx
jz ppz_error_main
mov dx,offset exit5z_mes
jmp ppz_error_main2
ppz_error_main:
mov al,cl
add al,"1"
mov cs:[banknum],al ;Bank
push dx
mov dx,offset ppzbank_mes
call ppz_error_main2
pop dx
ppz_error_main2:
push ds
push ax
mov ax,cs
mov ds,ax
mov ah,9
int 21h
pop ax
pop ds
endif
stc
ret
; PPZ8常駐check
ppz8_check:
xor bx,bx
mov es,bx
les bx,es:[ppzvec*4]
cmp word ptr es:2[bx],"PP"
jnz no_ppz
cmp word ptr es:4[bx],"8Z"
jnz no_ppz
cmp byte ptr es:6[bx],0
jnz no_ppz
clc
ret
no_ppz: stc
ret
;==============================================================================
;
; PCM(PPC/P86)ファイルの読み込み
; P86DRV.COMが常駐していれば .P86を、
; そうでない場合は .PPCを読む。
; PMDPPZEが常駐している場合は無条件にPVIをPPZ8に読み込む。
;
; input DS:AX filename (128byte)
; ES:DI pcm_work (32KB,P86の場合は必要無し)
; output cy=1 Not Loaded
; PMDB2/PMD86の場合
; AX=1 SPB/ADPCM-RAMかPMDB2がない
; 86B/P86DRV かPMD86がない
; AX=2 ファイルがない
; AX=3 ファイルがPMDのPCMデータではない
; AX=4 SPB/既に読み込んであるのと同じだった
; 86B/容量OVER
; AX=5 ファイルが読めない
; AX=6 PCMメモリがアクセス中だった
; PMDPPZEの場合
; AX=1 ファイルの読み込み失敗
; AX=2 データ形式が違う
; AX=3 メモリが確保できない
; AX=4 EMSハンドルのマッピングができない
; AX=5 PPZ8が常駐していない
;
; .PPC format:
; WORK=PMD内PCMWORK , DATA=PCMRAM先頭のWORK , FILE=PCMFILE
; 123456789012345678901234567890
; DATA/FILEのみ "ADPCM DATA for PMD ver.4.4- "30bytes
; WORK/DATA/FILE 1Word Next START Address
; 2Word*256 START/STOP
; WORK/DATAのみ 128bytes FILENAME
; DATAのみ 32bytes 予備
;
; PCMRAM_Work =00000H～00025H
; PCMRAM_Main_data =00026H～01FFFH
;
; .P86 format:
; "PCM86 DATA",0ah,0 12 byte
; P86DRVのversion 1 byte
; 全体のサイズ 3 byte
; 音色table start(3),size(3) * 256 (1536) bytes
; 音色データ 可変
;
;==============================================================================
pcm_all_load proc
assume ds:nothing,es:nothing
cld
push ds
push es
push bx
push cx
push dx
push si
push di
push bp
mov cs:[filename_ofs],ax
mov ax,ds
mov cs:[filename_seg],ax
mov cs:[pcmdata_ofs],di
mov ax,es
mov cs:[pcmdata_seg],ax
mov ah,0eh ;GET_PCM_ADR
int 60h ;DS:DX=PCMワーク
mov cs:[pcmwork_ofs],dx
mov ax,ds
mov cs:[pcmwork_seg],ax
call all_load
pop bp
pop di
pop si
pop dx
pop cx
pop bx
pop es
pop ds
ret
pcm_all_load endp
;==============================================================================
;
; PPSファイルの読み込み
;
; input DS:AX filename (128byte)
; output cy=1 AX=1 PPSDRVが常駐していない
; AX=2 ファイルが無い
; AX=3 PPSDRVの容量をオーバーした
; AX=5 ファイルが読めない
;
; PPSDATA構造
; 2Word*14 Start address/Length
; 以降 PPS Data
;
;==============================================================================
pps_load proc
assume ds:nothing,es:nothing
cld
push ds
push es
push bx
push cx
push dx
push si
push di
push bp
mov cs:[filename_ofs],ax
mov ax,ds
mov cs:[filename_seg],ax
call ppsdrv_check
jc not_load
pps_load_exec:
mov ah,4
int ppsdrv
mov cs:[pcmdata_ofs],dx
mov ax,ds
mov cs:[pcmdata_seg],ax
mov cs:[pcmdata_size],cx
call pps_load_main
not_load:
pop bp
pop di
pop si
pop dx
pop cx
pop bx
pop es
pop ds
ret
pps_load endp
;==============================================================================
; pps load
; in cs:[filename_ofs/seg] Filename
; cs:[pcmdata_ofs/seg] PPSData位置
; cs:[pcmdata_size] PPSData容量
;==============================================================================
pps_load_main proc
call filename_set
;-----------------------------------------------------------------------------
; File Read
;-----------------------------------------------------------------------------
mov bx,offset pps_ext
call ext_set ;拡張子 "PPS"に変更
mov ax,cs
mov ds,ax
mov dx,offset filename_buf
mov es,[kankyo_seg]
call opnhnd ;Open
jnc exec_ppsload
lds dx,dword ptr cs:[filename_ofs]
mov es,cs:[kankyo_seg]
call opnhnd ;Open
jc allload_exit2p ;Fileが無い
exec_ppsload:
lds dx,dword ptr cs:[pcmdata_ofs]
mov cx,cs:[pcmdata_size]
inc cx ;1byte余計に読む
push cx
call redhnd
pop cx
jc allload_exit5p_close ;fileが読めない
cmp ax,cx
jz allload_exit3p_close ;容量オーバー
call clohnd
xor ax,ax
ret
pps_load_main endp
;==============================================================================
; .PPC/.P86 一括load
; in cs:[filename_ofs/seg] Filename
; cs:[pcmdata_ofs/seg] PCMData loadarea
; cs:[pcmwork_ofs/seg] PMD内PCMwork
;==============================================================================
all_load proc
;-----------------------------------------------------------------------------
; 読み込むのは.P86か.PPCかどうかを判別
;-----------------------------------------------------------------------------
call check_p86drv
jnc p86_load
mov ah,09h
int 60h ;board check
cmp al,1 ;pmdb2
jz allload_main1
cmp al,4 ;pmdppz
jz allload_main1
cmp al,5 ;pmdppze
jz allload_ppze
jmp allload_exit1
;-----------------------------------------------------------------------------
; .PPC read Main
;-----------------------------------------------------------------------------
allload_main1:
call check_pmdb2
jc allload_exit1
call filename_set
;-----------------------------------------------------------------------------
; FileをPMDのワークにヘッダだけ読みこむ
;-----------------------------------------------------------------------------
mov bx,offset ppc_ext
call ext_set ;拡張子 "PPC"に変更
mov ax,cs
mov ds,ax
mov dx,offset filename_buf
mov es,[kankyo_seg]
call opnhnd ;Open
jnc exec_ppcload
lds dx,dword ptr cs:[filename_ofs]
mov es,cs:[kankyo_seg]
call opnhnd ;Open
jnc exec_ppcload
mov bx,offset p86_ext
call ext_set ;拡張子 "P86"に変更
mov ax,cs
mov ds,ax
mov dx,offset filename_buf
mov es,[kankyo_seg]
call opnhnd ;Open
jc allload_exit2
exec_ppcload:
lds dx,dword ptr cs:[pcmdata_ofs]
mov cx,30 ;識別文字列長
call redhnd
jc allload_exit5_close
cmp ax,30 ;Headerの長さ=読み込んだ長さか？
jnz allload_exit3_close
lds bx,dword ptr cs:[pcmdata_ofs]
cmp word ptr 0[bx],"VP" ;PV
jnz not_pvi
cmp word ptr 2[bx],"2I" ;I2
jnz not_pvi
cmp byte ptr 10[bx],02h ;RAM Type 8bit
jz pvi_load
not_pvi:
cmp word ptr 0[bx],"DA" ;AD
jnz allload_exit3_close ;PMDのPCMデータではない
cmp word ptr 2[bx],"CP" ;PC
jnz allload_exit3_close ;PMDのPCMデータではない
cmp word ptr 4[bx]," M" ;M
jnz allload_exit3_close ;PMDのPCMデータではない
lds dx,dword ptr cs:[pcmwork_ofs]
mov cx,4*256+2 ;Headerの長さ (filenameはない)
call redhnd ;Read
jc allload_exit5_close
cmp ax,4*256+2 ;Headerの長さ=読み込んだ長さか？
jnz allload_exit3_close
;-----------------------------------------------------------------------------
; PMDのワークにFilenameを書く
;-----------------------------------------------------------------------------
ppc_load_main:
call write_filename_to_pmdwork
;-----------------------------------------------------------------------------
; PCMRAMのヘッダを読む
;-----------------------------------------------------------------------------
cmp cs:[retry_flag],0
jnz write_pcm_main ;無条件
mov cs:[pcmstart],0
mov cs:[pcmstop],25h ;read 25h*32 = 1184(32+256*4+128) bytes
call pcmread
jc allload_exit6_close
;-----------------------------------------------------------------------------
; PMDのワークとPCMRAMのヘッダを比較
;-----------------------------------------------------------------------------
lds si,dword ptr cs:[pcmdata_ofs]
les di,dword ptr cs:[pcmwork_ofs]
add si,30 ;"ADPCM～"ヘッダを飛ばす
mov cx,+(4*256+128+2)/2
rep cmpsw
jz allload_exit4_close ;一致した
;-----------------------------------------------------------------------------
; PMDのワークをPCMRAM頭に書き込む
;-----------------------------------------------------------------------------
write_pcm_main:
mov ax,cs
mov ds,ax
mov si,offset adpcm_header
les di,dword ptr cs:[pcmdata_ofs]
mov cx,30/2 ;"ADPCM～"ヘッダを書き込み
rep movsw
lds si,dword ptr cs:[pcmwork_ofs]
mov cx,+(4*256+128+2)/2
rep movsw
mov cs:[pcmstart],0
mov cs:[pcmstop],25h
call pcmstore
;-----------------------------------------------------------------------------
; PCMDATAをPCMRAMに書き込む
; 8000hずつ読み込みながら定義
;-----------------------------------------------------------------------------
if message
mov ax,cs
mov ds,ax
mov dx,offset allload_mes
mov ah,09h
int 21h ;"ＰＣＭ定義中"の表示
endif
lds bx,dword ptr cs:[pcmwork_ofs]
mov ax,ds:[bx] ;AX=PCM Next Start Address
sub ax,26h ;実際にこれから転送するデータ量に変換
mov cs:[pcmstart],26h
mov cs:[pcmstop],426h ;400h*32=8000h 一括
allload_loop:
cmp ax,401h
jc allload_last
sub ax,400h
mov bp,ax ;Push
lds dx,dword ptr cs:[pcmdata_ofs]
mov cx,8000h
call redhnd ;DISK Read
jc allload_exit5_close
cmp ax,8000h
jnz allload_exit3_close
call pcmstore ;PCM Store
add cs:[pcmstart],400h
add cs:[pcmstop],400h
mov ax,bp ;Pop
jmp allload_loop
allload_last:
or ax,ax
jz allload_justend
mov bp,ax ;Push
add ax,cs:[pcmstart]
mov cs:[pcmstop],ax
lds dx,dword ptr cs:[pcmdata_ofs]
mov cx,8000h
call redhnd ;DISK Read
jc allload_exit5_close
mov bx,bp ;Pop
add bx,bx
add bx,bx
add bx,bx
add bx,bx
add bx,bx
cmp ax,bx
pushf
call pcmstore ;PCM Store
popf
jc allload_exit3_close
allload_justend:
call clohnd ;FILE Close
;-----------------------------------------------------------------------------
; 終了
;-----------------------------------------------------------------------------
xor ax,ax
ret
all_load endp
;==============================================================================
; .PVI loading
;==============================================================================
pvi_load:
;-----------------------------------------------------------------------------
; ヘッダ/音色tableの残りを読み込み
;-----------------------------------------------------------------------------
lds dx,dword ptr cs:[pcmdata_ofs]
add dx,30
mov cx,128*4+16-30 ;Header 残り
call redhnd
jc allload_exit5_close
cmp ax,128*4+16-30
jnz allload_exit3_close
;-----------------------------------------------------------------------------
; pviの音色情報からpmdへ転送
;-----------------------------------------------------------------------------
lds si,dword ptr cs:[pcmdata_ofs]
add si,16
les di,dword ptr cs:[pcmwork_ofs]
add di,2
xor bx,bx
mov cx,128
mov dx,26h
tableset_loop:
lodsw
add ax,dx
stosw
lodsw
or ax,ax
jnz not_null_pcm
sub word ptr es:-2[di],dx
sub ax,dx
not_null_pcm:
add ax,dx
stosw
cmp bx,ax
jnc not_set_max
mov bx,ax
inc bx
not_set_max:
loop tableset_loop
xor ax,ax
mov cx,128*2
rep stosw ;残り128個は未定義
mov di,cs:[pcmwork_ofs]
mov es:[di],bx
jmp ppc_load_main ;あとはppcと同じ
;==============================================================================
; PMDPPZEの ADPCM用 load
;==============================================================================
allload_ppze:
call ppz8_check
mov ax,4
mov cl,0
jc ppz_load_error ;PPZ8非常駐
call filename_set
mov bx,offset pvi_ext
call ext_set ;拡張子 "PVI"に変更
mov ax,cs
mov ds,ax
mov dx,offset filename_buf
mov cx,0001h ;pvi,buffer 1
mov ax,0300h
int ppzvec
jnc ppze_load_exit
cmp ax,2
jnc ppz_load_error
mov bx,offset pzi_ext
call ext_set ;拡張子 "PZI"に変更
mov ax,cs
mov ds,ax
mov dx,offset filename_buf
mov cx,0101h ;pzi,buffer 1
mov ax,0300h
int ppzvec
jc ppz_load_error
ppze_load_exit:
xor ax,ax
ret ;正常終了
;==============================================================================
; P86 data 一括load
; in cs:[filename_ofs/seg] Filename
;==============================================================================
p86_load proc
;-----------------------------------------------------------------------------
; P86drvのcheck
;-----------------------------------------------------------------------------
mov ah,-2
int p86drv ;INT65H 使用中?
or al,al
jnz allload_exit6
mov ah,-1
int p86drv
cmp al,10h ;ver.1.0以前?
jc allload_exit6
call filename_set
;-----------------------------------------------------------------------------
; P86Data,Size確認
;-----------------------------------------------------------------------------
mov bx,offset p86_ext
call ext_set ;拡張子 "P86"に変更
mov ax,cs
mov ds,ax
mov dx,offset filename_buf
mov es,[kankyo_seg]
mov ah,6
int p86drv ;Read
test al,al
jz p86load_complete
lds dx,dword ptr cs:[filename_ofs]
mov es,cs:[kankyo_seg]
mov ah,6
int p86drv ;Read
test al,al
jz p86load_complete
mov bx,offset ppc_ext
call ext_set ;拡張子 "PPC"に変更
mov ax,cs
mov ds,ax
mov dx,offset filename_buf
mov es,[kankyo_seg]
mov ah,6
int p86drv ;Read
test al,al
jnz p86load_error
p86load_complete:
xor ax,ax ;正常終了
ret
p86load_error:
dec al
jz allload_exit1 ;No Resident PMD86
dec al
jz allload_exit2 ;File not found
dec al
jz allload_exit4pp ;Size Over
dec al
jz allload_exit3 ;Type Missmatch
dec al
jz allload_exit5 ;Read Error
jmp allload_exit1 ;Other Errors
p86_load endp
;-----------------------------------------------------------------------------
; エラーリターン
;-----------------------------------------------------------------------------
allload_exit1:
if message
mov dx,offset exit1_mes
endif
mov ax,1 ;PCMが定義出来ません。
jmp error_exec
allload_exit1p:
if message
mov dx,offset exit1p_mes
endif
mov ax,1 ;PPSDRVが常駐してない
jmp error_exec
allload_exit2:
if message
mov dx,offset exit2_mes
endif
mov ax,2 ;PCMファイルがない
jmp error_exec
allload_exit2p:
if message
mov dx,offset exit2p_mes
endif
mov ax,2 ;PPSファイルがない
jmp error_exec
allload_exit3_close:
call clohnd
allload_exit3:
if message
mov dx,offset exit3_mes
endif
mov ax,3 ;ファイルがPMDのPCMではない
jmp error_exec
allload_exit3p_close:
call clohnd
if message
mov dx,offset exit3p_mes
endif
mov ax,3 ;PPSデータ容量オーバー
jmp error_exec
allload_exit4_close:
call clohnd
if message
mov dx,offset exit4_mes
endif
mov ax,4 ;データが一致した
jmp error_exec
allload_exit4pp:
if message
mov dx,offset exit4pp_mes
endif
mov ax,4 ;P86容量が足りない
jmp error_exec
allload_exit5_close:
call clohnd
allload_exit5:
if message
mov dx,offset exit5_mes
endif
mov ax,5 ;PCMファイルが読めない
jmp error_exec
allload_exit5p_close:
call clohnd
if message
mov dx,offset exit5p_mes
endif
mov ax,5 ;PPSファイルが読めない
jmp error_exec
allload_exit6_close:
call clohnd
allload_exit6:
if message
mov dx,offset exit6_mes
endif
mov ax,6 ;PCMメモリアクセス中
jmp error_exec
error_exec:
if message
push ax
mov ax,cs
mov ds,ax
mov ah,09h
int 21h
pop ax
endif
stc
ret
;==============================================================================
; PMDB2＆ADPCMのCheck
; output cy PMDB2又はADPCMがない
;==============================================================================
check_pmdb2 proc
;-----------------------------------------------------------------------------
; PMDB2＆ADPCMの搭載CHECK
;-----------------------------------------------------------------------------
mov ah,10h
int 60h ;get_workadr in DS:DX
mov bx,dx
mov bx,-2[bx] ;ds:bx = open_work
cmp _pcm_gs_flag[bx],0
jnz cpb_stc_ret ;ERROR Return
mov ax,_fm2_port1[bx]
mov cs:[port46],ax
mov ax,_fm2_port2[bx]
mov cs:[port47],ax
clc
ret
cpb_stc_ret:
stc
ret
check_pmdb2 endp
;==============================================================================
; P86DRVの常駐Check
; output cy P86DRVがない
;==============================================================================
check_p86drv proc
push es
push ax
xor ax,ax
mov es,ax
les bx,es:[p86drv*4]
cmp word ptr es:2[bx],"8P"
jnz p86drv_not_found
cmp byte ptr es:4[bx],"6"
jnz p86drv_not_found
pop ax
pop es
clc
ret
p86drv_not_found:
pop ax
pop es
stc
ret
check_p86drv endp
;==============================================================================
; PPSDRV 常駐check
; output cy=1 常駐してない
;==============================================================================
ppsdrv_check proc
xor ax,ax
mov es,ax
les bx,es:[ppsdrv*4]
cmp word ptr es:2[bx],"MP"
jnz allload_exit1p
cmp byte ptr es:4[bx],"P"
jnz allload_exit1p
clc
ret
ppsdrv_check endp
;==============================================================================
; Filenameの大文字化＆パス名回避処理
;==============================================================================
filename_set proc
;-----------------------------------------------------------------------------
; Filenameを小文字から大文字に変換(SHIFTJIS回避付き)
;-----------------------------------------------------------------------------
lds si,dword ptr cs:[filename_ofs]
exbig_loop:
lodsb
call sjis_check ;in DISKPMD.INC
jnc exbig_nonsjis
inc si ;2byte目を飛ばす
jmp exbig_loop
exbig_nonsjis:
or al,al
jz exbig_exit
cmp al,"a"
jc exbig_loop
cmp al,"z"+1
jnc exbig_loop
and al,11011111b ;小文字＞大文字変換
mov ds:-1[si],al ;して書込み
jmp exbig_loop
exbig_exit:
;-----------------------------------------------------------------------------
; Filename中のパス名を抜いたfilename_ofs2を設定(File名比較用)
;-----------------------------------------------------------------------------
lds si,dword ptr cs:[filename_ofs]
mov bx,si
yencheck_loop:
lodsb
call sjis_check ;in DISKPMD.INC
jnc yencheck_nonsjis
inc si ;2byte目を飛ばす
jmp yencheck_loop
yencheck_nonsjis:
or al,al
jz yencheck_exit
cmp al,"\"
jnz yencheck_loop
mov bx,si
jmp yencheck_loop
yencheck_exit:
mov cs:[filename_ofs2],bx
mov ax,ds
mov cs:[filename_seg2],ax ;セグメントはfilename_segと一緒
ret
filename_set endp
;==============================================================================
; PMDのワークにFilenameを書く
;==============================================================================
write_filename_to_pmdwork proc
lds si,dword ptr cs:[filename_ofs2]
les di,dword ptr cs:[pcmwork_ofs]
add di,4*256+2 ;ES:DI = PMD内PCM_WORKのFilename格納位置
mov cx,128 ;byte数
write_filename_loop:
dec cx
movsb
cmp byte ptr -1[si],0
jnz write_filename_loop
xor al,al
rep stosb ;残りを０で埋める
ret
write_filename_to_pmdwork endp
;==============================================================================
; ＰＣＭメモリへメインメモリからデータを送る (x8,高速/低速選択版)
;
; INPUTS .. cs:[pcmstart] to Start Address
; .. cs:[pcmstop] to Stop Address
; .. cs:[pcmdata_ofs/seg] to PCMData_Buffer
;==============================================================================
pcmstore proc
call key_check_reset
mov dx,0001h
call out46
mov dx,1017h ;brdy以外はマスク(=timer割り込みは掛からない)
call out46
mov dx,1080h
call out46
mov dx,0060h
call out46
mov dx,0102h ;x8
call out46
mov dx,0cffh