play3.as_

WRKARE: EQU 0C000H
PSG: EQU 0F760H
PPI: EQU 0F780H
LOTMP: EQU 0F000H


START: LXI H,ZAST
 CALL 0F818H
 CALL 0F803H
 CALL INITPL
 CPI '1'
 JZ PLAY1
 CPI '2'
 JZ PLAY2
 CPI '3'
 JZ PLAY3
 CPI '4'
 JZ PLAY4
 CPI '5'
 JZ PLAY5
 CPI '6'
 JZ PLAY6
 JMP 0F86CH

PLAY1:
 LXI H,PL01
 LXI D,PL02
 LXI B,PL03
 CALL PLAY
 JMP PLAY1
PLAY2:
 LXI H,PL11
 LXI D,PL12
 LXI B,PL13
 CALL PLAY
 JMP START
PLAY3:
 LXI H,PL21
 LXI D,PL22
 LXI B,PL23
 CALL PLAY
 JMP START
PLAY4:
 LXI H,PL31
 LXI D,PL32
 LXI B,PL33
 CALL PLAY
 JMP START
PLAY5:
 LXI H,PL41
 LXI D,PL42
 LXI B,PL43
 CALL PLAY
 JMP START
PLAY6:
 LXI H,PL51
 LXI D,PL52
 LXI B,PL53
 CALL PLAY
 JMP PLAY6
RDSND:
 MOV A,M
 PUSH PSW
 MOV C,A
;CALL 0F809H
 POP PSW
 INX H
 CPI 'V'
 JZ VOL
 CPI 'L'
 JZ LOUDN
 CPI 'O'
 JZ OCTAVE
 CPI 'T'
 JZ TEMP
 CPI 'R'
 JZ PAUSE
 CPI 'M'
 JZ FORM
 CPI '^'
 JZ LEG
 CPI '"'
 JZ NONLEG
 CPI 'A'
 JC ERROR
 CPI 'H'
 JNC ERROR
 CPI 'B'
 JNZ $+8
 MVI B,12
 JMP PL0
 CPI 'E'
 JNZ $+8
 MVI B,5
 JMP PL0
 CPI 'C'
 JNZ $+8
 MVI B,1
 JMP PL1
 CPI 'F'
 JNZ $+8
 MVI B,6
 JMP PL1
 CPI 'D'
 JNZ $+5
 MVI B,3
 CPI 'G'
 JNZ $+5
 MVI B,8
 CPI 'A'
 JNZ $+5
 MVI B,10
 CALL FNDBEM
 CALL FNDDZ
 JMP PL2

FNDBEM:
 MOV A,M
 CPI '$'
 RNZ
 DCR B
 INX H
 RET

FNDDZ:
 MOV A,M
 CPI '#'
 RNZ
 INR B
 INX H
 RET

PL0:
 CALL FNDBEM
 JMP PL2
PL1:
 CALL FNDDZ
PL2:
 MOV A,B
 CPI 13
 RNC
 INX D
 LDAX D
 DCX D
 MOV C,A
 MOV A,E
 ANI 0FCH
 RRC
 RRC
 PUSH PSW
 LDAX D
 ANI 80H
 JNZ PL9
 PUSH B
 MOV A,E
 ANI 0FCH
 RRC
 RRC
 RRC
 RRC
 ORI 36H
 STA PSG+3
 CALL SNDEL
 POP B
PL9:
 POP PSW
 CALL SOUND
 CALL GETVAL
 MOV B,A
 RET

ERROR:
 LHLD STCPNT
 SPHL
 RET

;CALL SNDEL
 RLC
 JC PL3
 RLC
 JC PL3
 RLC
 JC PL3
 RLC
 JC PL3
 RLC
 JC PL3
 RLC
 JNC PL4
PL3:
 MVI A,0FFH
PL4:
 MVI A,0FFH
 MOV B,A
 MOV A,E
 ANI 0FBH
 RRC
 RRC
 RRC
 RRC
 ORI 36H
 STA PSG+3
;CALL SNDEL
 JMP RDSND

