#45 Add common OAPI server generate function

Author: vityaman

backend/buildSrc/src/main/kotlin/buildlogic.foundation-conventions.gradle.kts

@@ -3,3 +3,37 @@ plugins {
     id("org.openapi.generator")
     application
 }
+
+extra["generateOAPIServer"] = { serviceName: String ->
+    val apiResourcesDir = layout.projectDirectory.asFile.let { "$it/src/main/resources" }
+    val generatedDir = layout.buildDirectory.dir("generated").get().toString()
+
+    openApiGenerate {
+        generatorName = "kotlin-spring"
+        inputSpec = "$apiResourcesDir/static/openapi/api.yml"
+        outputDir = generatedDir
+        invokerPackage = "$group.$serviceName"
+        apiPackage = "$group.$serviceName.api.generated"
+        modelPackage = "$group.$serviceName.model.generated"
+        configOptions = mapOf(
+            "delegatePattern" to "true",
+            "useSpringBoot3" to "true",
+        )
+    }
+
+    sourceSets {
+        main {
+            kotlin {
+                srcDir("$generatedDir/src/main/kotlin")
+            }
+        }
+    }
+
+    tasks.compileKotlin.configure {
+        dependsOn("openApiGenerate")
+    }
+
+    application {
+        mainClass = "$group.$serviceName.ApplicationKt"
+    }
+}

backend/matchmaker/build.gradle.kts

@@ -1,3 +1,5 @@
+@file:Suppress("UNCHECKED_CAST")
+
 plugins {
     id("buildlogic.foundation-conventions")
 }
@@ -7,34 +9,4 @@ dependencies {
     testImplementation(project(":foundation-test"))
 }
 
-val apiResourcesDir = layout.projectDirectory.asFile.let { "$it/src/main/resources" }
-val generatedDir = layout.buildDirectory.dir("generated").get().toString()
-
-openApiGenerate {
-    generatorName = "kotlin-spring"
-    inputSpec = "$apiResourcesDir/static/openapi/api.yml"
-    outputDir = generatedDir
-    invokerPackage = "${group}.matchmaker"
-    apiPackage = "${group}.matchmaker.api.generated"
-    modelPackage = "${group}.matchmaker.model.generated"
-    configOptions = mapOf(
-        "delegatePattern" to "true",
-        "useSpringBoot3" to "true",
-    )
-}
-
-sourceSets {
-    main {
-        kotlin {
-            srcDir("${generatedDir}/src/main/kotlin")
-        }
-    }
-}
-
-tasks.compileKotlin.configure {
-    dependsOn("openApiGenerate")
-}
-
-application {
-    mainClass = "${group}.matchmaker.ApplicationKt"
-}
+(extra["generateOAPIServer"] as (String) -> Unit)("matchmaker")

backend/people/build.gradle.kts

@@ -1,3 +1,5 @@
+@file:Suppress("UNCHECKED_CAST")
+
 plugins {
     id("buildlogic.foundation-conventions")
 }
@@ -7,34 +9,4 @@ dependencies {
     testImplementation(project(":foundation-test"))
 }
 
-val apiResourcesDir = layout.projectDirectory.asFile.let { "$it/src/main/resources" }
-val generatedDir = layout.buildDirectory.dir("generated").get().toString()
-
-openApiGenerate {
-    generatorName = "kotlin-spring"
-    inputSpec = "$apiResourcesDir/static/openapi/api.yml"
-    outputDir = generatedDir
-    invokerPackage = "${group}.people"
-    apiPackage = "${group}.people.api.generated"
-    modelPackage = "${group}.people.model.generated"
-    configOptions = mapOf(
-        "delegatePattern" to "true",
-        "useSpringBoot3" to "true",
-    )
-}
-
-sourceSets {
-    main {
-        kotlin {
-            srcDir("${generatedDir}/src/main/kotlin")
-        }
-    }
-}
-
-tasks.compileKotlin.configure {
-    dependsOn("openApiGenerate")
-}
-
-application {
-    mainClass = "${group}.people.ApplicationKt"
-}
+(extra["generateOAPIServer"] as (String) -> Unit)("people")