build.gradle

/*
 * Copyright Amazon.com, Inc. or its affiliates. All Rights Reserved.
 *
 * Licensed under the Apache License, Version 2.0 (the "License").
 * You may not use this file except in compliance with the License.
 * A copy of the License is located at
 *
 *     http://www.apache.org/licenses/LICENSE-2.0
 *
 * or in the "license" file accompanying this file. This file is distributed
 * on an "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either
 * express or implied. See the License for the specific language governing
 *  permissions and limitations under the License.
 */

// Documentation for using Gradle with Kotlin is here: https://kotlinlang.org/docs/reference/using-gradle.html

plugins {
    id 'java-library'
    id 'org.jetbrains.kotlin.jvm' version '1.6.20'
    id 'maven-publish'
    id 'signing'
    id 'org.jetbrains.dokka' version '1.6.20'
    id 'jacoco'
    id 'org.jetbrains.kotlinx.binary-compatibility-validator' version '0.9.0'
    id "org.jlleitschuh.gradle.ktlint" version "10.3.0"
}

group = "com.amazon.ion"
version = "1.1.0"
ext.isReleaseVersion = !version.endsWith("SNAPSHOT")

repositories {
    mavenCentral()
}

java {
    sourceCompatibility = JavaVersion.VERSION_1_8
    targetCompatibility = JavaVersion.VERSION_1_8
}

tasks.withType(org.jetbrains.kotlin.gradle.tasks.KotlinCompile).all {
    kotlinOptions {
        jvmTarget = "1.8"
        apiVersion = "1.3"
        languageVersion = "1.4" // Can be read by 1.3 compiler, so consumers on kotlin 1.3 are still supported.
        freeCompilerArgs = [
                "-opt-in=kotlin.RequiresOptIn" // Using RequiresOptIn requires opt-in itself, at least in kotlin-1.4
        ]
    }
}

kotlin {
    explicitApi = 'strict'
}

dependencies {
    api 'com.amazon.ion:ion-java:[1.4.0,)'
    implementation 'org.jetbrains.kotlin:kotlin-stdlib-jdk8'
    implementation 'org.jetbrains.kotlinx:kotlinx-collections-immutable:0.3.4'

    testImplementation 'org.jetbrains.kotlin:kotlin-test'
    testImplementation 'org.junit.jupiter:junit-jupiter-api:5.6.2'
    testImplementation 'org.junit.jupiter:junit-jupiter-params:5.6.2'
    testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.6.2'
}

test {
    useJUnitPlatform()
    jacoco {
        destinationFile = file("${buildDir}/jacoco/test.exec")
    }
}

task sourcesJar(type: Jar) {
    from "src"
    archiveClassifier.set("sources")
}

task javadocJar(type: Jar, dependsOn: dokkaJavadoc) {
    classifier 'javadoc'
    from dokkaJavadoc.outputDirectory
}

java {
    sourceSets {
        main.java.srcDirs = ["src"]
        main.resources.srcDirs = ["resources"]
        test.java.srcDirs = ["test"]
        test.resources.srcDirs = ["test-resources"]
    }
}


jacocoTestReport {
    // Adjust the output of the test report
    reports {
        xml.enabled true
        csv.enabled false
    }
}

tasks.jacocoTestReport {
    dependsOn(tasks.test) // tests are required to run before generating the report
}

ktlint {
    version = "0.45.2"
    outputToConsole = true
}

plugins.withId('org.jetbrains.kotlin.jvm', { _ ->
    sourceSets {
        main.kotlin.srcDirs = ["src"]
        test.kotlin.srcDirs = ["test"]
    }
})

publishing {
    publications {
        maven(MavenPublication) {
            artifactId = "ion-element"

            from components.java
            artifact sourcesJar
            artifact javadocJar

            pom {
                name = "Ion Element Kotlin"
                packaging = "jar"
                url = "https://github.com/amzn/ion-element-kotlin"
                description = "An immutable in-memory representation of Amazon Ion for Kotlin"
                scm {
                    connection = "scm:git@github.com:amzn/ion-element-kotlin.git"
                    developerConnection = "scm:git@github.com:amzn/ion-element-kotlin.git"
                    url = "git@github.com:amzn/ion-element-kotlin.git"
                }
                licenses {
                    license {
                        name = "The Apache License, Version 2.0"
                        url = "http://www.apache.org/licenses/LICENSE-2.0.txt"
                    }
                }
                developers {
                    developer {
                        name = "Amazon Ion Team"
                        email = "ion-team@amazon.com"
                        organization = "Amazon Ion"
                        organizationUrl = "https://github.com/amazon-ion"
                    }
                }
            }
        }
    }
    repositories {
        maven {
            url "https://aws.oss.sonatype.org/service/local/staging/deploy/maven2"
            credentials {
                username ossrhUsername
                password ossrhPassword
            }
        }
    }
}

signing {
    // Allow publishing to maven local even if we don't have the signing keys
    // This works because when not required, the signing task will be skipped
    // if signing.keyId, signing.password, signing.secretKeyRingFile, etc are
    // not present in gradle.properties.
    required { isReleaseVersion && gradle.taskGraph.hasTask("publish") }
    sign publishing.publications.maven
}

tasks.withType(Sign) {
    onlyIf { isReleaseVersion }
}