OCTAVE:
 CALL GETVL1
 CPI 7
 JNC ERROR
 INX D
 STAX D
 DCX D
 JMP RDSND

PAUSE:
 MOV A,E
 ANI 0FCH
 RRC
 RRC
 RRC
 RRC
 ORI 36H
 STA PSG+3
 CALL GETVAL
 MOV B,A
 RET



LOUDN:
 CALL GETVL1
 STAX D
 JMP RDSND

TEMP:
 CALL GETVL1
 ORA A
 JZ ERROR
 PUSH D
 INX D
 INX D
 MOV A,C
 STAX D
 MOV A,B
 INX D
 STAX D
 POP D
 JMP RDSND

VOL:
 MOV A,E
 ANI 0FCH
 RRC
 RRC
 MOV C,A
 PUSH B
 CALL GETVL1
 POP B
 SUI 16
 JNC ERROR
 CMA
 ADI 10

 MVI B,0
 PUSH H
 LXI H,0F740H
 DAD B
 MOV M,A
 POP H
 JMP RDSND

LEG:
 LDAX D
 ORI 80H
 STAX D
 JMP RDSND

NONLEG:
 LDAX D
 ANI 7FH
 STAX D
 JMP RDSND

FORM:
 CALL GETVL1
 JMP RDSND

GETVAL:
 CALL GETVL1
 ORA A
 JNZ $+4
 LDAX D
 ANI 7FH
 MOV C,A
 ANI 0FEH
 RRC
 MOV B,A
 MOV A,C
 RLC
 MOV C,A
 MOV A,M
 CPI '.'
 MOV A,C
 RNZ
 SUB B
 INX H
 RET

GETVL1:
 PUSH D
 LXI D,0
 MOV A,M
 SUI '0'
 MOV B,A
 MVI A,0
 RC
 CPI 0AH
 MVI A,0
 RNC
GET2:
 MOV A,M
 SUI '0'
 JC  GET1
 CPI 0AH
 JNC GET1
 XCHG
 DAD H
 DAD H
 DAD H
 DAD H
 XCHG
 ORA E
 MOV E,A
 INX H
 JMP GET2
GET1:
 MOV A,D
 STA DNUM+1
 MOV A,E
 STA DNUM
 PUSH H
 CALL ?FBCDB
 POP H
 LDA BNUM+1
 MOV B,A
 LDA BNUM
 MOV C,A
 POP D
 RET


INITPL:
 LXI H,PSG+3
 MVI M,36H
 MVI M,76H
 MVI M,0B6H
 LXI H,PPI+2
 MVI M,6
 LXI H,0F740H+3
 MVI M,14H
 MVI M,54H
 MVI M,94H
 DCX H
 MVI M,2
 DCX H
 MVI M,2
 DCX H
 MVI M,2
 RET


SOUND:; B - НОМЕР НОТЫ, C - НOМЕР ОКТАВЫ,A - НОМЕР КАНАЛА
 PUSH H
 PUSH D
 PUSH PSW
 LXI H,PLTBL
 MOV A,B
 DCR A
 ADD A
 MOV E,A
 MVI D,0
 DAD D
 MOV E,M
 INX H
 MOV D,M
 XCHG
 MOV B,C
 CALL ?SRNHB
 XCHG
 LXI H,PSG
 POP PSW
 MOV C,A
 MVI B,0
 DAD B
 MOV M,E
 MOV M,D
 POP D
 POP H
 RET

PLAY:
 SHLD PNT1
 LXI H,0
 DAD SP
 SHLD STCPNT
 XCHG
 SHLD PNT2
 MOV H,B
 MOV L,C
 SHLD PNT3
 CALL SND1
 CALL SND2
 CALL SND3
PLY0:
 LHLD DL1
 XCHG
 LHLD DLC1
 CALL ?NEGHL
 DAD D
 SHLD DL1
 CNC SND1
 LHLD DL2
 XCHG
 LHLD DLC2
 CALL ?NEGHL
 DAD D
 SHLD DL2
 CNC SND2
 LHLD DL3
 XCHG
 LHLD DLC3
 CALL ?NEGHL
 DAD D
 SHLD DL3
 CNC SND3
 LXI B,300
