build.gradle

plugins {
    id 'java'
    id 'idea'
    id 'com.google.protobuf' version '0.9.1'
}

group 'org.example'
version '1.0-SNAPSHOT'

repositories {
    mavenCentral()
}

dependencies {
    ['armeria',
     'armeria-grpc',
     'armeria-graphql',
     'armeria-logback',
     'armeria-junit5'
    ].each {
        implementation "com.linecorp.armeria:${it}:1.25.2"
    }

    implementation "io.micrometer:micrometer-registry-prometheus:1.11.0"

    runtimeOnly "io.grpc:grpc-netty-shaded:1.52.1"
    implementation "io.grpc:grpc-protobuf:1.52.1"
    implementation "io.grpc:grpc-stub:1.52.1"

    compileOnly "org.apache.tomcat:annotations-api:6.0.53" // necessary for Java 9+

    implementation "io.projectreactor:reactor-core:3.5.2"
    testImplementation "io.projectreactor:reactor-test:3.5.2"

    implementation "org.reactivestreams:reactive-streams:1.0.4"
    implementation "org.reactivestreams:reactive-streams-tck:1.0.4"
    implementation "org.reactivestreams:reactive-streams-tck-flow:1.0.4"
    implementation "org.reactivestreams:reactive-streams-examples:1.0.4"

    implementation "ch.qos.logback:logback-classic:1.4.7"
    implementation "org.slf4j:slf4j-api:2.0.7"

    testImplementation "org.junit.jupiter:junit-jupiter-api:5.8.1"
    testRuntimeOnly "org.junit.jupiter:junit-jupiter-engine:5.8.1"
    testImplementation "org.assertj:assertj-core:3.11.1"
}

protobuf {
    protoc {
        artifact = "com.google.protobuf:protoc:3.21.7"
    }
    plugins {
        grpc {
            artifact = 'io.grpc:protoc-gen-grpc-java:1.52.1'
        }
    }
    generateProtoTasks {
        all()*.plugins {
            grpc {}
        }
    }
}

tasks.withType(JavaCompile) {
    options.compilerArgs += '-parameters'
}

test {
    useJUnitPlatform()
}