build.gradle

buildscript {
    repositories {
        maven {
            url "https://plugins.gradle.org/m2/"
        }
    }
    dependencies {
        classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:1.6'
        classpath 'org.jfrog.buildinfo:build-info-extractor-gradle:4.4.4'
        classpath 'gradle.plugin.nl.javadude.gradle.plugins:license-gradle-plugin:0.13.1'
        classpath 'net.saliman:gradle-cobertura-plugin:2.3.2'
        classpath 'org.kt3k.gradle.plugin:coveralls-gradle-plugin:2.6.3'
        classpath 'com.github.ben-manes:gradle-versions-plugin:0.12.0'
        classpath "com.gradle.publish:plugin-publish-plugin:0.9.9"
    }
}

plugins {
    id 'de.gliderpilot.semantic-release' version '1.2.0'
}

apply from: "$rootDir/gradle/credentials.gradle"
apply from: "$rootDir/gradle/artifactory.gradle"
apply plugin: 'maven-publish'

apply plugin: 'base'

allprojects {
    apply plugin: 'com.github.ben-manes.versions'

    repositories {
        jcenter()
    }

    tasks.withType(Test) {
        maxHeapSize = "512m"
        jvmArgs "-XX:MaxPermSize=256m"
    }
}

semanticRelease {
    repo.ghToken = project.ext.ghToken
}

if (!version.toString().endsWith('-SNAPSHOT')) {
    publish.dependsOn getTasksByName("publishPlugins", true)
    publish.dependsOn getTasksByName("bintrayUpload", true)
} else if ((System.getenv('TRAVIS_PULL_REQUEST') ?: "false") == "false") {
    publish.dependsOn getTasksByName("artifactoryPublish", true)
}