PLY1: DCX B
 MOV A,B
 ORA C
 JNZ PLY1
 JMP PLY0

SND1:
 LHLD PNT1
 LXI D,WRKARE
 CALL RDSND
 SHLD PNT1
 MVI E,2
 CALL GETDEL
 SHLD DLC1
 LXI H,LOTMP
 SHLD DL1
 RET

SND2:
 LHLD PNT2
 LXI D,WRKARE+4
 CALL RDSND
 SHLD PNT2
 MVI E,6
 CALL GETDEL
 SHLD DLC2
 LXI H,LOTMP
 SHLD DL2
 RET

SND3:
 LHLD PNT3
 LXI D,WRKARE+8
 CALL RDSND
 SHLD PNT3
 MVI E,10
 CALL GETDEL
 SHLD DLC3
 LXI H,LOTMP
 SHLD DL3
 RET

SNDEL:
 LXI B,100
SNDL1:
 DCX B
 MOV A,B
 ORA A
 JNZ SNDL1
 RET
GETDEL:
 XCHG
 MOV E,M
 INX H
 MOV D,M
 MOV L,B
 MVI H,0
 CALL ?MULHD
 RET
; 16-BIT MULTIPLY
; HL *= DE
?MULHD:
 MOV B,H
 MOV C,L
 LXI H,0
 MVI A,16
?01:
 DAD H
 XCHG
 DAD H
 XCHG
 JNC ?02
 DAD B
?02:
 DCR A
 JNZ ?01
 RET


?ABSHL:
 MOV A,H
 ORA A
 RP
?NEGHL:
 DCX H
?NOTHL:
 MOV A,L
 CMA
 MOV L,A
 MOV A,H
 CMA
 MOV H,A
 RET

;УСКОРЕННЫЕ ПРЕОБРАЗОВАНИЯ BIN И BCD - ЧИСЕЛ
; DNUM - АДРЕС BCD - ЧИСЛА
; NDEC - ДЛИНА -""-
; BNUM - ДЛИНА BIN - ЧИСЛА
; NBIN - ДЛИНА -""-

?ZERON:XRA A
LOOP1:MOV M,A
 INX H
 DCR B
 JNZ LOOP1
 RET

; BCD -> BINARY
?FBCDB:
 LXI H,BNUM
 MVI B,NBIN
 CALL ?ZERON
 MVI A,NDEC
 ADD A
 ADD A
 ADD A
 MOV C,A
?NEW:
 XRA A
 LXI H,DNUM+NDEC-1
 MVI B,NDEC
 CALL SHIFTR
 LXI H,BNUM+NBIN-1
 MVI B,NBIN
 CALL SHIFTR
 LXI H,DNUM
 MVI B,NDEC
 CALL ?CORR
 DCR C
 JNZ ?NEW
 RET

NBIN: EQU 2
NDEC: EQU 2
DNUM: DB 55H,2
BNUM: DW 0

SHIFTR:
 MOV A,M
 RAR
 MOV M,A
 DCX H
 DCR B
 JNZ SHIFTR
 RET

?CORR:
 MOV A,M
 ANI 8
 JZ ?NOCR1
 MOV A,M
 SUI 3
 MOV M,A
?NOCR1:
 MOV A,M
 ANI 80H
 JZ ?NOCR2
 MOV A,M
 SUI 30H
 MOV M,A
?NOCR2:
 INX H
 DCR B
 JNZ ?CORR
 RET

; 16-BIT UNSIGNED SHIFT RIGHT
; HL >>= B
?SRNHB:
 INR B
?71:
 DCR B
 RZ
 ANA A
 MOV A,H
 RAR
 MOV H,A
 MOV A,L
 RAR
 MOV L,A
 JMP ?71

