add cvemap (#4066)

packages/cvemap/PKGBUILD

@@ -0,0 +1,43 @@
+# This file is part of BlackArch Linux ( https://www.blackarch.org/ ).
+# See COPYING for license details.
+
+pkgname=cvemap
+pkgver=v0.0.2.r0.gda2fdef
+pkgrel=1
+pkgdesc='CLI tool designed to provide a structured and easily navigable interface to various vulnerability databases.'
+arch=('x86_64' 'aarch64')
+groups=('blackarch' 'blackarch-exploitation')
+url='https://github.com/projectdiscovery/cvemap'
+license=('MIT')
+depends=()
+makedepends=('git' 'go')
+source=("git+https://github.com/projectdiscovery/$pkgname.git")
+sha512sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+
+  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+  cd $pkgname
+
+  GOPATH="$srcdir" go mod download
+  GOPATH="$srcdir" go build \
+    -trimpath \
+    -buildmode=pie \
+    -mod=readonly \
+    -modcacherw \
+    -ldflags "-s -w" \
+    -o $pkgname ./cmd/$pkgname
+}
+
+package() {
+  cd $pkgname
+
+  install -Dm 755 $pkgname "$pkgdir/usr/bin/$pkgname"
+  install -Dm 644 -t "$pkgdir/usr/share/doc/$pkgname/" README.md
+  install -Dm 644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+