chore(nix): Initial flake

.envrc

@@ -0,0 +1,3 @@
+watch_file nix
+
+use flake

.gitignore

@@ -1,3 +1,4 @@
 target
-
 /.env
+
+/.direnv

flake.nix

@@ -0,0 +1,24 @@
+{
+  inputs = {
+    nixpkgs.url = "github:nixos/nixpkgs?ref=nixpkgs-unstable";
+    flake-parts.url = "github:hercules-ci/flake-parts";
+    fenix.url = "github:nix-community/fenix";
+    fenix.inputs.nixpkgs.follows = "nixpkgs";
+  };
+
+  outputs =
+    inputs@{ flake-parts, ... }:
+    flake-parts.lib.mkFlake { inherit inputs; } {
+      systems = [
+        "aarch64-linux"
+        "aarch64-darwin"
+        "x86_64-linux"
+      ];
+      perSystem = {
+        imports = [
+          ./nix/devshells.nix
+          ./nix/packages.nix
+        ];
+      };
+    };
+}

nix/devshells.nix

@@ -0,0 +1,97 @@
+{
+  inputs',
+  pkgs,
+  lib,
+  ...
+}:
+
+let
+  fenix = inputs'.fenix.packages;
+
+  # creates list of components taken from a toolchain for given channel
+  rustComponents =
+    channel:
+    [
+      "rustc"
+      "cargo"
+      "clippy"
+      "rustfmt"
+    ]
+    ++ lib.optionals (channel == "stable") [
+      "rust-analyzer"
+    ];
+
+  # creates list of the extra targets to be installed for given channel
+  rustExtraTargets =
+    channel:
+    [
+      "wasm32-unknown-unknown"
+    ]
+    ++ lib.optionals (channel == "stable") [
+      # android
+      "aarch64-linux-android"
+      "armv7-linux-androideabi"
+      "x86_64-linux-android"
+      "i686-linux-android"
+      # ios
+      "aarch64-apple-ios"
+      "aarch64-apple-ios-sim"
+    ];
+
+  # creates toolchain configuration for given channel
+  rustToolchain =
+    channel:
+    fenix.combine [
+      # components
+      (fenix."${channel}".withComponents (rustComponents channel))
+      # extra targets
+      (lib.lists.map (target: fenix.targets."${target}"."${channel}".rust-std) (rustExtraTargets channel))
+    ];
+
+  # wrapper for cargo to allow `+channel` syntax
+  cargoWrapper = pkgs.writeShellScriptBin "cargo" ''
+    case "$1" in
+      "+stable")
+        shift
+        exec env PATH="${rustToolchain "stable"}/bin:$PATH" cargo "$@"
+        ;;
+      "+nightly")
+        shift
+        exec env PATH="${rustToolchain "latest"}/bin:$PATH" cargo "$@"
+        ;;
+      "+"*)
+        echo "Channel $1 not installed. You may need to add it to the devShell" >&2
+        exit 1
+        ;;
+      *)
+        exec env PATH="${rustToolchain "stable"}/bin:$PATH" cargo "$@"
+        ;;
+    esac
+  '';
+in
+{
+  devShells.default = pkgs.mkShell {
+    packages = with pkgs; [
+      # c/gnu base
+      gnumake
+      pkg-config
+      stdenv
+
+      # rust - toolchain
+      cargoWrapper # first in PATH, to be invoked instead one from toolchain
+      (rustToolchain "stable")
+      # rust - wasm
+      binaryen # wasm-opt
+      wasm-bindgen-cli_0_2_100
+      wasm-pack
+      # rust - other
+      cargo-edit
+      cargo-ndk
+      cargo-udeps
+
+      # javascript
+      nodejs
+      nodePackages.typescript-language-server
+    ];
+  };
+}

nix/packages.nix

@@ -0,0 +1,5 @@
+{ ... }:
+
+{
+  packages.default = { };
+}