; КОЭФФИЦИЕНТЫ ДЕЛЕНИЯ ДЛЯ НОТ КОНТРОКТАВЫ
; 16.5МГЦ;16 МГЦ
PLTBL:
 DW 0DB34H;0D459H - ДО
 DW 0CEE7H;0C86EH - ДО#
 DW 0C34AH;0BD2EH - РЕ
 DW 0B854H;0B290H - РЕ#
 DW 0ADFCH;0A88AH - МИ
 DW 0A438H;09F15H - ФА
 DW 09B00H;09627H - ФА#
 DW 0924DH;08DBAH - СОЛЬ
 DW 08A17H;085C5H - СОЛЬ#
 DW 08257H;07E43H - ЛЯ
 DW 07B00H;0772DH - ЛЯ#
 DW 0741FH;0707DH - СИ

; МЕНУЭТ И.С.БАХ
; 1 ГОЛОС
PL01:
 DB 'V13T110L4O4^E2ED8E8E1E4"FFFF^EDEC2CO3B8O4C8C1C4'
 DB '"CCCCC^O3BO4CO3A2AG8A8A1A4'
 DB '"FFFFF^EFD1D2D4GO4C1O3B1'
 DB 0

 DB 'T1L1RRR',0
 DB 0
PL02:
 DB 'V5T110L8O1^CO2CO1CO2CO1CO2CO1CO2C'
 DB 'O1CO2CO1CO2CO1CO2CO1CO2C'
 DB 'O1CO2CO1CO2CO1CO2CO1CO2C'
 DB 'O1CO2CO1CO2CO1CO2CO1CO2C'
 DB 'O0AO1AO0AO1AO0AO1AO0AO1A'
 DB 'O0AO1AO0AO1AO0AO1AO0AO1A'
 DB 'O0AO1AO0AO1AO0AO1AO0AO1A'
 DB 'O0AO1AO0AO1AO0AO1AO0AO1A'
 DB 'O1FO2FO1FO2FO1FO2FO1FO2F'
 DB 'O1FO2FO1FO2FO1FO2FO1FO2F'
 DB 'O1FO2FO1FO2FO1FO2FO1FO2F'
 DB 'O1FO2FO1FO2FO1FO2FO1FO2F'
 DB 'O1GO2GO1GO2GO1GO2GO1GO2G'
 DB 'O1GO2GO1GO2GO1GO2GO1GO2G'
 DB 'O1GO2GO1GO2GO1GO2GO1GO2G'
 DB 'O1GO2GO1GO2GO1GO2GO1GO2G8'
 DB 0

PL03: DB 'T1L1RRR',0

; ВО ПОЛЕ БЕРЕЗА СТОЯЛА (EMPTY)
; 1 ГОЛОС
PL11:
 DB 'T110L4^O4AEDE8O3A8AO4GAG8A8'
 DB 'AEDE8O3A8AO4GAG8A8AA1',0
 DB  0
; 2 ГОЛОС
PL12:
 DB 'T110L8^O0AO1AO0AO1AO0AO1AO0AO1A'
 DB 'O0AO1AO0AO1AO0AO1AO0AO1A'
 DB 'O0AO1AO0AO1AO0AO1AO0AO1A'
 DB 'O0AO1AO0AO1AO0AO1AO0AO1A'
 DB 'O0AO1AO0AO1AO0AO1AO0AO1A'
 DB 'O0AO1A8'
 DB 0
PL13: DB 'T1L1RRR1',0



; ПЕСЕНКА КРОКОДИЛА ГЕНЫ (PLAY START)
; 1 ГОЛОС
PL21:
 DB 'T180L8"O4CRCRRRCR','DRDRRRDR','ERERRRCR'
 DB 'EREDRDDR','^CCC8'
 DB 0
; 2 ГОЛОС
PL22:
 DB 'T180L8"O3GRGGRGGR','GRGGRGGR','GRGGRGGR'
 DB 'GRGGRGGR','^GGG8',0
PL23:
 DB 'T1L1RRRR',0
PL31:
; КУЗНЕЧИК (START)
 DB 'T160L8O3^E1DEFDE1O4DEFDE1',0
 DB 0
PL32:
 DB 'T160L1O2^EEEE1',0
 DB 0

