cambiatus · MatheusBuss · May 31, 2022 · May 8, 2022 · May 11, 2022 · May 12, 2022
diff --git a/lib/cambiatus_web/controllers/rich_link_controller.ex b/lib/cambiatus_web/controllers/rich_link_controller.ex
@@ -0,0 +1,91 @@
+defmodule CambiatusWeb.RichLinkController do
+  use CambiatusWeb, :controller
+
+  @moduledoc """
+  Get data and render html to be used for rich links (also known as Open Graphs).
+  These rich links show additional information about the website when shared on social media
+  and must be compliant with the [Open Grap Protocol](https://ogp.me/)
+  """
+
+  alias CambiatusWeb.Resolvers.{Accounts, Commune, Shop}
+  alias Cambiatus.Repo
+
+  def rich_link(conn, params) do
+    data =
+      case Map.get(params, "page") do
+        ["shop", id] ->
+          product_rich_link(id)
+
+        ["profile", account] ->
+          user_rich_link(account)
+
+        [] ->
+          community_rich_link(conn.host)
+
+        _ ->
+          send_resp(conn, 404, "Category not found")
+      end
+
+    case data do
+      {:ok, data} ->
+        render(conn, "rich_link.html", %{data: data})
+
+      {:error, reason} ->
+        send_resp(conn, 404, reason)
+    end
+  end
+
+  def product_rich_link(id) do
+    case Shop.get_product(nil, %{id: id}, nil) do
+      {:ok, product} ->
+        product = Repo.preload(product, :images)
+        [image | _] = product.images
+
+        {:ok,
+         %{
+           description: product.description,
+           title: product.title,
+           url: nil,
+           image: image.uri,
+           locale: nil
+         }}
+
+      {:error, reason} ->
+        {:error, reason}
+    end
+  end
+
+  def user_rich_link(account) do
+    case Accounts.get_user(nil, %{account: account}, nil) do
+      {:ok, user} ->
+        {:ok,
+         %{
+           description: user.bio,
+           title: user.name,
+           url: user.email,
+           image: user.avatar,
+           locale: user.location
+         }}
+
+      {:error, reason} ->
+        {:error, reason}
+    end
+  end
+
+  def community_rich_link(community_subdomain) do
+    case Commune.find_community(%{}, %{subdomain: community_subdomain}, %{}) do
+      {:ok, community} ->
+        {:ok,
+         %{
+           description: community.description,
+           title: community.name,
+           url: community_subdomain,
+           image: community.logo,
+           locale: nil
+         }}
+
+      {:error, reason} ->
+        {:error, reason}
+    end
+  end
+end
diff --git a/lib/cambiatus_web/router.ex b/lib/cambiatus_web/router.ex
@@ -51,6 +51,7 @@ defmodule CambiatusWeb.Router do
     get("/chain/info", ChainController, :info)
     post("/invite", InviteController, :invite)
     get("/manifest", ManifestController, :manifest)
+    get("/rich_link/*page", RichLinkController, :rich_link)
 
     post("/paypal", PaypalController, :index)
   end

diff --git a/lib/cambiatus_web/templates/layout/app.html.eex b/lib/cambiatus_web/templates/layout/app.html.eex
@@ -0,0 +1 @@
+<%= @inner_content %>
diff --git a/lib/cambiatus_web/templates/rich_link/rich_link.html.eex b/lib/cambiatus_web/templates/rich_link/rich_link.html.eex
@@ -0,0 +1,18 @@
+<html lang="en" class="h-full" >
+  <head>
+    <meta charset="utf-8">
+    <meta http-equiv="x-ua-compatible" content="ie=edge">
+    <meta name="viewport" content="width=device-width, initial-scale=1, shrink-to-fit=no">
+
+    <meta name="twitter:card" content="summary">
+    <meta name="twitter:site" content="@_cambiatus">
+    <meta name="description" content="<%= md_to_txt(@data.description) %>">
+    <meta property="og:description" content="<%= md_to_txt(@data.description) %>">
+    <meta property="og:locale" content="<%= @data.locale %>">
+    <meta property="og:type" content="website">
+    <meta property="og:title" content="<%= @data.title %>">
+    <meta property="og:url" content="<%= @data.url %>">
+    <meta property="og:image" content="<%= @data.image %>">
+
+    <title>"<%= @data.title %>"</title>
+  </head>
diff --git a/lib/cambiatus_web/views/rich_link_view.ex b/lib/cambiatus_web/views/rich_link_view.ex
@@ -0,0 +1,16 @@
+defmodule CambiatusWeb.RichLinkView do
+  use CambiatusWeb, :view
+
+  require Earmark
+  require HtmlSanitizeEx
+
+  def md_to_txt(markdown) do
+    with {:ok, string, _} <- Earmark.as_html(markdown) do
+      HtmlSanitizeEx.strip_tags(string)
+      |> String.trim()
+    else
+      {:error, _} ->
+        ""
+    end
+  end
+end
diff --git a/mix.exs b/mix.exs
@@ -49,6 +49,7 @@ defmodule Cambiatus.Mixfile do
       {:ex_phone_number, "~> 0.2"},
       {:number, "~> 1.0"},
       {:earmark, "~> 1.4"},