PL33:
 DB 'T1L1RRR',0

; ПТИЦА ЩАСЬЯ (ПОЕТ И.KОБЗОН)    (CHECK POINT)
PL41: DB 'T160L8O4"E8R8R4R2FRCDRRC4',0

PL42: DB 'T160L8O3"G8R8R4R2GRGGRRG4',0

PL43: DB 'T160L1O4C8T1RRR',0

;THE FINAL COUNT DOWN
PL51:
      DB 'T100O2L4^AA8O4E16D16EO3AAA8O4'
      DB 'F16E16F8E8DDD8F16E16FO3AAA8O4D16C16D8C8'
      DB 'O3B8O4D8'
      DB 'CC8E16D16EO3AAA8O4F16E16F8E8DDD8'
      DB 'F16E16FO3AAA8O4D16C16D8C8O3B8O4D8'
      DB 'CC8O3B16O4C16DD8C16D16E8D8C8O3B8'
      DB 'AO4FE2E4"E16^F16E16D16E1'


      DB 'O3^AA8O4E16D16EO3AAA8O4'
      DB 'F16E16F8E8DDD8F16E16FO3AAA8O4D16C16D8C8'
      DB 'O3B8O4D8'
      DB 'CC8E16D16EO3AAA8O4F16E16F8E8DDD8'
      DB 'F16E16FO3AAA8O4D16C16D8C8O3B8O4D8'
      DB 'CC8O3B16O4C16DD8C16D16E8D8C8O3B8'
      DB 'AO4FE2E4"E16^F16E16D16E1'

;PL51: DB 'T100O3L4"A2AGEO4CO3BGA^A8"A8A2'
      DB 'T1L1RRRRRR1'
      DB 0
PL52:
      DB 'T1L1RRRRRRRRRRRRRRRRRRRRRRRRRRRRRRRRR1'
      DB 0
PL53:
      DB 'T100O1L1"AFDG^G32"AFDGA2G2O2C2O1F2EE'
      DB '^E32"L8'
      DB 'O0AO1AO0AO1AO0AO1AO0AO1A'
      DB 'O0FO1FO0FO1FO0FO1FO0FO1F'
      DB 'O0DO1DO0DO1DO0DO1DO0DO1D'
      DB 'O0GO1GO0GO1GO0GO1GO0GO1G'
      DB 'O0AO1AO0AO1AO0AO1AO0AO1A'
      DB 'O0FO1FO0FO1FO0FO1FO0FO1F'
      DB 'O0DO1DO0DO1DO0DO1DO0DO1D'
      DB 'O0GO1GO0GO1GO0GO1GO0GO1G'
      DB 'O0AO1AO0AO1AO0GO1GO0GO1G'
      DB 'O1CO2CO1CO2CO0FO1FO0FO1F'
      DB 'O0EO1EO0EO1EO0EO1EO0EO1E'
      DB 'O0EO1EO0EO1EO0EO1EO0EO1E8'

;PL53: DB 'T200O1L4"AR8A8AAAR8A8AAAR8A8AAAR8A8AA4'

      DB 0


PNT1:DS 2
PNT2:DS 2
PNT3:DS 2
DL1: DS 2
DL2: DS 2
DL3: DS 2
DLC1:DS 2
DLC2:DS 2
DLC3:DS 2
LEGATO:DS 1
STCPNT:DS 2
ZAST: DB 1FH,' 1  МИНУЭТ И.С.БАХ'
      DB 0DH,0AH,' 2  ВО ПОЛЕ БЕРЕЗА СТОЯЛА..'
      DB 0AH,0DH,' 3 pЕСЕНКА КРОКОДИЛА ГЕНЫ'
      DB 0DH,0AH,' 4 КУЗНЕЧИК'
      DB 0DH,0AH,' 5 ПТИЦА ЩАСЬЯ (ПОЕТ И.КОБЗОН)'
      DB 0DH,0AH,' 6 В ЛЕСУ РОДИЛАСЬ ЕЛОЧКА ...',0

 END