+      {:html_sanitize_ex, "~> 1.4"},
 
       # Email capabilities
       {:swoosh, "~> 1.0"},

diff --git a/test/cambiatus_web/controllers/rich_link_controller_test.exs b/test/cambiatus_web/controllers/rich_link_controller_test.exs
@@ -0,0 +1,109 @@
+defmodule CambiatusWeb.RichLinkControllerTest do
+  use Cambiatus.DataCase
+  use CambiatusWeb.ConnCase
+
+  alias Cambiatus.Repo
+
+  setup %{conn: conn} do
+    {:ok, conn: put_req_header(conn, "accept", "application/json")}
+  end
+
+  describe "RichLink" do
+    test "generate rich link for community",
+         %{conn: conn} do
+      # Insert community and extract data for the rich link
+      community =
+        insert(:community)
+        |> Repo.preload(:subdomain)
+
+      expected_data = %{
+        description: md_to_txt(community.description),
+        title: community.name,
+        url: community.subdomain.name,
+        image: community.logo,
+        locale: nil
+      }
+
+      # Submit GET request for a community rich link
+      conn =
+        %{conn | host: community.subdomain.name}
+        |> get("/api/rich_link")
+
+      response = html_response(conn, 200)
+
+      # Check http code 200 and if all the rich link fields are properly filled
+      assert conn.status == 200
+
+      Enum.each(expected_data, fn {k, v} ->
+        assert String.match?(response, ~r/meta property=\"og:#{k}\" content=\"#{v}/)
+      end)
+    end
+
+    test "generate rich link for user",
+         %{conn: conn} do
+      # Insert user and extract data for the rich link
+
+      user = insert(:user)
+
+      expected_data = %{
+        description: md_to_txt(user.bio),
+        title: user.name,
+        url: user.email,
+        image: user.avatar,
+        locale: user.location
+      }
+
+      # Submit GET request for a user rich link
+      conn = get(conn, "/api/rich_link/profile/#{user.account}")
+      response = html_response(conn, 200)
+
+      # Check http code 200 and if all the rich link fields are properly filled
+      assert conn.status == 200
+
+      Enum.each(expected_data, fn {k, v} ->
+        assert String.match?(response, ~r/meta property=\"og:#{k}\" content=\"#{v}/)
+      end)
+    end
+
+    test "generate rich link for product",
+         %{conn: conn} do
+      # Insert product and extract data for the rich link
+
+      product =
+        insert(:product)
+        |> Repo.preload(:images)
+
+      [image | _] = product.images
+
+      expected_data = %{
+        description: md_to_txt(product.description),
+        title: product.title,
+        url: nil,
+        image: image.uri,
+        locale: nil
+      }
+
+      # Submit GET request for a product rich link
+      conn = get(conn, "/api/rich_link/shop/#{product.id}")
+      response = html_response(conn, 200)
+
+      # Check http code 200 and if all the rich link fields are properly filled
+      assert conn.status == 200
+
+      Enum.each(expected_data, fn {k, v} ->
+        assert String.match?(response, ~r/meta property=\"og:#{k}\" content=\"#{v}/)
+      end)
+    end
+  end
+
+  defp md_to_txt(markdown) do
+    # Convert markdown to plain text
+    with {:ok, string, _} <- Earmark.as_html(markdown) do
+      HtmlSanitizeEx.strip_tags(string)
+      |> String.trim()
+    else
+      {:error, _} ->
+        ""
+    end
+  end
+end